git.sur5r.net Git - kconfig-frontends/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #---------------------------------------------------------------------------
   5 # Global initialisation
   6
   7 #----------------------------------------
   8 # Prepare autoconf
   9 AC_PREREQ([2.67])
  10 AC_INIT(
  11     [kconfig-frontends],
  12     [m4_esyscmd_s([./scripts/version.sh])],
  13     [nobody@nowhere.org])
  14 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
  15 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
  16 AC_CONFIG_HEADERS([scripts/.autostuff/config.h])
  17 AC_CONFIG_AUX_DIR([scripts/.autostuff/scritps])
  18 AC_CONFIG_MACRO_DIR([scripts/.autostuff/m4])
  19
  20 #----------------------------------------
  21 # Prepare automake
  22 AM_INIT_AUTOMAKE
  23
  24 #----------------------------------------
  25 # Prepare libtool
  26 LT_PREREQ([2.2.6])
  27 LT_INIT([disable-static])
  28
  29 #---------------------------------------------------------------------------
  30 # Set misc options
  31 # Although there is a default (="linux") in the code, we do provide
  32 # a default here, to get a consistent autostuff behavior
  33 AC_ARG_ENABLE(
  34     [root-menu-prompt],
  35     [AS_HELP_STRING(
  36         [--enable-root-menu-prompt=PROMPT],
  37         [set the root-menu prompt (default=Configuration)])],
  38     [AS_CASE(
  39         ["$enableval"],
  40         [yes], [root_menu=Configuration],
  41         [no],  [root_menu=],
  42                [# Escape the $ signs, otherwise they would get munged by make
  43                 # Also, append a space at the end, to separate the package
  44                 # name from the literal 'Configuration'
  45                 root_menu="$( echo "$enableval" |sed -r -e 's/\$/\\$$/g;' )"])])
  46 AC_SUBST([root_menu], [${root_menu=Configuration}])
  47
  48 AC_ARG_ENABLE(
  49     [config-prefix],
  50     [AS_HELP_STRING(
  51         [--enable-config-prefix=PREFIX],
  52         [the prefix to the config option (default=CONFIG_)])],
  53     [AS_CASE(
  54         ["$enableval"],
  55         [*" "*],[AC_MSG_ERROR([config prefix can not contain spaces: '$enableval'])],
  56         [yes],  [config_prefix=CONFIG_],
  57         [no],   [config_prefix=],
  58                 [config_prefix=$enableval])])
  59 AC_SUBST([config_prefix], [${config_prefix-CONFIG_}])
  60
  61 #----------------------------------------
  62 # Options to selectively enable/disable frontends
  63 # All are selected by default
  64 AC_ARG_ENABLE(
  65     [conf],
  66     [AS_HELP_STRING(
  67         [--disable-conf],
  68         [conf, the stdin-based frontend (default=auto)])])
  69 AC_SUBST([enable_conf], [${enable_conf:-auto}])
  70 AC_ARG_ENABLE(
  71     [mconf],
  72     [AS_HELP_STRING(
  73         [--disable-mconf],
  74         [mconf, the traditional ncurses-based frontend (default=auto)])])
  75 AC_SUBST([enable_mconf], [${enable_mconf:-auto}])
  76 AC_ARG_ENABLE(
  77     [nconf],
  78     [AS_HELP_STRING(
  79         [--disable-nconf],
  80         [nconf, the modern ncurses-based frontend (default=auto)])])
  81 AC_SUBST([enable_nconf], [${enable_nconf:-auto}])
  82 AC_ARG_ENABLE(
  83     [gconf],
  84     [AS_HELP_STRING(
  85         [--disable-gconf],
  86         [gconf, the GTK-based frontend (default=auto)])])
  87 AC_SUBST([enable_gconf], [${enable_gconf:-auto}])
  88 AC_ARG_ENABLE(
  89     [qconf],
  90     [AS_HELP_STRING(
  91         [--disable-qconf],
  92         [qconf, the QT-based frontend (default=auto)])])
  93 AC_SUBST([enable_qconf], [${enable_qconf:-auto}])
  94
  95 AC_ARG_ENABLE(
  96     [frontends],
  97     [AS_HELP_STRING(
  98         [--enable-frontends=list],
  99         [enables only the set of frontends in comma-separated 'list'
 100          (default: auto selection), takes precedence over all
 101          --enable-*conf, above])],
 102     [for f in conf mconf nconf gconf qconf; do
 103         AS_CASE(
 104             ["$enableval"],
 105             [yes],      [eval enable_$f=yes],
 106             ["$f"],     [eval enable_$f=yes],
 107             ["$f",*],   [eval enable_$f=yes],
 108             [*,"$f"],   [eval enable_$f=yes],
 109             [*,"$f",*], [eval enable_$f=yes],
 110                         [eval enable_$f=no])
 111      done])
 112 AC_SUBST([enable_frontends])
 113
 114 #----------------------------------------
 115 # Dependencies that will be needed, depending on the frontends
 116 AS_CASE(
 117     ["$enable_mconf":"$enable_nconf"],
 118     [*yes*],  [need_curses=yes],
 119     [*auto*], [need_curses=auto],
 120               [need_curses=no])
 121 [need_panel_menu="$enable_nconf"]
 122 AS_CASE(
 123     ["$enable_gconf":"$enable_qconf"],
 124     [*yes*],  [need_pkgconfig=yes],
 125     [*auto*], [need_pkgconfig=yes],
 126               [need_pkgconfig=no ])
 127 [need_gtk="$enable_gconf"]
 128 [need_qt="$enable_qconf"]
 129
 130 #---------------------------------------------------------------------------
 131 # Now check we have the required stuff
 132
 133 #----------------------------------------
 134 # Some program checks
 135 AC_PROG_CC
 136 AM_PROG_CC_C_O
 137 AC_PROG_CXX
 138 AC_C_INLINE
 139 AC_PROG_MAKE_SET
 140 AC_CHECK_PROGS(
 141     [GPERF],
 142     [gperf])
 143 AS_IF(
 144     [test -z "$GPERF"],
 145     [AC_MSG_ERROR([can not find gperf])])
 146 AS_IF(
 147     [test "$need_pkgconfig" = "yes"],
 148     [PKG_PROG_PKG_CONFIG()])
 149 AC_PROG_LEX
 150 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
 151 AC_PROG_YACC
 152 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
 153
 154 #----------------------------------------
 155 # Check for standard headers
 156 AC_HEADER_STDC
 157 AC_HEADER_STDBOOL
 158 AC_CHECK_HEADERS([ fcntl.h libintl.h limits.h locale.h ])
 159 AC_CHECK_HEADERS([ stdlib.h string.h sys/time.h unistd.h ])
 160 AC_TYPE_SIZE_T
 161
 162 #----------------------------------------
 163 # Checks for library functions.
 164 AC_FUNC_MALLOC
 165 AC_FUNC_REALLOC
 166 AC_FUNC_ALLOCA
 167 AC_CHECK_FUNCS([ bzero memmove memset ])
 168 AC_CHECK_FUNCS([ strcasecmp strchr strcspn strdup strncasecmp strpbrk strrchr strspn strtol ])
 169 AC_CHECK_FUNCS([ gettimeofday mkdir regcomp setlocale uname ])
 170
 171 #----------------------------------------
 172 # Check for gettext, for the kconfig frontends
 173 AC_SUBST([GETTEXT])
 174 AC_CHECK_HEADERS(
 175     [libintl.h],
 176     [ac_ct_gettext_hdr=$ac_header; break],
 177     [AC_MSG_WARN([libintl is missing, frontends will not be localised])])
 178 AS_IF(
 179     [test -n "$ac_ct_gettext_hdr"],
 180     [AC_CHECK_DECL(
 181         [gettext],,
 182         [AC_MSG_WARN([gettext is missing, frontends will not be localised])
 183          GETTEXT=-DKBUILD_NO_NLS],
 184         [#include <$ac_ct_gettext_hdr>])])
 185
 186 #----------------------------------------
 187 # Check for ncurses, for the mconf & nconf frontends
 188 AS_IF(
 189     [test "$need_curses" = "yes" -o "$need_curses" = "auto"],
 190     [AC_SUBST([CURSES_LOC])
 191      AC_SUBST([ncurses_LIBS])
 192      LIBS_old="$LIBS"
 193      AC_CHECK_HEADERS(
 194         [ncurses/ncurses.h ncurses/curses.h ncursesw/curses.h ncurses.h curses.h],
 195         [CURSES_LOC=$ac_header; break])
 196      AS_IF(
 197         [test -z "$CURSES_LOC"],
 198         [AS_IF(
 199             [test "$need_curses" = "yes"],
 200             [AC_MSG_ERROR([could not find curses headers (frontends: mconf/nconf)])],
 201             [has_curses=no])])
 202      AC_SEARCH_LIBS(
 203         [initscr],
 204         [ncursesw ncurses curses],
 205         [ac_ct_curses_lib_found=yes; break])
 206      AS_IF(
 207         [test -z "$ac_ct_curses_lib_found"],
 208         [AS_IF(
 209             [test "$need_curses" = "yes"],
 210             [AC_MSG_ERROR([could not find curses library (frontends: mconf/nconf)])],
 211             [has_curses=no])])
 212      ncurses_LIBS="$LIBS"
 213      LIBS=$LIBS_old])
 214
 215 AS_IF(
 216     [test "$has_curses" = "no" ],
 217     [enable_mconf=no; enable_nconf=no])
 218
 219 #----------------------------------------
 220 # Check for libpanel and libmenu, for the nconf frontend
 221 AS_IF(
 222     [test "$need_panel_menu" = "yes" -o "$need_panel_menu" = "auto"],
 223     [AC_SUBST([ncurses_extra_LIBS])
 224      LIBS_old="$LIBS"
 225      AC_SEARCH_LIBS(
 226         [new_panel],
 227         [panelw panel],
 228         [ac_ct_panel_lib_found=yes; break])
 229      AS_IF(
 230         [test -z "$ac_ct_panel_lib_found"],
 231         [AS_IF(
 232             [test "$need_panel_menu" = "yes"],
 233             [AC_MSG_ERROR([could not find libpanel library (frontend: nconf)])],
 234             [has_panel_menu=no])])
 235      AC_SEARCH_LIBS(
 236         [menu_init],
 237         [menuw menu],
 238         [ac_ct_menu_lib_found=yes; break])
 239      AS_IF(
 240         [test -z "$ac_ct_panel_lib_found"],
 241         [AS_IF(
 242             [test "$need_panel_menu" = "yes"],
 243             [AC_MSG_ERROR([could not find libmenu library (frontend: nconf)])],
 244             [has_panel_menu=no])])
 245      ncurses_extra_LIBS="$LIBS"
 246      LIBS=$LIBS_old])
 247
 248 AS_IF(
 249     [test "$has_panel_menu" = "no" ],
 250     [enable_nconf=no])
 251
 252 #----------------------------------------
 253 # Check headers and libs for gconf
 254 AS_IF(
 255     [test "$need_gtk" = "yes" -o "$need_gtk" = "auto"],
 256     [PKG_CHECK_MODULES(
 257         [gtk],
 258         [gtk+-2.0 gmodule-2.0 libglade-2.0],
 259         [has_gtk=yes],
 260         [AS_IF(
 261             [test "$need_gtk" = "yes"],
 262             [AC_MSG_ERROR([could not find GTK+ headers and/or libraries (frontend: gconf)])],
 263             [has_gtk=no])])])
 264
 265 AS_IF(
 266     [test "$has_gtk" = "no" ],
 267     [enable_gconf=no])
 268
 269 #----------------------------------------
 270 # Check headers and libs for qconf
 271 AS_IF(
 272     [test "$need_qt" = "yes" -o "$need_qt" = "auto"],
 273     [PKG_CHECK_MODULES(
 274         [qt4],
 275         [QtCore QtGui Qt3Support],
 276         [has_qt=yes],
 277         [AS_IF(
 278             [test "$need_qt" = "yes"],
 279             [AC_MSG_ERROR([could not find QT4 headers and/or libraries (frontend: qconf)])],
 280             [has_qt=no])])])
 281
 282 AS_IF(
 283     [test "$has_qt" = "no" ],
 284     [enable_qconf=no])
 285
 286 #---------------------------------------------------------------------------
 287 # Now, we know what frontends to enable
 288 AS_IF([test "$enable_conf"  = "auto"], [enable_conf=yes ])
 289 AS_IF([test "$enable_gconf" = "auto"], [enable_gconf=yes])
 290 AS_IF([test "$enable_mconf" = "auto"], [enable_mconf=yes])
 291 AS_IF([test "$enable_nconf" = "auto"], [enable_nconf=yes])
 292 AS_IF([test "$enable_qconf" = "auto"], [enable_qconf=yes])
 293
 294 #----------------------------------------
 295 # Check if the lxdialog library should be built
 296 AS_IF(
 297     [test "$enable_mconf" = "yes"],
 298     [need_lxdialog=yes],
 299     [need_lxdialog=no])
 300
 301 #----------------------------------------
 302 # Setup automake conditional build
 303 AM_CONDITIONAL(
 304     [COND_conf],
 305     [test "$enable_conf" = "yes"])
 306 AM_CONDITIONAL(
 307     [COND_mconf],
 308     [test "$enable_mconf" = "yes"])
 309 AM_CONDITIONAL(
 310     [COND_nconf],
 311     [test "$enable_nconf" = "yes"])
 312 AM_CONDITIONAL(
 313     [COND_gconf],
 314     [test "$enable_gconf" = "yes"])
 315 AM_CONDITIONAL(
 316     [COND_qconf],
 317     [test "$enable_qconf" = "yes"])
 318 AM_CONDITIONAL(
 319     [COND_lxdialog],
 320     [test "$need_lxdialog" = "yes"])
 321
 322 #----------------------------------------
 323 # Get the version to apply to the parser shared library
 324 AC_SUBST(
 325     [KCONFIGPARSER_LIB_VERSION],
 326     [m4_esyscmd_s([./scripts/version.sh --plain])])
 327
 328 #----------------------------------------
 329 # Finalise
 330 AC_CONFIG_FILES([
 331     Makefile
 332     libs/Makefile
 333     libs/images/Makefile
 334     libs/lxdialog/Makefile
 335     libs/parser/Makefile
 336     frontends/Makefile
 337     frontends/conf/Makefile
 338     frontends/mconf/Makefile
 339     frontends/nconf/Makefile
 340     frontends/gconf/Makefile
 341     frontends/qconf/Makefile
 342 ])
 343 AC_OUTPUT
 344
 345 AC_MSG_NOTICE()
 346 AC_MSG_NOTICE([Configured with:])
 347 AC_MSG_NOTICE([- root-menu prompt: '$root_menu'])
 348 AC_MSG_NOTICE([- config prefix:    '$config_prefix'])
 349 AC_MSG_NOTICE([- frontends:])
 350 AS_IF([test "$enable_conf" = "yes"],
 351       [AC_MSG_NOTICE([  - conf:  yes])],
 352       [AC_MSG_NOTICE([  - conf:  no])])
 353 AS_IF([test "$enable_gconf" = "yes"],
 354       [AC_MSG_NOTICE([  - gconf: yes])],
 355       [AC_MSG_NOTICE([  - gconf: no])])
 356 AS_IF([test "$enable_mconf" = "yes"],
 357       [AC_MSG_NOTICE([  - mconf: yes])],
 358       [AC_MSG_NOTICE([  - mconf: no])])
 359 AS_IF([test "$enable_nconf" = "yes"],
 360       [AC_MSG_NOTICE([  - nconf: yes])],
 361       [AC_MSG_NOTICE([  - nconf: no])])
 362 AS_IF([test "$enable_qconf" = "yes"],
 363       [AC_MSG_NOTICE([  - qconf: yes])],
 364       [AC_MSG_NOTICE([  - qconf: no])])
 365 AC_MSG_NOTICE([- parser library:])
 366 AS_IF([test "$enable_shared" = "yes"],
 367       [AC_MSG_NOTICE([  - shared: yes, versioned $KCONFIGPARSER_LIB_VERSION])],
 368       [AC_MSG_NOTICE([  - shared: no])])
 369 AC_MSG_NOTICE([  - static: $enable_static])