git.sur5r.net Git - kconfig-frontends/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #---------------------------------------------------------------------------
   5 # Global initialisation
   6
   7 #----------------------------------------
   8 # Prepare autoconf
   9 AC_PREREQ([2.67])
  10 AC_INIT(
  11     [kconfig-frontends],
  12     [m4_esyscmd_s([./scripts/version.sh])],
  13     [yann.morin.1998@free.fr])
  14 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
  15 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
  16 AC_CONFIG_HEADERS([scripts/.autostuff/config.h])
  17 AC_CONFIG_AUX_DIR([scripts/.autostuff/scripts])
  18 AC_CONFIG_MACRO_DIR([scripts/.autostuff/m4])
  19
  20 #----------------------------------------
  21 # Prepare automake
  22
  23 # We want to allow the user to override our default program-prefix,
  24 # so we must set-it now, before automake has a chance to interpret
  25 # it, but after the options are parsed, so as not to overwrite the
  26 # value (if any) set by the user
  27 AS_IF(
  28     [test "$program_prefix" = NONE],
  29     [program_prefix=kconfig-])
  30
  31 AM_INIT_AUTOMAKE([foreign])
  32
  33 AS_IF(
  34     [test "$(${srcdir}/scripts/version.sh --internal)" = "hg"],
  35     [AM_SILENT_RULES],
  36     [AM_SILENT_RULES([yes])])
  37
  38 AS_IF(
  39     [test $AM_DEFAULT_VERBOSITY -eq 0],
  40     [SILENT_MAKEFLAGS="--no-print-directory -s"],
  41     [SILENT_MAKEFLAGS=""])
  42 AC_SUBST([SILENT_MAKEFLAGS])
  43
  44 #----------------------------------------
  45 # Prepare libtool
  46 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl Automake, we have a problem...
  47 LT_PREREQ([2.2.6])
  48 LT_INIT([disable-static])
  49
  50 #---------------------------------------------------------------------------
  51 # Set misc options
  52
  53 # By default, do not build with -Wall, unless the user asks for it
  54 AC_ARG_ENABLE(
  55     [wall],
  56     [AS_HELP_STRING(
  57         [--enable-wall],
  58         [build with -Wall (default=no)])],
  59     [AS_CASE(
  60         ["$enableval"],
  61         [yes], [wall_CFLAGS=-Wall],
  62         [*],   [wall_CFLAGS=""])])
  63 AC_SUBST([wall_CFLAGS],[${wall_CFLAGS}])
  64
  65 # By default, do not build with -Werror, unless the user asks for it
  66 AC_ARG_ENABLE(
  67     [werror],
  68     [AS_HELP_STRING(
  69         [--enable-werror],
  70         [build with -Werror (default=no)])],
  71     [AS_CASE(
  72         ["$enableval"],
  73         [yes], [werror_CFLAGS=-Werror],
  74         [*],   [werror_CFLAGS=""])])
  75 AC_SUBST([werror_CFLAGS],[${werror_CFLAGS}])
  76
  77 # Although there is a default (="linux") in the code, we do provide
  78 # a default here, to get a consistent autostuff behavior
  79 AC_ARG_ENABLE(
  80     [root-menu-prompt],
  81     [AS_HELP_STRING(
  82         [--enable-root-menu-prompt=PROMPT],
  83         [set the root-menu prompt (default=Configuration)])],
  84     [AS_CASE(
  85         ["$enableval"],
  86         [yes], [root_menu=Configuration],
  87         [no],  [root_menu=],
  88                [# Escape the $ signs, otherwise they would get munged by make
  89                 # Also, append a space at the end, to separate the package
  90                 # name from the literal 'Configuration'
  91                 root_menu="$( echo "$enableval" |sed -r -e 's/\$/\\$$/g;' )"])])
  92 AC_SUBST([root_menu], [${root_menu=Configuration}])
  93
  94 AC_ARG_ENABLE(
  95     [config-prefix],
  96     [AS_HELP_STRING(
  97         [--enable-config-prefix=PREFIX],
  98         [the prefix to the config option (default=CONFIG_)])],
  99     [AS_CASE(
 100         ["$enableval"],
 101         [*" "*],[AC_MSG_ERROR([config prefix can not contain spaces: '$enableval'])],
 102         [yes],  [config_prefix=CONFIG_],
 103         [no],   [config_prefix=],
 104                 [config_prefix=$enableval])])
 105 AC_SUBST([config_prefix], [${config_prefix-CONFIG_}])
 106
 107 AC_ARG_ENABLE(
 108     [utils],
 109     [AS_HELP_STRING(
 110         [--disable-utils],
 111         [install utilities to manage .config files (default=yes)])])
 112 AC_SUBST([enable_utils], [${enable_utils:-yes}])
 113
 114 AC_ARG_ENABLE(
 115     [L10n],
 116     [AS_HELP_STRING(
 117         [--disable-L10n],
 118         [enable localisation (L10n) (default=auto)])])
 119 AC_SUBST([enable_L10n], [${enable_L10n:-yes}])
 120
 121 #----------------------------------------
 122 # Options to selectively enable/disable frontends
 123 # All are selected by default
 124 AC_ARG_ENABLE(
 125     [conf],
 126     [AS_HELP_STRING(
 127         [--disable-conf],
 128         [conf, the stdin-based frontend (default=auto)])])
 129 AC_SUBST([enable_conf], [${enable_conf:-auto}])
 130 AC_ARG_ENABLE(
 131     [mconf],
 132     [AS_HELP_STRING(
 133         [--disable-mconf],
 134         [mconf, the traditional ncurses-based frontend (default=auto)])])
 135 AC_SUBST([enable_mconf], [${enable_mconf:-auto}])
 136 AC_ARG_ENABLE(
 137     [nconf],
 138     [AS_HELP_STRING(
 139         [--disable-nconf],
 140         [nconf, the modern ncurses-based frontend (default=auto)])])
 141 AC_SUBST([enable_nconf], [${enable_nconf:-auto}])
 142 AC_ARG_ENABLE(
 143     [gconf],
 144     [AS_HELP_STRING(
 145         [--disable-gconf],
 146         [gconf, the GTK-based frontend (default=auto)])])
 147 AC_SUBST([enable_gconf], [${enable_gconf:-auto}])
 148 AC_ARG_ENABLE(
 149     [qconf],
 150     [AS_HELP_STRING(
 151         [--disable-qconf],
 152         [qconf, the QT-based frontend (default=auto)])])
 153 AC_SUBST([enable_qconf], [${enable_qconf:-auto}])
 154
 155 AC_ARG_ENABLE(
 156     [frontends],
 157     [AS_HELP_STRING(
 158         [--enable-frontends=list],
 159         [enables only the set of frontends in comma-separated 'list'
 160          (default: auto selection), takes precedence over all
 161          --enable-*conf, above])],
 162     [for f in conf mconf nconf gconf qconf; do
 163         AS_CASE(
 164             ["$enableval"],
 165             [yes],      [eval enable_$f=yes],
 166             ["$f"],     [eval enable_$f=yes],
 167             ["$f",*],   [eval enable_$f=yes],
 168             [*,"$f"],   [eval enable_$f=yes],
 169             [*,"$f",*], [eval enable_$f=yes],
 170                         [eval enable_$f=no])
 171      done])
 172 AC_SUBST([enable_frontends])
 173
 174 #----------------------------------------
 175 # What extra CFLAGS we will be using
 176 AC_SUBST([kf_CFLAGS], ["$wall_CFLAGS $werror_CFLAGS"])
 177
 178 #----------------------------------------
 179 # Dependencies that will be needed, depending on the frontends
 180 AS_CASE(
 181     ["$enable_mconf":"$enable_nconf"],
 182     [*yes*],  [need_curses=yes],
 183     [*auto*], [need_curses=auto],
 184               [need_curses=no])
 185 [need_panel_menu="$enable_nconf"]
 186 AS_CASE(
 187     ["$enable_gconf":"$enable_qconf"],
 188     [*yes*],  [need_pkgconfig=yes],
 189     [*auto*], [need_pkgconfig=yes],
 190               [need_pkgconfig=no ])
 191 [need_gtk="$enable_gconf"]
 192 [need_qt="$enable_qconf"]
 193
 194 #---------------------------------------------------------------------------
 195 # Now check we have the required stuff
 196
 197 #----------------------------------------
 198 # Some program checks
 199 AC_PROG_CC
 200 AM_PROG_CC_C_O
 201 AC_PROG_CXX
 202 AC_C_INLINE
 203 AC_PROG_MAKE_SET
 204 AC_CHECK_PROGS(
 205     [GPERF],
 206     [gperf])
 207 AS_IF(
 208     [test -z "$GPERF"],
 209     [AC_MSG_ERROR([can not find gperf])])
 210 AS_IF(
 211     [test "$need_pkgconfig" = "yes"],
 212     [PKG_PROG_PKG_CONFIG()])
 213 AC_PROG_LEX
 214 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
 215 AC_PROG_YACC
 216 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
 217
 218 #----------------------------------------
 219 # Check for gettext, for the kconfig frontends
 220 [has_gettext="$enable_L10n"]
 221 AS_IF(
 222     [test "$has_gettext" = "yes"],
 223     [AC_CHECK_HEADERS(
 224         [libintl.h],
 225         [ac_ct_gettext_hdr=$ac_header; break],
 226         [has_gettext=no])])
 227 AS_IF(
 228     [test "$has_gettext" = "yes"],
 229     [AC_CHECK_DECL(
 230         [gettext],,
 231         [has_gettext=no],
 232         [#include <$ac_ct_gettext_hdr>])])
 233 AS_IF(
 234     [test "$has_gettext" = "yes"],
 235     [LIBS_old="$LIBS"
 236      LIBS=
 237      AC_SEARCH_LIBS(
 238         [gettext],
 239         [intl],,
 240         [has_gettext=no])
 241     intl_LIBS="$LIBS"
 242     LIBS="$LIBS_old"])
 243 AS_IF(
 244     [test "$has_gettext" = "no"],
 245     [intl_CPPFLAGS=-DKBUILD_NO_NLS])
 246 AC_SUBST([intl_CPPFLAGS])
 247 AC_SUBST([intl_LIBS])
 248
 249 #----------------------------------------
 250 # Check for ncurses, for the mconf & nconf frontends
 251 AS_IF(
 252     [test "$need_curses" = "yes" -o "$need_curses" = "auto"],
 253     [AC_SUBST([CURSES_LOC])
 254      AC_SUBST([ncurses_LIBS])
 255      LIBS_old="$LIBS"
 256      LIBS=
 257      AC_CHECK_HEADERS(
 258         [ncursesw/curses.h ncurses/ncurses.h ncurses/curses.h ncurses.h curses.h],
 259         [CURSES_LOC=$ac_header; break])
 260      AS_IF(
 261         [test -z "$CURSES_LOC"],
 262         [AS_IF(
 263             [test "$need_curses" = "yes"],
 264             [AC_MSG_ERROR([could not find curses headers (frontends: mconf/nconf)])],
 265             [has_curses=no])])
 266      AC_SEARCH_LIBS(
 267         [initscr],
 268         [ncursesw ncurses curses],
 269         [ac_ct_curses_lib_found=yes; break])
 270      AS_IF(
 271         [test -z "$ac_ct_curses_lib_found"],
 272         [AS_IF(
 273             [test "$need_curses" = "yes"],
 274             [AC_MSG_ERROR([could not find curses library (frontends: mconf/nconf)])],
 275             [has_curses=no])])
 276      ncurses_LIBS="$LIBS"
 277      LIBS=$LIBS_old])
 278
 279 AS_IF(
 280     [test "$has_curses" = "no" ],
 281     [enable_mconf=no; enable_nconf=no])
 282
 283 #----------------------------------------
 284 # Check for libpanel and libmenu, for the nconf frontend
 285 AS_IF(
 286     [test "$need_panel_menu" = "yes" -o "$need_panel_menu" = "auto"],
 287     [AC_SUBST([ncurses_extra_LIBS])
 288      AC_SUBST([ncurses_extra_CPPFLAGS])
 289      AS_CASE(
 290         [$CURSES_LOC],
 291         [ncursesw/*],[ncurses_extra_CPPFLAGS="-I/usr/include/ncursesw"],
 292         [ncurses/*],[ncurses_extra_CPPFLAGS="-I/usr/include/ncurses"])
 293      LIBS_old="$LIBS"
 294      LIBS=
 295      AC_SEARCH_LIBS(
 296         [new_panel],
 297         [panelw panel],
 298         [ac_ct_panel_lib_found=yes; break],,
 299         [$ncurses_LIBS])
 300      AS_IF(
 301         [test -z "$ac_ct_panel_lib_found"],
 302         [AS_IF(
 303             [test "$need_panel_menu" = "yes"],
 304             [AC_MSG_ERROR([could not find libpanel library (frontend: nconf)])],
 305             [has_panel_menu=no])])
 306      AC_SEARCH_LIBS(
 307         [menu_init],
 308         [menuw menu],
 309         [ac_ct_menu_lib_found=yes; break],,
 310         [$ncurses_LIBS])
 311      AS_IF(
 312         [test -z "$ac_ct_panel_lib_found"],
 313         [AS_IF(
 314             [test "$need_panel_menu" = "yes"],
 315             [AC_MSG_ERROR([could not find libmenu library (frontend: nconf)])],
 316             [has_panel_menu=no])])
 317      ncurses_extra_LIBS="$LIBS"
 318      LIBS=$LIBS_old])
 319
 320 AS_IF(
 321     [test "$has_panel_menu" = "no" ],
 322     [enable_nconf=no])
 323
 324 #----------------------------------------
 325 # Check headers and libs for gconf
 326 AS_IF(
 327     [test "$need_gtk" = "yes" -o "$need_gtk" = "auto"],
 328     [PKG_CHECK_MODULES(
 329         [gtk],
 330         [gtk+-2.0 gmodule-2.0 libglade-2.0],
 331         [has_gtk=yes],
 332         [AS_IF(
 333             [test "$need_gtk" = "yes"],
 334             [AC_MSG_ERROR([could not find GTK+ headers and/or libraries (frontend: gconf)])],
 335             [has_gtk=no])])])
 336
 337 AS_IF(
 338     [test "$has_gtk" = "no" ],
 339     [enable_gconf=no])
 340
 341 #----------------------------------------
 342 # Check headers and libs for qconf
 343 AS_IF(
 344     [test "$need_qt" = "yes" -o "$need_qt" = "auto"],
 345     [PKG_CHECK_MODULES(
 346         [qt4],
 347         [QtCore QtGui Qt3Support],
 348         [has_qt=yes; need_moc="$need_qt"],
 349         [AS_IF(
 350             [test "$need_qt" = "yes"],
 351             [AC_MSG_ERROR([could not find QT4 headers and/or libraries (frontend: qconf)])],
 352             [has_qt=no; need_moc=no])])])
 353
 354 AC_ARG_VAR([MOC], [Qt meta object compiler (moc) command])
 355 AS_IF(
 356     [test "$need_moc" = "yes" -o "$need_moc" = "auto"],
 357     [QT4_BINDIR=`$PKG_CONFIG Qt --variable bindir`
 358      AC_PATH_PROGS(
 359         [MOC],
 360         [moc-qt4 moc],,
 361         [$QT4_BINDIR:$PATH])
 362      AS_IF(
 363         [test -n "$MOC"],
 364         [has_moc=yes],
 365         [AS_IF(
 366             [test "$need_moc" = "yes"],
 367             [AC_MSG_ERROR([could not find moc (frontend: qconf)])],
 368             [has_moc=no])])])
 369
 370 AS_IF(
 371     [test "$has_qt" = "no" -o "$has_moc" = "no"],
 372     [enable_qconf=no])
 373
 374 #----------------------------------------
 375 # Per-frontends extra libraries
 376 AC_ARG_VAR([conf_EXTRA_LIBS],  [Extra libraries to build the conf frontend] )
 377 AC_ARG_VAR([gconf_EXTRA_LIBS], [Extra libraries to build the gconf frontend])
 378 AC_ARG_VAR([mconf_EXTRA_LIBS], [Extra libraries to build the mconf frontend])
 379 AC_ARG_VAR([nconf_EXTRA_LIBS], [Extra libraries to build the nconf frontend])
 380 AC_ARG_VAR([qconf_EXTRA_LIBS], [Extra libraries to build the qconf frontend])
 381
 382 #---------------------------------------------------------------------------
 383 # Now, we know what frontends to enable
 384 AS_IF([test "$enable_conf"  = "auto"], [enable_conf=yes ])
 385 AS_IF([test "$enable_gconf" = "auto"], [enable_gconf=yes])
 386 AS_IF([test "$enable_mconf" = "auto"], [enable_mconf=yes])
 387 AS_IF([test "$enable_nconf" = "auto"], [enable_nconf=yes])
 388 AS_IF([test "$enable_qconf" = "auto"], [enable_qconf=yes])
 389
 390 #----------------------------------------
 391 # Check if the lxdialog library should be built
 392 AS_IF(
 393     [test "$enable_mconf" = "yes"],
 394     [need_lxdialog=yes],
 395     [need_lxdialog=no])
 396
 397 #----------------------------------------
 398 # Check if the images library should be built
 399 AS_IF(
 400     [test "$enable_gconf" = "yes" -o "$enable_qconf" = "yes"],
 401     [need_images=yes],
 402     [need_images=no])
 403
 404 #----------------------------------------
 405 # Setup automake conditional build
 406 AM_CONDITIONAL(
 407     [COND_conf],
 408     [test "$enable_conf" = "yes"])
 409 AM_CONDITIONAL(
 410     [COND_mconf],
 411     [test "$enable_mconf" = "yes"])
 412 AM_CONDITIONAL(
 413     [COND_nconf],
 414     [test "$enable_nconf" = "yes"])
 415 AM_CONDITIONAL(
 416     [COND_gconf],
 417     [test "$enable_gconf" = "yes"])
 418 AM_CONDITIONAL(
 419     [COND_qconf],
 420     [test "$enable_qconf" = "yes"])
 421 AM_CONDITIONAL(
 422     [COND_lxdialog],
 423     [test "$need_lxdialog" = "yes"])
 424 AM_CONDITIONAL(
 425     [COND_images],
 426     [test "$need_images" = "yes"])
 427 AM_CONDITIONAL(
 428     [COND_utils],
 429     [test "$enable_utils" = "yes"])
 430 AM_CONDITIONAL(
 431     [COND_utils_gettext],
 432     [test "$has_gettext" = "yes"])
 433
 434 #----------------------------------------
 435 # Get the version to apply to the parser shared library
 436 AC_SUBST(
 437     [KCONFIGPARSER_LIB_VERSION],
 438     [m4_esyscmd_s([./scripts/version.sh --plain])])
 439
 440 #----------------------------------------
 441 # Finalise
 442 AC_CONFIG_FILES([
 443     Makefile
 444     docs/Makefile
 445     libs/Makefile
 446     libs/images/Makefile
 447     libs/lxdialog/Makefile
 448     libs/parser/Makefile
 449     frontends/Makefile
 450     frontends/conf/Makefile
 451     frontends/mconf/Makefile
 452     frontends/nconf/Makefile
 453     frontends/gconf/Makefile
 454     frontends/qconf/Makefile
 455     utils/Makefile
 456     scripts/Makefile
 457 ])
 458 AC_OUTPUT
 459
 460 #----------------------------------------
 461 # Pretty-print the configuration settings
 462 [fe_list=]
 463 AS_IF([test "$enable_conf"  = "yes"], [fe_list="$fe_list conf" ])
 464 AS_IF([test "$enable_gconf" = "yes"], [fe_list="$fe_list gconf"])
 465 AS_IF([test "$enable_mconf" = "yes"], [fe_list="$fe_list mconf"])
 466 AS_IF([test "$enable_nconf" = "yes"], [fe_list="$fe_list nconf"])
 467 AS_IF([test "$enable_qconf" = "yes"], [fe_list="$fe_list qconf"])
 468
 469 [lib_list=]
 470 AS_IF(
 471     [test "$enable_shared" = "yes"],
 472     [lib_list="$lib_list shared (version: $KCONFIGPARSER_LIB_VERSION)"])
 473 AS_IF(
 474     [test "$enable_static" = "yes"],
 475     [lib_list="$lib_list${lib_list:+,} static"])
 476
 477 AC_MSG_NOTICE()
 478 AC_MSG_NOTICE([Configured with:])
 479 AC_MSG_NOTICE([- parser library     :$lib_list])
 480 AC_MSG_NOTICE([  - root-menu prompt : $root_menu])
 481 AC_MSG_NOTICE([  - config prefix    : $config_prefix])
 482 AC_MSG_NOTICE([- frontends          :$fe_list])
 483 AC_MSG_NOTICE([  - transform name   : $program_transform_name])
 484 AC_MSG_NOTICE([  - localised        : $has_gettext])
 485 AC_MSG_NOTICE([- install utilities  : $enable_utils])
 486 AC_MSG_NOTICE([- CFLAGS CXXFLAGS    : $wall_CFLAGS $werror_CFLAGS])