git.sur5r.net Git - kconfig-frontends/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #---------------------------------------------------------------------------
   5 # Global initialisation
   6
   7 #----------------------------------------
   8 # Prepare autoconf
   9 AC_PREREQ([2.67])
  10 AC_INIT(
  11     [kconfig-frontends],
  12     [m4_esyscmd_s([./scripts/version.sh])],
  13     [yann.morin.1998@free.fr])
  14 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
  15 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
  16 AC_CONFIG_HEADERS([scripts/.autostuff/config.h])
  17 AC_CONFIG_AUX_DIR([scripts/.autostuff/scripts])
  18 AC_CONFIG_MACRO_DIR([scripts/.autostuff/m4])
  19
  20 #----------------------------------------
  21 # Prepare automake
  22
  23 # We want to allow the user to override our default program-prefix,
  24 # so we must set-it now, before automake has a chance to interpret
  25 # it, but after the options are parsed, so as not to overwrite the
  26 # value (if any) set by the user
  27 AS_IF(
  28     [test "$program_prefix" = NONE],
  29     [program_prefix=kconfig-])
  30
  31 AM_INIT_AUTOMAKE
  32
  33 #----------------------------------------
  34 # Prepare libtool
  35 LT_PREREQ([2.2.6])
  36 LT_INIT([disable-static])
  37
  38 #---------------------------------------------------------------------------
  39 # Set misc options
  40
  41 # By default, do not build with -Wall, unless the user asks for it
  42 AC_ARG_ENABLE(
  43     [wall],
  44     [AS_HELP_STRING(
  45         [--enable-wall],
  46         [build with -Wall (default=no)])],
  47     [AS_CASE(
  48         ["$enableval"],
  49         [yes], [wall_CFLAGS=-Wall],
  50         [*],   [wall_CFLAGS=""])])
  51 AC_SUBST([wall_CFLAGS],[${wall_CFLAGS}])
  52
  53 # By default, do not build with -Werror, unless the user asks for it
  54 AC_ARG_ENABLE(
  55     [werror],
  56     [AS_HELP_STRING(
  57         [--enable-werror],
  58         [build with -Werror (default=no)])],
  59     [AS_CASE(
  60         ["$enableval"],
  61         [yes], [werror_CFLAGS=-Werror],
  62         [*],   [werror_CFLAGS=""])])
  63 AC_SUBST([werror_CFLAGS],[${werror_CFLAGS}])
  64
  65 # Although there is a default (="linux") in the code, we do provide
  66 # a default here, to get a consistent autostuff behavior
  67 AC_ARG_ENABLE(
  68     [root-menu-prompt],
  69     [AS_HELP_STRING(
  70         [--enable-root-menu-prompt=PROMPT],
  71         [set the root-menu prompt (default=Configuration)])],
  72     [AS_CASE(
  73         ["$enableval"],
  74         [yes], [root_menu=Configuration],
  75         [no],  [root_menu=],
  76                [# Escape the $ signs, otherwise they would get munged by make
  77                 # Also, append a space at the end, to separate the package
  78                 # name from the literal 'Configuration'
  79                 root_menu="$( echo "$enableval" |sed -r -e 's/\$/\\$$/g;' )"])])
  80 AC_SUBST([root_menu], [${root_menu=Configuration}])
  81
  82 AC_ARG_ENABLE(
  83     [config-prefix],
  84     [AS_HELP_STRING(
  85         [--enable-config-prefix=PREFIX],
  86         [the prefix to the config option (default=CONFIG_)])],
  87     [AS_CASE(
  88         ["$enableval"],
  89         [*" "*],[AC_MSG_ERROR([config prefix can not contain spaces: '$enableval'])],
  90         [yes],  [config_prefix=CONFIG_],
  91         [no],   [config_prefix=],
  92                 [config_prefix=$enableval])])
  93 AC_SUBST([config_prefix], [${config_prefix-CONFIG_}])
  94
  95 AC_ARG_ENABLE(
  96     [utils],
  97     [AS_HELP_STRING(
  98         [--disable-utils],
  99         [install utilities to manage .config files (default=no)])])
 100 AC_SUBST([enable_utils], [${enable_utils:-yes}])
 101
 102 #----------------------------------------
 103 # Options to selectively enable/disable frontends
 104 # All are selected by default
 105 AC_ARG_ENABLE(
 106     [conf],
 107     [AS_HELP_STRING(
 108         [--disable-conf],
 109         [conf, the stdin-based frontend (default=auto)])])
 110 AC_SUBST([enable_conf], [${enable_conf:-auto}])
 111 AC_ARG_ENABLE(
 112     [mconf],
 113     [AS_HELP_STRING(
 114         [--disable-mconf],
 115         [mconf, the traditional ncurses-based frontend (default=auto)])])
 116 AC_SUBST([enable_mconf], [${enable_mconf:-auto}])
 117 AC_ARG_ENABLE(
 118     [nconf],
 119     [AS_HELP_STRING(
 120         [--disable-nconf],
 121         [nconf, the modern ncurses-based frontend (default=auto)])])
 122 AC_SUBST([enable_nconf], [${enable_nconf:-auto}])
 123 AC_ARG_ENABLE(
 124     [gconf],
 125     [AS_HELP_STRING(
 126         [--disable-gconf],
 127         [gconf, the GTK-based frontend (default=auto)])])
 128 AC_SUBST([enable_gconf], [${enable_gconf:-auto}])
 129 AC_ARG_ENABLE(
 130     [qconf],
 131     [AS_HELP_STRING(
 132         [--disable-qconf],
 133         [qconf, the QT-based frontend (default=auto)])])
 134 AC_SUBST([enable_qconf], [${enable_qconf:-auto}])
 135
 136 AC_ARG_ENABLE(
 137     [frontends],
 138     [AS_HELP_STRING(
 139         [--enable-frontends=list],
 140         [enables only the set of frontends in comma-separated 'list'
 141          (default: auto selection), takes precedence over all
 142          --enable-*conf, above])],
 143     [for f in conf mconf nconf gconf qconf; do
 144         AS_CASE(
 145             ["$enableval"],
 146             [yes],      [eval enable_$f=yes],
 147             ["$f"],     [eval enable_$f=yes],
 148             ["$f",*],   [eval enable_$f=yes],
 149             [*,"$f"],   [eval enable_$f=yes],
 150             [*,"$f",*], [eval enable_$f=yes],
 151                         [eval enable_$f=no])
 152      done])
 153 AC_SUBST([enable_frontends])
 154
 155 #----------------------------------------
 156 # What extra CFLAGS we will be using
 157 AC_SUBST([kf_CFLAGS], ["$wall_CFLAGS $werror_CFLAGS"])
 158
 159 #----------------------------------------
 160 # Dependencies that will be needed, depending on the frontends
 161 AS_CASE(
 162     ["$enable_mconf":"$enable_nconf"],
 163     [*yes*],  [need_curses=yes],
 164     [*auto*], [need_curses=auto],
 165               [need_curses=no])
 166 [need_panel_menu="$enable_nconf"]
 167 AS_CASE(
 168     ["$enable_gconf":"$enable_qconf"],
 169     [*yes*],  [need_pkgconfig=yes],
 170     [*auto*], [need_pkgconfig=yes],
 171               [need_pkgconfig=no ])
 172 [need_gtk="$enable_gconf"]
 173 [need_qt="$enable_qconf"]
 174
 175 #---------------------------------------------------------------------------
 176 # Now check we have the required stuff
 177
 178 #----------------------------------------
 179 # Some program checks
 180 AC_PROG_CC
 181 AM_PROG_CC_C_O
 182 AC_PROG_CXX
 183 AC_C_INLINE
 184 AC_PROG_MAKE_SET
 185 AC_CHECK_PROGS(
 186     [GPERF],
 187     [gperf])
 188 AS_IF(
 189     [test -z "$GPERF"],
 190     [AC_MSG_ERROR([can not find gperf])])
 191 AS_IF(
 192     [test "$need_pkgconfig" = "yes"],
 193     [PKG_PROG_PKG_CONFIG()])
 194 AC_PROG_LEX
 195 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
 196 AC_PROG_YACC
 197 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
 198
 199 #----------------------------------------
 200 # Check for standard headers
 201 AC_HEADER_STDC
 202 AC_HEADER_STDBOOL
 203 AC_CHECK_HEADERS([ fcntl.h limits.h locale.h ])
 204 AC_CHECK_HEADERS([ stdlib.h string.h sys/time.h unistd.h ])
 205 AC_TYPE_SIZE_T
 206
 207 #----------------------------------------
 208 # Checks for library functions.
 209 AC_FUNC_MALLOC
 210 AC_FUNC_REALLOC
 211 AC_FUNC_ALLOCA
 212 AC_CHECK_FUNCS([ bzero memmove memset ])
 213 AC_CHECK_FUNCS([ strcasecmp strchr strcspn strdup strncasecmp strpbrk strrchr strspn strtol ])
 214 AC_CHECK_FUNCS([ gettimeofday mkdir regcomp setlocale uname ])
 215
 216 #----------------------------------------
 217 # Check for gettext, for the kconfig frontends
 218 AC_SUBST([intl_CPPFLAGS])
 219 AC_CHECK_HEADERS(
 220     [libintl.h],
 221     [ac_ct_gettext_hdr=$ac_header; break],
 222     [AC_MSG_WARN([libintl is missing, frontends will not be localised])
 223      intl_CPPFLAGS=-DKBUILD_NO_NLS])
 224 AS_IF(
 225     [test -n "$ac_ct_gettext_hdr"],
 226     [AC_CHECK_DECL(
 227         [gettext],,
 228         [AC_MSG_WARN([gettext is missing, frontends will not be localised])
 229          intl_CPPFLAGS=-DKBUILD_NO_NLS],
 230         [#include <$ac_ct_gettext_hdr>])])
 231
 232 #----------------------------------------
 233 # Check for ncurses, for the mconf & nconf frontends
 234 AS_IF(
 235     [test "$need_curses" = "yes" -o "$need_curses" = "auto"],
 236     [AC_SUBST([CURSES_LOC])
 237      AC_SUBST([ncurses_LIBS])
 238      LIBS_old="$LIBS"
 239      LIBS=
 240      AC_CHECK_HEADERS(
 241         [ncurses/ncurses.h ncurses/curses.h ncursesw/curses.h ncurses.h curses.h],
 242         [CURSES_LOC=$ac_header; break])
 243      AS_IF(
 244         [test -z "$CURSES_LOC"],
 245         [AS_IF(
 246             [test "$need_curses" = "yes"],
 247             [AC_MSG_ERROR([could not find curses headers (frontends: mconf/nconf)])],
 248             [has_curses=no])])
 249      AC_SEARCH_LIBS(
 250         [initscr],
 251         [ncursesw ncurses curses],
 252         [ac_ct_curses_lib_found=yes; break])
 253      AS_IF(
 254         [test -z "$ac_ct_curses_lib_found"],
 255         [AS_IF(
 256             [test "$need_curses" = "yes"],
 257             [AC_MSG_ERROR([could not find curses library (frontends: mconf/nconf)])],
 258             [has_curses=no])])
 259      ncurses_LIBS="$LIBS"
 260      LIBS=$LIBS_old])
 261
 262 AS_IF(
 263     [test "$has_curses" = "no" ],
 264     [enable_mconf=no; enable_nconf=no])
 265
 266 #----------------------------------------
 267 # Check for libpanel and libmenu, for the nconf frontend
 268 AS_IF(
 269     [test "$need_panel_menu" = "yes" -o "$need_panel_menu" = "auto"],
 270     [AC_SUBST([ncurses_extra_LIBS])
 271      LIBS_old="$LIBS"
 272      LIBS=
 273      AC_SEARCH_LIBS(
 274         [new_panel],
 275         [panelw panel],
 276         [ac_ct_panel_lib_found=yes; break],,
 277         [$ncurses_LIBS])
 278      AS_IF(
 279         [test -z "$ac_ct_panel_lib_found"],
 280         [AS_IF(
 281             [test "$need_panel_menu" = "yes"],
 282             [AC_MSG_ERROR([could not find libpanel library (frontend: nconf)])],
 283             [has_panel_menu=no])])
 284      AC_SEARCH_LIBS(
 285         [menu_init],
 286         [menuw menu],
 287         [ac_ct_menu_lib_found=yes; break],,
 288         [$ncurses_LIBS])
 289      AS_IF(
 290         [test -z "$ac_ct_panel_lib_found"],
 291         [AS_IF(
 292             [test "$need_panel_menu" = "yes"],
 293             [AC_MSG_ERROR([could not find libmenu library (frontend: nconf)])],
 294             [has_panel_menu=no])])
 295      ncurses_extra_LIBS="$LIBS"
 296      LIBS=$LIBS_old])
 297
 298 AS_IF(
 299     [test "$has_panel_menu" = "no" ],
 300     [enable_nconf=no])
 301
 302 #----------------------------------------
 303 # Check headers and libs for gconf
 304 AS_IF(
 305     [test "$need_gtk" = "yes" -o "$need_gtk" = "auto"],
 306     [PKG_CHECK_MODULES(
 307         [gtk],
 308         [gtk+-2.0 gmodule-2.0 libglade-2.0],
 309         [has_gtk=yes],
 310         [AS_IF(
 311             [test "$need_gtk" = "yes"],
 312             [AC_MSG_ERROR([could not find GTK+ headers and/or libraries (frontend: gconf)])],
 313             [has_gtk=no])])])
 314
 315 AS_IF(
 316     [test "$has_gtk" = "no" ],
 317     [enable_gconf=no])
 318
 319 #----------------------------------------
 320 # Check headers and libs for qconf
 321 AS_IF(
 322     [test "$need_qt" = "yes" -o "$need_qt" = "auto"],
 323     [PKG_CHECK_MODULES(
 324         [qt4],
 325         [QtCore QtGui Qt3Support],
 326         [has_qt=yes; need_moc="$need_qt"],
 327         [AS_IF(
 328             [test "$need_qt" = "yes"],
 329             [AC_MSG_ERROR([could not find QT4 headers and/or libraries (frontend: qconf)])],
 330             [has_qt=no; need_moc=no])])])
 331
 332 AC_ARG_VAR([MOC], [Qt meta object compiler (moc) command])
 333 AS_IF(
 334     [test "$need_moc" = "yes" -o "$need_moc" = "auto"],
 335     [QT4_BINDIR=`$PKG_CONFIG Qt --variable bindir`
 336      AC_PATH_PROGS(
 337         [MOC],
 338         [moc-qt4 moc],,
 339         [$QT4_BINDIR:$PATH])
 340      AS_IF(
 341         [test -n "$MOC"],
 342         [has_moc=yes],
 343         [AS_IF(
 344             [test "$need_moc" = "yes"],
 345             [AC_MSG_ERROR([could not find moc (frontend: qconf)])],
 346             [has_moc=no])])])
 347
 348 AS_IF(
 349     [test "$has_qt" = "no" -o "$has_moc" = "no"],
 350     [enable_qconf=no])
 351
 352 #----------------------------------------
 353 # Per-frontends extra libraries
 354 AC_ARG_VAR([conf_EXTRA_LIBS],  [Extra libraries to build the conf frontend] )
 355 AC_ARG_VAR([gconf_EXTRA_LIBS], [Extra libraries to build the gconf frontend])
 356 AC_ARG_VAR([mconf_EXTRA_LIBS], [Extra libraries to build the mconf frontend])
 357 AC_ARG_VAR([nconf_EXTRA_LIBS], [Extra libraries to build the nconf frontend])
 358 AC_ARG_VAR([qconf_EXTRA_LIBS], [Extra libraries to build the qconf frontend])
 359
 360 #---------------------------------------------------------------------------
 361 # Now, we know what frontends to enable
 362 AS_IF([test "$enable_conf"  = "auto"], [enable_conf=yes ])
 363 AS_IF([test "$enable_gconf" = "auto"], [enable_gconf=yes])
 364 AS_IF([test "$enable_mconf" = "auto"], [enable_mconf=yes])
 365 AS_IF([test "$enable_nconf" = "auto"], [enable_nconf=yes])
 366 AS_IF([test "$enable_qconf" = "auto"], [enable_qconf=yes])
 367
 368 #----------------------------------------
 369 # Check if the lxdialog library should be built
 370 AS_IF(
 371     [test "$enable_mconf" = "yes"],
 372     [need_lxdialog=yes],
 373     [need_lxdialog=no])
 374
 375 #----------------------------------------
 376 # Check if the images library should be built
 377 AS_IF(
 378     [test "$enable_gconf" = "yes" -o "$enable_qconf" = "yes"],
 379     [need_images=yes],
 380     [need_images=no])
 381
 382 #----------------------------------------
 383 # Setup automake conditional build
 384 AM_CONDITIONAL(
 385     [COND_conf],
 386     [test "$enable_conf" = "yes"])
 387 AM_CONDITIONAL(
 388     [COND_mconf],
 389     [test "$enable_mconf" = "yes"])
 390 AM_CONDITIONAL(
 391     [COND_nconf],
 392     [test "$enable_nconf" = "yes"])
 393 AM_CONDITIONAL(
 394     [COND_gconf],
 395     [test "$enable_gconf" = "yes"])
 396 AM_CONDITIONAL(
 397     [COND_qconf],
 398     [test "$enable_qconf" = "yes"])
 399 AM_CONDITIONAL(
 400     [COND_lxdialog],
 401     [test "$need_lxdialog" = "yes"])
 402 AM_CONDITIONAL(
 403     [COND_images],
 404     [test "$need_images" = "yes"])
 405 AM_CONDITIONAL(
 406     [COND_utils],
 407     [test "$enable_utils" = "yes"])
 408
 409 #----------------------------------------
 410 # Get the version to apply to the parser shared library
 411 AC_SUBST(
 412     [KCONFIGPARSER_LIB_VERSION],
 413     [m4_esyscmd_s([./scripts/version.sh --plain])])
 414
 415 #----------------------------------------
 416 # Finalise
 417 AC_CONFIG_FILES([
 418     Makefile
 419     docs/Makefile
 420     libs/Makefile
 421     libs/images/Makefile
 422     libs/lxdialog/Makefile
 423     libs/parser/Makefile
 424     frontends/Makefile
 425     frontends/conf/Makefile
 426     frontends/mconf/Makefile
 427     frontends/nconf/Makefile
 428     frontends/gconf/Makefile
 429     frontends/qconf/Makefile
 430     utils/Makefile
 431     scripts/Makefile
 432 ])
 433 AC_OUTPUT
 434
 435 #----------------------------------------
 436 # Pretty-print the configuration settings
 437 [fe_list=]
 438 AS_IF([test "$enable_conf"  = "yes"], [fe_list="$fe_list conf" ])
 439 AS_IF([test "$enable_gconf" = "yes"], [fe_list="$fe_list gconf"])
 440 AS_IF([test "$enable_mconf" = "yes"], [fe_list="$fe_list mconf"])
 441 AS_IF([test "$enable_nconf" = "yes"], [fe_list="$fe_list nconf"])
 442 AS_IF([test "$enable_qconf" = "yes"], [fe_list="$fe_list qconf"])
 443
 444 [lib_list=]
 445 AS_IF(
 446     [test "$enable_shared" = "yes"],
 447     [lib_list="$lib_list shared (version: $KCONFIGPARSER_LIB_VERSION)"])
 448 AS_IF(
 449     [test "$enable_static" = "yes"],
 450     [lib_list="$lib_list${lib_list:+,} static"])
 451
 452 AC_MSG_NOTICE()
 453 AC_MSG_NOTICE([Configured with:])
 454 AC_MSG_NOTICE([- parser library     :$lib_list])
 455 AC_MSG_NOTICE([  - root-menu prompt : $root_menu])
 456 AC_MSG_NOTICE([  - config prefix    : $config_prefix])
 457 AC_MSG_NOTICE([- frontends          :$fe_list])
 458 AC_MSG_NOTICE([  - transform name   : $program_transform_name])
 459 AC_MSG_NOTICE([- install utilities  : $enable_utils])
 460 AC_MSG_NOTICE([- CFLAGS CXXFLAGS    : $wall_CFLAGS $werror_CFLAGS])