git.sur5r.net Git - kconfig-frontends/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #---------------------------------------------------------------------------
   5 # Global initialisation
   6
   7 #----------------------------------------
   8 # Prepare autoconf
   9 AC_PREREQ([2.67])
  10 AC_INIT(
  11     [kconfig-frontends],
  12     [m4_esyscmd_s([./scripts/version.sh])],
  13     [yann.morin.1998@free.fr])
  14 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
  15 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
  16 AC_CONFIG_HEADERS([scripts/.autostuff/config.h])
  17 AC_CONFIG_AUX_DIR([scripts/.autostuff/scripts])
  18 AC_CONFIG_MACRO_DIR([scripts/.autostuff/m4])
  19
  20 #----------------------------------------
  21 # Prepare automake
  22
  23 # We want to allow the user to override our default program-prefix,
  24 # so we must set-it now, before automake has a chance to interpret
  25 # it, but after the options are parsed, so as not to overwrite the
  26 # value (if any) set by the user
  27 AS_IF(
  28     [test "$program_prefix" = NONE],
  29     [program_prefix=kconfig-])
  30
  31 AM_INIT_AUTOMAKE
  32
  33 AS_IF(
  34     [test "$(${srcdir}/scripts/version.sh --internal)" = "hg"],
  35     [AM_SILENT_RULES],
  36     [AM_SILENT_RULES([yes])])
  37
  38 AS_IF(
  39     [test $AM_DEFAULT_VERBOSITY -eq 0],
  40     [SILENT_MAKEFLAGS="--no-print-directory -s"],
  41     [SILENT_MAKEFLAGS=""])
  42 AC_SUBST([SILENT_MAKEFLAGS])
  43
  44 #----------------------------------------
  45 # Prepare libtool
  46 LT_PREREQ([2.2.6])
  47 LT_INIT([disable-static])
  48
  49 #---------------------------------------------------------------------------
  50 # Set misc options
  51
  52 # By default, do not build with -Wall, unless the user asks for it
  53 AC_ARG_ENABLE(
  54     [wall],
  55     [AS_HELP_STRING(
  56         [--enable-wall],
  57         [build with -Wall (default=no)])],
  58     [AS_CASE(
  59         ["$enableval"],
  60         [yes], [wall_CFLAGS=-Wall],
  61         [*],   [wall_CFLAGS=""])])
  62 AC_SUBST([wall_CFLAGS],[${wall_CFLAGS}])
  63
  64 # By default, do not build with -Werror, unless the user asks for it
  65 AC_ARG_ENABLE(
  66     [werror],
  67     [AS_HELP_STRING(
  68         [--enable-werror],
  69         [build with -Werror (default=no)])],
  70     [AS_CASE(
  71         ["$enableval"],
  72         [yes], [werror_CFLAGS=-Werror],
  73         [*],   [werror_CFLAGS=""])])
  74 AC_SUBST([werror_CFLAGS],[${werror_CFLAGS}])
  75
  76 # Although there is a default (="linux") in the code, we do provide
  77 # a default here, to get a consistent autostuff behavior
  78 AC_ARG_ENABLE(
  79     [root-menu-prompt],
  80     [AS_HELP_STRING(
  81         [--enable-root-menu-prompt=PROMPT],
  82         [set the root-menu prompt (default=Configuration)])],
  83     [AS_CASE(
  84         ["$enableval"],
  85         [yes], [root_menu=Configuration],
  86         [no],  [root_menu=],
  87                [# Escape the $ signs, otherwise they would get munged by make
  88                 # Also, append a space at the end, to separate the package
  89                 # name from the literal 'Configuration'
  90                 root_menu="$( echo "$enableval" |sed -r -e 's/\$/\\$$/g;' )"])])
  91 AC_SUBST([root_menu], [${root_menu=Configuration}])
  92
  93 AC_ARG_ENABLE(
  94     [config-prefix],
  95     [AS_HELP_STRING(
  96         [--enable-config-prefix=PREFIX],
  97         [the prefix to the config option (default=CONFIG_)])],
  98     [AS_CASE(
  99         ["$enableval"],
 100         [*" "*],[AC_MSG_ERROR([config prefix can not contain spaces: '$enableval'])],
 101         [yes],  [config_prefix=CONFIG_],
 102         [no],   [config_prefix=],
 103                 [config_prefix=$enableval])])
 104 AC_SUBST([config_prefix], [${config_prefix-CONFIG_}])
 105
 106 AC_ARG_ENABLE(
 107     [utils],
 108     [AS_HELP_STRING(
 109         [--disable-utils],
 110         [install utilities to manage .config files (default=no)])])
 111 AC_SUBST([enable_utils], [${enable_utils:-yes}])
 112
 113 AC_ARG_ENABLE(
 114     [L10n],
 115     [AS_HELP_STRING(
 116         [--disable-L10n],
 117         [enable localisation (L10n) (default=auto)])])
 118 AC_SUBST([enable_L10n], [${enable_L10n:-yes}])
 119
 120 #----------------------------------------
 121 # Options to selectively enable/disable frontends
 122 # All are selected by default
 123 AC_ARG_ENABLE(
 124     [conf],
 125     [AS_HELP_STRING(
 126         [--disable-conf],
 127         [conf, the stdin-based frontend (default=auto)])])
 128 AC_SUBST([enable_conf], [${enable_conf:-auto}])
 129 AC_ARG_ENABLE(
 130     [mconf],
 131     [AS_HELP_STRING(
 132         [--disable-mconf],
 133         [mconf, the traditional ncurses-based frontend (default=auto)])])
 134 AC_SUBST([enable_mconf], [${enable_mconf:-auto}])
 135 AC_ARG_ENABLE(
 136     [nconf],
 137     [AS_HELP_STRING(
 138         [--disable-nconf],
 139         [nconf, the modern ncurses-based frontend (default=auto)])])
 140 AC_SUBST([enable_nconf], [${enable_nconf:-auto}])
 141 AC_ARG_ENABLE(
 142     [gconf],
 143     [AS_HELP_STRING(
 144         [--disable-gconf],
 145         [gconf, the GTK-based frontend (default=auto)])])
 146 AC_SUBST([enable_gconf], [${enable_gconf:-auto}])
 147 AC_ARG_ENABLE(
 148     [qconf],
 149     [AS_HELP_STRING(
 150         [--disable-qconf],
 151         [qconf, the QT-based frontend (default=auto)])])
 152 AC_SUBST([enable_qconf], [${enable_qconf:-auto}])
 153
 154 AC_ARG_ENABLE(
 155     [frontends],
 156     [AS_HELP_STRING(
 157         [--enable-frontends=list],
 158         [enables only the set of frontends in comma-separated 'list'
 159          (default: auto selection), takes precedence over all
 160          --enable-*conf, above])],
 161     [for f in conf mconf nconf gconf qconf; do
 162         AS_CASE(
 163             ["$enableval"],
 164             [yes],      [eval enable_$f=yes],
 165             ["$f"],     [eval enable_$f=yes],
 166             ["$f",*],   [eval enable_$f=yes],
 167             [*,"$f"],   [eval enable_$f=yes],
 168             [*,"$f",*], [eval enable_$f=yes],
 169                         [eval enable_$f=no])
 170      done])
 171 AC_SUBST([enable_frontends])
 172
 173 #----------------------------------------
 174 # What extra CFLAGS we will be using
 175 AC_SUBST([kf_CFLAGS], ["$wall_CFLAGS $werror_CFLAGS"])
 176
 177 #----------------------------------------
 178 # Dependencies that will be needed, depending on the frontends
 179 AS_CASE(
 180     ["$enable_mconf":"$enable_nconf"],
 181     [*yes*],  [need_curses=yes],
 182     [*auto*], [need_curses=auto],
 183               [need_curses=no])
 184 [need_panel_menu="$enable_nconf"]
 185 AS_CASE(
 186     ["$enable_gconf":"$enable_qconf"],
 187     [*yes*],  [need_pkgconfig=yes],
 188     [*auto*], [need_pkgconfig=yes],
 189               [need_pkgconfig=no ])
 190 [need_gtk="$enable_gconf"]
 191 [need_qt="$enable_qconf"]
 192
 193 #---------------------------------------------------------------------------
 194 # Now check we have the required stuff
 195
 196 #----------------------------------------
 197 # Some program checks
 198 AC_PROG_CC
 199 AM_PROG_CC_C_O
 200 AC_PROG_CXX
 201 AC_C_INLINE
 202 AC_PROG_MAKE_SET
 203 AC_CHECK_PROGS(
 204     [GPERF],
 205     [gperf])
 206 AS_IF(
 207     [test -z "$GPERF"],
 208     [AC_MSG_ERROR([can not find gperf])])
 209 AS_IF(
 210     [test "$need_pkgconfig" = "yes"],
 211     [PKG_PROG_PKG_CONFIG()])
 212 AC_PROG_LEX
 213 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
 214 AC_PROG_YACC
 215 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
 216
 217 #----------------------------------------
 218 # Check for standard headers
 219 AC_HEADER_STDC
 220 AC_HEADER_STDBOOL
 221 AC_CHECK_HEADERS([ fcntl.h limits.h locale.h ])
 222 AC_CHECK_HEADERS([ stdlib.h string.h sys/time.h unistd.h ])
 223 AC_TYPE_SIZE_T
 224
 225 #----------------------------------------
 226 # Checks for library functions.
 227 AC_FUNC_MALLOC
 228 AC_FUNC_REALLOC
 229 AC_FUNC_ALLOCA
 230 AC_CHECK_FUNCS([ bzero memmove memset ])
 231 AC_CHECK_FUNCS([ strcasecmp strchr strcspn strdup strncasecmp strpbrk strrchr strspn strtol ])
 232 AC_CHECK_FUNCS([ gettimeofday mkdir regcomp setlocale uname ])
 233
 234 #----------------------------------------
 235 # Check for gettext, for the kconfig frontends
 236 [has_gettext="$enable_L10n"]
 237 AS_IF(
 238     [test "$has_gettext" = "yes"],
 239     [AC_CHECK_HEADERS(
 240         [libintl.h],
 241         [ac_ct_gettext_hdr=$ac_header; break],
 242         [has_gettext=no])])
 243 AS_IF(
 244     [test "$has_gettext" = "yes"],
 245     [AC_CHECK_DECL(
 246         [gettext],,
 247         [has_gettext=no],
 248         [#include <$ac_ct_gettext_hdr>])])
 249 AS_IF(
 250     [test "$has_gettext" = "yes"],
 251     [LIBS_old="$LIBS"
 252      LIBS=
 253      AC_SEARCH_LIBS(
 254         [gettext],
 255         [intl],,
 256         [has_gettext=no])
 257     intl_LIBS="$LIBS"
 258     LIBS="$LIBS_old"])
 259 AS_IF(
 260     [test "$has_gettext" = "no"],
 261     [intl_CPPFLAGS=-DKBUILD_NO_NLS])
 262 AC_SUBST([intl_CPPFLAGS])
 263 AC_SUBST([intl_LIBS])
 264
 265 #----------------------------------------
 266 # Check for ncurses, for the mconf & nconf frontends
 267 AS_IF(
 268     [test "$need_curses" = "yes" -o "$need_curses" = "auto"],
 269     [AC_SUBST([CURSES_LOC])
 270      AC_SUBST([ncurses_LIBS])
 271      LIBS_old="$LIBS"
 272      LIBS=
 273      AC_CHECK_HEADERS(
 274         [ncursesw/curses.h ncurses/ncurses.h ncurses/curses.h ncurses.h curses.h],
 275         [CURSES_LOC=$ac_header; break])
 276      AS_IF(
 277         [test -z "$CURSES_LOC"],
 278         [AS_IF(
 279             [test "$need_curses" = "yes"],
 280             [AC_MSG_ERROR([could not find curses headers (frontends: mconf/nconf)])],
 281             [has_curses=no])])
 282      AC_SEARCH_LIBS(
 283         [initscr],
 284         [ncursesw ncurses curses],
 285         [ac_ct_curses_lib_found=yes; break])
 286      AS_IF(
 287         [test -z "$ac_ct_curses_lib_found"],
 288         [AS_IF(
 289             [test "$need_curses" = "yes"],
 290             [AC_MSG_ERROR([could not find curses library (frontends: mconf/nconf)])],
 291             [has_curses=no])])
 292      ncurses_LIBS="$LIBS"
 293      LIBS=$LIBS_old])
 294
 295 AS_IF(
 296     [test "$has_curses" = "no" ],
 297     [enable_mconf=no; enable_nconf=no])
 298
 299 #----------------------------------------
 300 # Check for libpanel and libmenu, for the nconf frontend
 301 AS_IF(
 302     [test "$need_panel_menu" = "yes" -o "$need_panel_menu" = "auto"],
 303     [AC_SUBST([ncurses_extra_LIBS])
 304      AC_SUBST([ncurses_extra_CPPFLAGS])
 305      AS_CASE(
 306         [$CURSES_LOC],
 307         [ncursesw/*],[ncurses_extra_CPPFLAGS="-I/usr/include/ncursesw"],
 308         [ncurses/*],[ncurses_extra_CPPFLAGS="-I/usr/include/ncurses"])
 309      LIBS_old="$LIBS"
 310      LIBS=
 311      AC_SEARCH_LIBS(
 312         [new_panel],
 313         [panelw panel],
 314         [ac_ct_panel_lib_found=yes; break],,
 315         [$ncurses_LIBS])
 316      AS_IF(
 317         [test -z "$ac_ct_panel_lib_found"],
 318         [AS_IF(
 319             [test "$need_panel_menu" = "yes"],
 320             [AC_MSG_ERROR([could not find libpanel library (frontend: nconf)])],
 321             [has_panel_menu=no])])
 322      AC_SEARCH_LIBS(
 323         [menu_init],
 324         [menuw menu],
 325         [ac_ct_menu_lib_found=yes; break],,
 326         [$ncurses_LIBS])
 327      AS_IF(
 328         [test -z "$ac_ct_panel_lib_found"],
 329         [AS_IF(
 330             [test "$need_panel_menu" = "yes"],
 331             [AC_MSG_ERROR([could not find libmenu library (frontend: nconf)])],
 332             [has_panel_menu=no])])
 333      ncurses_extra_LIBS="$LIBS"
 334      LIBS=$LIBS_old])
 335
 336 AS_IF(
 337     [test "$has_panel_menu" = "no" ],
 338     [enable_nconf=no])
 339
 340 #----------------------------------------
 341 # Check headers and libs for gconf
 342 AS_IF(
 343     [test "$need_gtk" = "yes" -o "$need_gtk" = "auto"],
 344     [PKG_CHECK_MODULES(
 345         [gtk],
 346         [gtk+-2.0 gmodule-2.0 libglade-2.0],
 347         [has_gtk=yes],
 348         [AS_IF(
 349             [test "$need_gtk" = "yes"],
 350             [AC_MSG_ERROR([could not find GTK+ headers and/or libraries (frontend: gconf)])],
 351             [has_gtk=no])])])
 352
 353 AS_IF(
 354     [test "$has_gtk" = "no" ],
 355     [enable_gconf=no])
 356
 357 #----------------------------------------
 358 # Check headers and libs for qconf
 359 AS_IF(
 360     [test "$need_qt" = "yes" -o "$need_qt" = "auto"],
 361     [PKG_CHECK_MODULES(
 362         [qt4],
 363         [QtCore QtGui Qt3Support],
 364         [has_qt=yes; need_moc="$need_qt"],
 365         [AS_IF(
 366             [test "$need_qt" = "yes"],
 367             [AC_MSG_ERROR([could not find QT4 headers and/or libraries (frontend: qconf)])],
 368             [has_qt=no; need_moc=no])])])
 369
 370 AC_ARG_VAR([MOC], [Qt meta object compiler (moc) command])
 371 AS_IF(
 372     [test "$need_moc" = "yes" -o "$need_moc" = "auto"],
 373     [QT4_BINDIR=`$PKG_CONFIG Qt --variable bindir`
 374      AC_PATH_PROGS(
 375         [MOC],
 376         [moc-qt4 moc],,
 377         [$QT4_BINDIR:$PATH])
 378      AS_IF(
 379         [test -n "$MOC"],
 380         [has_moc=yes],
 381         [AS_IF(
 382             [test "$need_moc" = "yes"],
 383             [AC_MSG_ERROR([could not find moc (frontend: qconf)])],
 384             [has_moc=no])])])
 385
 386 AS_IF(
 387     [test "$has_qt" = "no" -o "$has_moc" = "no"],
 388     [enable_qconf=no])
 389
 390 #----------------------------------------
 391 # Per-frontends extra libraries
 392 AC_ARG_VAR([conf_EXTRA_LIBS],  [Extra libraries to build the conf frontend] )
 393 AC_ARG_VAR([gconf_EXTRA_LIBS], [Extra libraries to build the gconf frontend])
 394 AC_ARG_VAR([mconf_EXTRA_LIBS], [Extra libraries to build the mconf frontend])
 395 AC_ARG_VAR([nconf_EXTRA_LIBS], [Extra libraries to build the nconf frontend])
 396 AC_ARG_VAR([qconf_EXTRA_LIBS], [Extra libraries to build the qconf frontend])
 397
 398 #---------------------------------------------------------------------------
 399 # Now, we know what frontends to enable
 400 AS_IF([test "$enable_conf"  = "auto"], [enable_conf=yes ])
 401 AS_IF([test "$enable_gconf" = "auto"], [enable_gconf=yes])
 402 AS_IF([test "$enable_mconf" = "auto"], [enable_mconf=yes])
 403 AS_IF([test "$enable_nconf" = "auto"], [enable_nconf=yes])
 404 AS_IF([test "$enable_qconf" = "auto"], [enable_qconf=yes])
 405
 406 #----------------------------------------
 407 # Check if the lxdialog library should be built
 408 AS_IF(
 409     [test "$enable_mconf" = "yes"],
 410     [need_lxdialog=yes],
 411     [need_lxdialog=no])
 412
 413 #----------------------------------------
 414 # Check if the images library should be built
 415 AS_IF(
 416     [test "$enable_gconf" = "yes" -o "$enable_qconf" = "yes"],
 417     [need_images=yes],
 418     [need_images=no])
 419
 420 #----------------------------------------
 421 # Setup automake conditional build
 422 AM_CONDITIONAL(
 423     [COND_conf],
 424     [test "$enable_conf" = "yes"])
 425 AM_CONDITIONAL(
 426     [COND_mconf],
 427     [test "$enable_mconf" = "yes"])
 428 AM_CONDITIONAL(
 429     [COND_nconf],
 430     [test "$enable_nconf" = "yes"])
 431 AM_CONDITIONAL(
 432     [COND_gconf],
 433     [test "$enable_gconf" = "yes"])
 434 AM_CONDITIONAL(
 435     [COND_qconf],
 436     [test "$enable_qconf" = "yes"])
 437 AM_CONDITIONAL(
 438     [COND_lxdialog],
 439     [test "$need_lxdialog" = "yes"])
 440 AM_CONDITIONAL(
 441     [COND_images],
 442     [test "$need_images" = "yes"])
 443 AM_CONDITIONAL(
 444     [COND_utils],
 445     [test "$enable_utils" = "yes"])
 446 AM_CONDITIONAL(
 447     [COND_utils_gettext],
 448     [test "$has_gettext" = "yes"])
 449
 450 #----------------------------------------
 451 # Get the version to apply to the parser shared library
 452 AC_SUBST(
 453     [KCONFIGPARSER_LIB_VERSION],
 454     [m4_esyscmd_s([./scripts/version.sh --plain])])
 455
 456 #----------------------------------------
 457 # Finalise
 458 AC_CONFIG_FILES([
 459     Makefile
 460     docs/Makefile
 461     libs/Makefile
 462     libs/images/Makefile
 463     libs/lxdialog/Makefile
 464     libs/parser/Makefile
 465     frontends/Makefile
 466     frontends/conf/Makefile
 467     frontends/mconf/Makefile
 468     frontends/nconf/Makefile
 469     frontends/gconf/Makefile
 470     frontends/qconf/Makefile
 471     utils/Makefile
 472     scripts/Makefile
 473 ])
 474 AC_OUTPUT
 475
 476 #----------------------------------------
 477 # Pretty-print the configuration settings
 478 [fe_list=]
 479 AS_IF([test "$enable_conf"  = "yes"], [fe_list="$fe_list conf" ])
 480 AS_IF([test "$enable_gconf" = "yes"], [fe_list="$fe_list gconf"])
 481 AS_IF([test "$enable_mconf" = "yes"], [fe_list="$fe_list mconf"])
 482 AS_IF([test "$enable_nconf" = "yes"], [fe_list="$fe_list nconf"])
 483 AS_IF([test "$enable_qconf" = "yes"], [fe_list="$fe_list qconf"])
 484
 485 [lib_list=]
 486 AS_IF(
 487     [test "$enable_shared" = "yes"],
 488     [lib_list="$lib_list shared (version: $KCONFIGPARSER_LIB_VERSION)"])
 489 AS_IF(
 490     [test "$enable_static" = "yes"],
 491     [lib_list="$lib_list${lib_list:+,} static"])
 492
 493 AC_MSG_NOTICE()
 494 AC_MSG_NOTICE([Configured with:])
 495 AC_MSG_NOTICE([- parser library     :$lib_list])
 496 AC_MSG_NOTICE([  - root-menu prompt : $root_menu])
 497 AC_MSG_NOTICE([  - config prefix    : $config_prefix])
 498 AC_MSG_NOTICE([- frontends          :$fe_list])
 499 AC_MSG_NOTICE([  - transform name   : $program_transform_name])
 500 AC_MSG_NOTICE([  - localised        : $has_gettext])
 501 AC_MSG_NOTICE([- install utilities  : $enable_utils])
 502 AC_MSG_NOTICE([- CFLAGS CXXFLAGS    : $wall_CFLAGS $werror_CFLAGS])