git.sur5r.net Git - glabels/blob - glabels2/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.52)
   4
   5 AC_INIT(glabels, 2.3.pre0svn, http://sourceforge.net/tracker/?func=add&group_id=46122&atid=445116)
   6 AC_CONFIG_SRCDIR(src/glabels.c)
   7 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   8
   9 AM_MAINTAINER_MODE
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AC_PROG_INTLTOOL([0.21])
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_HEADER_STDC
  20
  21 GNOME_COMPILE_WARNINGS
  22
  23 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
  24
  25 GTK_DOC_CHECK(1.0)
  26
  27 dnl ---------------------------------------------------------------------------
  28 dnl - LIBGLABELS API versioning
  29 dnl ---------------------------------------------------------------------------
  30 dnl From the libtool manual:
  31 dnl 1. Start with version information of `0:0:0' for each libtool library.
  32 dnl 2. Update the version information only immediately before a public release.
  33 dnl    More frequent updates are unnecessary, and only guarantee that the current
  34 dnl    interface number gets larger faster.
  35 dnl 3. If the library source code has changed at all since the last update, then increment
  36 dnl    revision (`c:r:a' becomes `c:r+1:a').
  37 dnl 4. If any interfaces have been added, removed, or changed since the last update,
  38 dnl    increment current, and set revision to 0.
  39 dnl 5. If any interfaces have been added since the last public release, then increment age.
  40 dnl 6. If any interfaces have been removed since the last public release, then set age
  41 dnl    to 0.
  42 LIBGLABELS_C=5
  43 LIBGLABELS_R=1
  44 LIBGLABELS_A=0
  45
  46 LIBGLABELS_VERSION_INFO=${LIBGLABELS_C}:${LIBGLABELS_R}:${LIBGLABELS_A}
  47 AC_SUBST(LIBGLABELS_VERSION_INFO)
  48
  49
  50 dnl ---------------------------------------------------------------------------
  51 dnl - Library dependencies
  52 dnl ---------------------------------------------------------------------------
  53 GLIB_REQUIRED=2.12.0
  54 GTK_REQUIRED=2.10.0
  55 LIBGNOME_REQUIRED=2.16.0
  56 LIBGNOMEUI_REQUIRED=2.16.0
  57 LIBXML_REQUIRED=2.6.0
  58 LIBGLADE_REQUIRED=2.6.0
  59 LIBEBOOK_REQUIRED=1.8.0
  60
  61 dnl Make above strings available for packaging files (e.g. rpm spec files)
  62 AC_SUBST(GLIB_REQUIRED)
  63 AC_SUBST(GTK_REQUIRED)
  64 AC_SUBST(LIBGNOME_REQUIRED)
  65 AC_SUBST(LIBGNOMEUI_REQUIRED)
  66 AC_SUBST(LIBXML_REQUIRED)
  67 AC_SUBST(LIBGLADE_REQUIRED)
  68 AC_SUBST(LIBEBOOK_REQUIRED)
  69
  70
  71 dnl ---------------------------------------------------------------------------
  72 dnl - Check for evolution data server
  73 dnl ---------------------------------------------------------------------------
  74 AC_ARG_WITH(libebook,
  75             [AC_HELP_STRING([--without-libebook],
  76                             [build without Evolution Data Server support])])
  77 have_libebook=no
  78 if test "x$with_libebook" != xno; then
  79         PKG_CHECK_MODULES(LIBEBOOK, libebook-1.2 >= $LIBEBOOK_REQUIRED,
  80                           [have_libebook=yes], [have_libebook=no])
  81 fi
  82
  83 if test "x$have_libebook" = "xyes"; then
  84         AC_DEFINE(HAVE_LIBEBOOK,1,[Define to 1 for EDS support])
  85         OPTIONAL_MODULES="$OPTIONAL_MODULES libebook-1.2 >= $LIBEBOOK_REQUIRED"
  86 fi
  87
  88
  89 dnl ---------------------------------------------------------------------------
  90 dnl - GLABELS prerequisites
  91 dnl ---------------------------------------------------------------------------
  92 PKG_CHECK_MODULES(GLABELS, \
  93 glib-2.0 >= $GLIB_REQUIRED \
  94 gtk+-2.0 >= $GTK_REQUIRED \
  95 libgnome-2.0 >= $LIBGNOME_REQUIRED \
  96 libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED \
  97 libxml-2.0 >= $LIBXML_REQUIRED \
  98 libglade-2.0 >= $LIBGLADE_REQUIRED \
  99 $OPTIONAL_MODULES \
 100 )
 101
 102 AC_SUBST(GLABELS_CFLAGS)
 103 AC_SUBST(GLABELS_LIBS)
 104
 105
 106 dnl ---------------------------------------------------------------------------
 107 dnl - LIBGLABELS more modest prerequisites
 108 dnl ---------------------------------------------------------------------------
 109 PKG_CHECK_MODULES(LIBGLABELS, \
 110 glib-2.0 >= $GLIB_REQUIRED \
 111 libxml-2.0 >= $LIBXML_REQUIRED \
 112 )
 113
 114 AC_SUBST(LIBGLABELS_CFLAGS)
 115 AC_SUBST(LIBGLABELS_LIBS)
 116
 117
 118 dnl ---------------------------------------------------------------------------
 119 dnl - Enable deprecation testing
 120 dnl ---------------------------------------------------------------------------
 121 AC_ARG_ENABLE(deprecations,
 122               [AC_HELP_STRING([--enable-deprecations],
 123                               [warn about deprecated usages [default=no]])],,
 124               [enable_deprecations=no])
 125
 126 if test "x$enable_deprecations" = "xyes"; then
 127    DISABLE_DEPRECATED_CFLAGS="\
 128 -DG_DISABLE_DEPRECATED \
 129 -DGDK_DISABLE_DEPRECATED \
 130 -DGTK_DISABLE_DEPRECATED \
 131 -DGDK_PIXBUF_DISABLE_DEPRECATED \
 132 -DGNOME_DISABLE_DEPRECATED \
 133 -DLIBGLADE_DISABLE_DEPRECATED"
 134    AC_SUBST(DISABLE_DEPRECATED_CFLAGS)
 135 fi
 136
 137
 138 dnl ---------------------------------------------------------------------------
 139 dnl - Is freedesktop mime dbase available?
 140 dnl ---------------------------------------------------------------------------
 141 AC_PATH_PROG(UPDATE_MIME_DATABASE, update-mime-database, no)
 142 AM_CONDITIONAL(HAVE_NEW_MIME, test x$UPDATE_MIME_DATABASE != xno)
 143
 144 AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, update-desktop-database, no)
 145 AM_CONDITIONAL(HAVE_NEWER_MIME, test x$UPDATE_DESKTOP_DATABASE != xno)
 146
 147 AC_ARG_ENABLE(update-mimedb, AC_HELP_STRING([--disable-update-mimedb],
 148               [disable the update-mime-database after install [default=no]]),,
 149               enable_update_mimedb=yes)
 150 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)
 151
 152 AC_ARG_ENABLE(update-desktopdb, AC_HELP_STRING([--disable-update-desktopdb],
 153               [disable the update-desktop-database after install [default=no]]),,
 154               enable_update_desktopdb=yes)
 155 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)
 156
 157
 158 dnl ---------------------------------------------------------------------------
 159 dnl - Supported languages
 160 dnl ---------------------------------------------------------------------------
 161 GETTEXT_PACKAGE=glabels
 162 AC_SUBST(GETTEXT_PACKAGE)
 163 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
 164
 165 dnl Add the languages here.
 166 ALL_LINGUAS="fr de ja pt_BR es ru zh_TW.Big5 pl cs it eo ko"
 167 AM_GLIB_GNU_GETTEXT
 168
 169
 170 dnl ---------------------------------------------------------------------------
 171 dnl - Makefiles, etc.
 172 dnl ---------------------------------------------------------------------------
 173 AC_OUTPUT([
 174 Makefile
 175 barcode-0.98/Makefile
 176 iec16022-0.2.1/Makefile
 177 libglabels/Makefile
 178 libglabels/libglabels.pc
 179 src/Makefile
 180 src/pixmaps/Makefile
 181 src/stock-pixmaps/Makefile
 182 src/mygal/Makefile
 183 data/Makefile
 184 data/templates/Makefile
 185 data/pixmaps/Makefile
 186 data/mime/Makefile
 187 data/glade/Makefile
 188 data/desktop/Makefile
 189 data/dtd/Makefile
 190 data/man/Makefile
 191 po/Makefile.in
 192 help/Makefile
 193 help/C/Makefile
 194 docs/Makefile
 195 docs/libglabels/Makefile
 196 glabels.spec
 197 ])
 198
 199
 200 dnl ---------------------------------------------------------------------------
 201 dnl - Print configuration information
 202 dnl ---------------------------------------------------------------------------
 203 echo "
 204 Configuration:
 205
 206         Package:                        ${PACKAGE}-${VERSION}:
 207         Installation prefix             ${prefix}
 208         Source code location:           ${srcdir}
 209         Compiler:                       ${CC}
 210         Evolution Data Server support:  ${have_libebook}
 211
 212 "
 213
 214 cat ${srcdir}/MESSAGE-OF-DOOM
 215