git.sur5r.net Git - kconfig-frontends/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #---------------------------------------------------------------------------
   5 # Global initialisation
   6
   7 #----------------------------------------
   8 # Prepare autoconf
   9 AC_PREREQ([2.67])
  10 AC_INIT(
  11     [kconfig-frontends],
  12     [m4_esyscmd_s([./scripts/version.sh])],
  13     [yann.morin.1998@free.fr])
  14 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
  15 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
  16 AC_CONFIG_HEADERS([scripts/.autostuff/config.h])
  17 AC_CONFIG_AUX_DIR([scripts/.autostuff/scripts])
  18 AC_CONFIG_MACRO_DIR([scripts/.autostuff/m4])
  19
  20 #----------------------------------------
  21 # Prepare automake
  22
  23 # We want to allow the user to override our default program-prefix,
  24 # so we must set-it now, before automake has a chance to interpret
  25 # it, but after the options are parsed, so as not to overwrite the
  26 # value (if any) set by the user
  27 AS_IF(
  28     [test "$program_prefix" = NONE],
  29     [program_prefix=kconfig-])
  30
  31 AM_INIT_AUTOMAKE([foreign])
  32
  33 # For releases, enable silent rules, unless the user explicitly
  34 # disables them.
  35 # For the devel tree, do build with verbose output, unless user
  36 # explicitly enables silent rules
  37 AS_IF(
  38     [test "$(${srcdir}/scripts/version.sh --internal)" = "git"],
  39     [AM_SILENT_RULES],
  40     [AM_SILENT_RULES([yes])])
  41
  42 AS_IF(
  43     [test $AM_DEFAULT_VERBOSITY -eq 0],
  44     [SILENT_MAKEFLAGS="--no-print-directory -s"],
  45     [SILENT_MAKEFLAGS=""])
  46 AC_SUBST([SILENT_MAKEFLAGS])
  47
  48 #----------------------------------------
  49 # Prepare libtool
  50 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl Automake, we have a problem...
  51 LT_PREREQ([2.2.6])
  52 LT_INIT([disable-static])
  53
  54 #---------------------------------------------------------------------------
  55 # Set misc options
  56
  57 # By default, do build with -Wall, unless the user asks not to
  58 [wall_CFLAGS=-Wall]
  59 AC_ARG_ENABLE(
  60     [wall],
  61     [AS_HELP_STRING(
  62         [--disable-wall],
  63         [build with -Wall (default=yes)])],
  64     [AS_CASE(
  65         ["$enableval"],
  66         [yes], [wall_CFLAGS=-Wall],
  67         [*],   [wall_CFLAGS=""])])
  68 AC_SUBST([wall_CFLAGS],[${wall_CFLAGS}])
  69
  70 # For releases, do not build with -Werror, unless the user explicitly
  71 # requests to build with -Werror.
  72 # For the devel tree, do build with -Werror by default, unless user
  73 # explicitly disables -Werror
  74 AS_IF(
  75     [test "$(${srcdir}/scripts/version.sh --internal)" = "git"],
  76     [werror_CFLAGS=-Werror])
  77 AC_ARG_ENABLE(
  78     [werror],
  79     [AS_HELP_STRING(
  80         [--enable-werror],
  81         [build with -Werror (default=no)])],
  82     [AS_CASE(
  83         ["$enableval"],
  84         [yes], [werror_CFLAGS=-Werror],
  85         [*],   [werror_CFLAGS=""])])
  86 AC_SUBST([werror_CFLAGS],[${werror_CFLAGS}])
  87
  88 # Although there is a default (="linux") in the code, we do provide
  89 # a default here, to get a consistent autostuff behavior
  90 AC_ARG_ENABLE(
  91     [root-menu-prompt],
  92     [AS_HELP_STRING(
  93         [--enable-root-menu-prompt=PROMPT],
  94         [set the root-menu prompt (default=Configuration)])],
  95     [AS_CASE(
  96         ["$enableval"],
  97         [yes], [root_menu=Configuration],
  98         [no],  [root_menu=],
  99                [# Escape the $ signs, otherwise they would get munged by make
 100                 root_menu="$( echo "$enableval" |sed -e 's/\$/\\$$/g;' )"])])
 101 AC_SUBST([root_menu], [${root_menu=Configuration}])
 102
 103 AC_ARG_ENABLE(
 104     [config-prefix],
 105     [AS_HELP_STRING(
 106         [--enable-config-prefix=PREFIX],
 107         [the prefix to the config option (default=CONFIG_)])],
 108     [AS_CASE(
 109         ["$enableval"],
 110         [*" "*],[AC_MSG_ERROR([config prefix can not contain spaces: '$enableval'])],
 111         [yes],  [config_prefix=CONFIG_],
 112         [no],   [config_prefix=],
 113                 [config_prefix=$enableval])])
 114 AC_SUBST([config_prefix], [${config_prefix-CONFIG_}])
 115
 116 AC_ARG_ENABLE(
 117     [utils],
 118     [AS_HELP_STRING(
 119         [--disable-utils],
 120         [install utilities to manage .config files (default=yes)])])
 121 AC_SUBST([enable_utils], [${enable_utils:-yes}])
 122
 123 AC_ARG_ENABLE(
 124     [L10n],
 125     [AS_HELP_STRING(
 126         [--disable-L10n],
 127         [enable localisation (L10n) (default=auto)])])
 128 AC_SUBST([enable_L10n], [${enable_L10n:-yes}])
 129
 130 #----------------------------------------
 131 # Options to selectively enable/disable frontends
 132 # All are selected by default
 133 AC_ARG_ENABLE(
 134     [conf],
 135     [AS_HELP_STRING(
 136         [--disable-conf],
 137         [conf, the stdin-based frontend (default=auto)])])
 138 AC_SUBST([enable_conf], [${enable_conf:-auto}])
 139 AC_ARG_ENABLE(
 140     [mconf],
 141     [AS_HELP_STRING(
 142         [--disable-mconf],
 143         [mconf, the traditional ncurses-based frontend (default=auto)])])
 144 AC_SUBST([enable_mconf], [${enable_mconf:-auto}])
 145 AC_ARG_ENABLE(
 146     [nconf],
 147     [AS_HELP_STRING(
 148         [--disable-nconf],
 149         [nconf, the modern ncurses-based frontend (default=auto)])])
 150 AC_SUBST([enable_nconf], [${enable_nconf:-auto}])
 151 AC_ARG_ENABLE(
 152     [gconf],
 153     [AS_HELP_STRING(
 154         [--disable-gconf],
 155         [gconf, the GTK-based frontend (default=auto)])])
 156 AC_SUBST([enable_gconf], [${enable_gconf:-auto}])
 157 AC_ARG_ENABLE(
 158     [qconf],
 159     [AS_HELP_STRING(
 160         [--disable-qconf],
 161         [qconf, the QT-based frontend (default=auto)])])
 162 AC_SUBST([enable_qconf], [${enable_qconf:-auto}])
 163
 164 AC_ARG_ENABLE(
 165     [frontends],
 166     [AS_HELP_STRING(
 167         [--enable-frontends=list],
 168         [enables only the set of frontends in comma-separated 'list'
 169          (default: auto selection), takes precedence over all
 170          --enable-*conf, above])],
 171     [for f in conf mconf nconf gconf qconf; do
 172         AS_CASE(
 173             ["$enableval"],
 174             [yes],      [eval enable_$f=yes],
 175             ["$f"],     [eval enable_$f=yes],
 176             ["$f",*],   [eval enable_$f=yes],
 177             [*,"$f"],   [eval enable_$f=yes],
 178             [*,"$f",*], [eval enable_$f=yes],
 179                         [eval enable_$f=no])
 180      done])
 181 AC_SUBST([enable_frontends])
 182
 183 #----------------------------------------
 184 # What extra CFLAGS we will be using
 185 AC_SUBST([kf_CFLAGS], ["$wall_CFLAGS $werror_CFLAGS"])
 186
 187 #----------------------------------------
 188 # Dependencies that will be needed, depending on the frontends
 189 AS_CASE(
 190     ["$enable_mconf":"$enable_nconf"],
 191     [*yes*],  [need_curses=yes],
 192     [*auto*], [need_curses=auto],
 193               [need_curses=no])
 194 [need_panel_menu="$enable_nconf"]
 195 AS_CASE(
 196     ["$enable_gconf":"$enable_qconf"],
 197     [*yes*],  [need_pkgconfig=yes],
 198     [*auto*], [need_pkgconfig=yes],
 199               [need_pkgconfig=no ])
 200 [need_gtk="$enable_gconf"]
 201 [need_qt="$enable_qconf"]
 202
 203 #---------------------------------------------------------------------------
 204 # Now check we have the required stuff
 205
 206 #----------------------------------------
 207 # Some program checks
 208 AC_PROG_CC
 209 AM_PROG_CC_C_O
 210 AC_PROG_CXX
 211 AC_C_INLINE
 212 AC_PROG_MAKE_SET
 213 AC_CHECK_PROGS(
 214     [GPERF],
 215     [gperf])
 216 AS_IF(
 217     [test -z "$GPERF"],
 218     [AC_MSG_ERROR([can not find gperf])])
 219 AS_IF(
 220     [test "$need_pkgconfig" = "yes"],
 221     [PKG_PROG_PKG_CONFIG()])
 222 # Look for `lex'. If it cannot be found, autoconf sets $LEX to ':'.
 223 AC_PROG_LEX
 224 AS_IF(
 225     [test "$LEX" = ":"],
 226     [AC_MSG_ERROR([can not find a lexer generator (such as lex or flex)])])
 227 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
 228 # Look for `yacc'. If it cannot be found, autoconf sets $YACC to 'yacc'.
 229 AC_PROG_YACC
 230 AS_IF(
 231     [test "$YACC" = "yacc"],
 232     [AC_CHECK_PROGS(
 233         [YACC_IN_PATH],
 234         [yacc])]
 235      AS_IF(
 236         [test -z "$YACC_IN_PATH"],
 237         [AC_MSG_ERROR([can not find a parser generator (such as yacc or bison)])]))
 238 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
 239
 240 #----------------------------------------
 241 # Check for gettext, for the kconfig frontends
 242 [has_gettext="$enable_L10n"]
 243 AS_IF(
 244     [test "$has_gettext" = "yes"],
 245     [AC_CHECK_HEADERS(
 246         [libintl.h],
 247         [ac_ct_gettext_hdr=$ac_header; break],
 248         [has_gettext=no])])
 249 AS_IF(
 250     [test "$has_gettext" = "yes"],
 251     [AC_CHECK_DECL(
 252         [gettext],,
 253         [has_gettext=no],
 254         [#include <$ac_ct_gettext_hdr>])])
 255 AS_IF(
 256     [test "$has_gettext" = "yes"],
 257     [LIBS_old="$LIBS"
 258      LIBS=
 259      AC_SEARCH_LIBS(
 260         [gettext],
 261         [intl],,
 262         [has_gettext=no])
 263     intl_LIBS="$LIBS"
 264     LIBS="$LIBS_old"])
 265 AS_IF(
 266     [test "$has_gettext" = "no"],
 267     [intl_CPPFLAGS=-DKBUILD_NO_NLS])
 268 AC_SUBST([intl_CPPFLAGS])
 269 AC_SUBST([intl_LIBS])
 270
 271 #----------------------------------------
 272 # Check for ncurses, for the mconf & nconf frontends
 273 AS_IF(
 274     [test "$need_curses" = "yes" -o "$need_curses" = "auto"],
 275     [AC_SUBST([ncurses_mconf_CPPFLAGS])
 276      AC_SUBST([ncurses_LIBS])
 277      LIBS_old="$LIBS"
 278      LIBS=
 279      AC_CHECK_HEADERS(
 280         [ncursesw/curses.h ncurses/ncurses.h ncurses/curses.h ncurses.h curses.h],
 281         [CURSES_LOC=$ac_header
 282          ncurses_mconf_CPPFLAGS=-DCURSES_LOC=\\\"$ac_header\\\"
 283          break # Stupid syntax-coloring in vim: "])
 284      AS_IF(
 285         [test -z "$CURSES_LOC"],
 286         [AS_IF(
 287             [test "$need_curses" = "yes"],
 288             [AC_MSG_ERROR([could not find curses headers (frontends: mconf/nconf)])],
 289             [has_curses=no])])
 290      AS_CASE(
 291         [$CURSES_LOC],
 292         [ncursesw/*],[ncurses_mconf_CPPFLAGS="$ncurses_mconf_CPPFLAGS -DNCURSES_WIDECHAR=1"])
 293      AC_SEARCH_LIBS(
 294         [setupterm],
 295         [tinfo],
 296         [break])
 297      AC_SEARCH_LIBS(
 298         [initscr],
 299         [ncursesw ncurses curses],
 300         [ac_ct_curses_lib_found=yes; break])
 301      AS_IF(
 302         [test -z "$ac_ct_curses_lib_found"],
 303         [AS_IF(
 304             [test "$need_curses" = "yes"],
 305             [AC_MSG_ERROR([could not find curses library (frontends: mconf/nconf)])],
 306             [has_curses=no])])
 307      ncurses_LIBS="$LIBS"
 308      LIBS=$LIBS_old])
 309
 310 AS_IF(
 311     [test "$has_curses" = "no" ],
 312     [enable_mconf=no; enable_nconf=no])
 313
 314 #----------------------------------------
 315 # Check for libpanel and libmenu, for the nconf frontend
 316 AS_IF(
 317     [test "$need_panel_menu" = "yes" -o "$need_panel_menu" = "auto"],
 318     [AC_SUBST([ncurses_nconf_CPPFLAGS])
 319      AC_SUBST([ncurses_panel_menu_LIBS])
 320      AS_CASE(
 321         [$CURSES_LOC],
 322         [ncursesw/*],[ncurses_nconf_CPPFLAGS="-I/usr/include/ncursesw"],
 323         [ncurses/*],[ncurses_nconf_CPPFLAGS="-I/usr/include/ncurses"])
 324      LIBS_old="$LIBS"
 325      LIBS=
 326      AC_SEARCH_LIBS(
 327         [new_panel],
 328         [panelw panel],
 329         [ac_ct_panel_lib_found=yes; break],,
 330         [$ncurses_LIBS])
 331      AS_IF(
 332         [test -z "$ac_ct_panel_lib_found"],
 333         [AS_IF(
 334             [test "$need_panel_menu" = "yes"],
 335             [AC_MSG_ERROR([could not find libpanel library (frontend: nconf)])],
 336             [has_panel_menu=no])])
 337      AC_SEARCH_LIBS(
 338         [menu_init],
 339         [menuw menu],
 340         [ac_ct_menu_lib_found=yes; break],,
 341         [$ncurses_LIBS])
 342      AS_IF(
 343         [test -z "$ac_ct_panel_lib_found"],
 344         [AS_IF(
 345             [test "$need_panel_menu" = "yes"],
 346             [AC_MSG_ERROR([could not find libmenu library (frontend: nconf)])],
 347             [has_panel_menu=no])])
 348      ncurses_panel_menu_LIBS="$LIBS"
 349      LIBS=$LIBS_old])
 350
 351 AS_IF(
 352     [test "$has_panel_menu" = "no" ],
 353     [enable_nconf=no])
 354
 355 #----------------------------------------
 356 # Check headers and libs for gconf
 357 AS_IF(
 358     [test "$need_gtk" = "yes" -o "$need_gtk" = "auto"],
 359     [PKG_CHECK_MODULES(
 360         [gtk],
 361         [gtk+-2.0 gmodule-2.0 libglade-2.0],
 362         [has_gtk=yes],
 363         [AS_IF(
 364             [test "$need_gtk" = "yes"],
 365             [AC_MSG_ERROR([could not find GTK+ headers and/or libraries (frontend: gconf)])],
 366             [has_gtk=no])])])
 367
 368 AS_IF(
 369     [test "$has_gtk" = "no" ],
 370     [enable_gconf=no])
 371
 372 #----------------------------------------
 373 # Check headers and libs for qconf
 374 AS_IF(
 375     [test "$need_qt" = "yes" -o "$need_qt" = "auto"],
 376     [PKG_CHECK_MODULES(
 377         [Qt5],
 378         [Qt5Core Qt5Gui Qt5Widgets],
 379         [has_qt=yes; need_moc="$need_qt"],
 380         [AS_IF(
 381             [test "$need_qt" = "yes"],
 382             [AC_MSG_ERROR([could not find Qt5 headers and/or libraries (frontend: qconf)])],
 383             [has_qt=no; need_moc=no])])])
 384
 385 AC_ARG_VAR([MOC], [Qt5 meta object compiler (moc) command])
 386 AS_IF(
 387     [test "$need_moc" = "yes" -o "$need_moc" = "auto"],
 388     [QT5_BINDIR=`$PKG_CONFIG Qt5Core --variable host_bins`
 389      AC_PATH_PROGS(
 390         [MOC],
 391         [moc-qt5 moc],,
 392         [$QT5_BINDIR:$PATH])
 393      AS_IF(
 394         [test -n "$MOC"],
 395         [has_moc=yes],
 396         [AS_IF(
 397             [test "$need_moc" = "yes"],
 398             [AC_MSG_ERROR([could not find moc (frontend: qconf)])],
 399             [has_moc=no])])])
 400
 401 AS_IF(
 402     [test "$has_qt" = "no" -o "$has_moc" = "no"],
 403     [enable_qconf=no])
 404
 405 #----------------------------------------
 406 # Per-frontends extra libraries
 407 AC_ARG_VAR([conf_EXTRA_LIBS],  [Extra libraries to build the conf frontend] )
 408 AC_ARG_VAR([gconf_EXTRA_LIBS], [Extra libraries to build the gconf frontend])
 409 AC_ARG_VAR([mconf_EXTRA_LIBS], [Extra libraries to build the mconf frontend])
 410 AC_ARG_VAR([nconf_EXTRA_LIBS], [Extra libraries to build the nconf frontend])
 411 AC_ARG_VAR([qconf_EXTRA_LIBS], [Extra libraries to build the qconf frontend])
 412
 413 #---------------------------------------------------------------------------
 414 # Now, we know what frontends to enable
 415 AS_IF([test "$enable_conf"  = "auto"], [enable_conf=yes ])
 416 AS_IF([test "$enable_gconf" = "auto"], [enable_gconf=yes])
 417 AS_IF([test "$enable_mconf" = "auto"], [enable_mconf=yes])
 418 AS_IF([test "$enable_nconf" = "auto"], [enable_nconf=yes])
 419 AS_IF([test "$enable_qconf" = "auto"], [enable_qconf=yes])
 420
 421 #----------------------------------------
 422 # Check if the lxdialog library should be built
 423 AS_IF(
 424     [test "$enable_mconf" = "yes"],
 425     [need_lxdialog=yes],
 426     [need_lxdialog=no])
 427
 428 #----------------------------------------
 429 # Check if the images library should be built
 430 AS_IF(
 431     [test "$enable_gconf" = "yes" -o "$enable_qconf" = "yes"],
 432     [need_images=yes],
 433     [need_images=no])
 434
 435 #----------------------------------------
 436 # Setup automake conditional build
 437 AM_CONDITIONAL(
 438     [COND_conf],
 439     [test "$enable_conf" = "yes"])
 440 AM_CONDITIONAL(
 441     [COND_mconf],
 442     [test "$enable_mconf" = "yes"])
 443 AM_CONDITIONAL(
 444     [COND_nconf],
 445     [test "$enable_nconf" = "yes"])
 446 AM_CONDITIONAL(
 447     [COND_gconf],
 448     [test "$enable_gconf" = "yes"])
 449 AM_CONDITIONAL(
 450     [COND_qconf],
 451     [test "$enable_qconf" = "yes"])
 452 AM_CONDITIONAL(
 453     [COND_lxdialog],
 454     [test "$need_lxdialog" = "yes"])
 455 AM_CONDITIONAL(
 456     [COND_images],
 457     [test "$need_images" = "yes"])
 458 AM_CONDITIONAL(
 459     [COND_utils],
 460     [test "$enable_utils" = "yes"])
 461 AM_CONDITIONAL(
 462     [COND_utils_gettext],
 463     [test "$has_gettext" = "yes"])
 464
 465 #----------------------------------------
 466 # Get the version to apply to the parser shared library
 467 AC_SUBST(
 468     [KCONFIGPARSER_LIB_VERSION],
 469     [m4_esyscmd_s([./scripts/version.sh --plain])])
 470
 471 #----------------------------------------
 472 # Finalise
 473 AC_CONFIG_FILES([
 474     Makefile
 475     docs/Makefile
 476     libs/Makefile
 477     libs/images/Makefile
 478     libs/lxdialog/Makefile
 479     libs/parser/Makefile
 480     frontends/Makefile
 481     frontends/conf/Makefile
 482     frontends/mconf/Makefile
 483     frontends/nconf/Makefile
 484     frontends/gconf/Makefile
 485     frontends/qconf/Makefile
 486     utils/Makefile
 487     scripts/Makefile
 488 ])
 489 AC_OUTPUT
 490
 491 #----------------------------------------
 492 # Pretty-print the configuration settings
 493 [fe_list=]
 494 AS_IF([test "$enable_conf"  = "yes"], [fe_list="$fe_list conf" ])
 495 AS_IF([test "$enable_gconf" = "yes"], [fe_list="$fe_list gconf"])
 496 AS_IF([test "$enable_mconf" = "yes"], [fe_list="$fe_list mconf"])
 497 AS_IF([test "$enable_nconf" = "yes"], [fe_list="$fe_list nconf"])
 498 AS_IF([test "$enable_qconf" = "yes"], [fe_list="$fe_list qconf"])
 499
 500 [lib_list=]
 501 AS_IF(
 502     [test "$enable_shared" = "yes"],
 503     [lib_list="$lib_list shared (version: $KCONFIGPARSER_LIB_VERSION)"])
 504 AS_IF(
 505     [test "$enable_static" = "yes"],
 506     [lib_list="$lib_list${lib_list:+,} static"])
 507
 508 AC_MSG_NOTICE()
 509 AC_MSG_NOTICE([Configured with:])
 510 AC_MSG_NOTICE([- parser library     :$lib_list])
 511 AC_MSG_NOTICE([  - root-menu prompt : $root_menu])
 512 AC_MSG_NOTICE([  - config prefix    : $config_prefix])
 513 AC_MSG_NOTICE([- frontends          :$fe_list])
 514 AC_MSG_NOTICE([  - transform name   : $program_transform_name])
 515 AC_MSG_NOTICE([  - localised        : $has_gettext])
 516 AC_MSG_NOTICE([- install utilities  : $enable_utils])
 517 AC_MSG_NOTICE([- CFLAGS CXXFLAGS    : $wall_CFLAGS $werror_CFLAGS])