git.sur5r.net Git - kconfig-frontends/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5 AC_INIT([kconfig-frontends], [m4_esyscmd_s([cat .version])], [nobody@nowhere.org])
   6 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
   7 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([scripts])
  10
  11 # Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_CXX
  14 AC_PROG_MAKE_SET
  15
  16 # Checks for libraries.
  17 # (none)
  18
  19 # Checks for header files.
  20 AC_HEADER_STDC
  21 # The folowing AC_CHECK_HEADERS was a single big line
  22 AC_CHECK_HEADERS([ fcntl.h libintl.h limits.h locale.h ])
  23 AC_CHECK_HEADERS([ stdlib.h string.h sys/time.h unistd.h ])
  24
  25 # Checks for typedefs, structures, and compiler characteristics.
  26 AC_HEADER_STDBOOL
  27 AC_C_INLINE
  28 AC_TYPE_SIZE_T
  29
  30 # Checks for library functions.
  31 AC_FUNC_MALLOC
  32 AC_FUNC_REALLOC
  33 AC_FUNC_ALLOCA
  34 # The following AC_CHECK_FUNCS was a single big line
  35 AC_CHECK_FUNCS([ bzero memmove memset ])
  36 AC_CHECK_FUNCS([ strcasecmp strchr strcspn strdup strncasecmp strpbrk strrchr strspn strtol ])
  37 AC_CHECK_FUNCS([ gettimeofday mkdir regcomp setlocale uname ])
  38
  39 # End of the autoscan-detected stuff
  40 #---------------------------------------------------------------------------
  41
  42 #----------------------------------------
  43 # Options to selectively enable/disable frontends
  44 # All are selected by default
  45 AC_ARG_ENABLE(
  46     [conf],
  47     [AS_HELP_STRING(
  48         [--enable-conf],
  49         [conf, the stdin-based frontend (default=yes)])])
  50 AC_SUBST([enable_conf], [${enable_conf:-yes}])
  51 AC_ARG_ENABLE(
  52     [mconf],
  53     [AS_HELP_STRING(
  54         [--enable-mconf],
  55         [mconf, the traditional ncurses-based frontend (default=yes)])])
  56 AC_SUBST([enable_mconf], [${enable_mconf:-yes}])
  57 AC_ARG_ENABLE(
  58     [nconf],
  59     [AS_HELP_STRING(
  60         [--enable-nconf],
  61         [nconf, the modern ncurses-based frontend (default=yes)])])
  62 AC_SUBST([enable_nconf], [${enable_nconf:-yes}])
  63 AC_ARG_ENABLE(
  64     [gconf],
  65     [AS_HELP_STRING(
  66         [--enable-gconf],
  67         [gconf, the GTK-based frontend (default=yes)])])
  68 AC_SUBST([enable_gconf], [${enable_gconf:-yes}])
  69
  70 #----------------------------------------
  71 # Some program checks
  72 AC_PROG_RANLIB
  73 AC_PROG_LEX
  74 AC_PROG_YACC
  75 AC_CHECK_PROGS(
  76     [GPERF],
  77     [gperf])
  78 AS_IF(
  79     [test -z "$GPERF"],
  80     [AC_MSG_ERROR([can not find gperf])])
  81 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
  82 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
  83
  84 #----------------------------------------
  85 # Check for gettext, for the kconfig frontends
  86 AC_SUBST([GETTEXT])
  87 AC_CHECK_HEADERS(
  88     [libintl.h],
  89     [ac_ct_gettext_hdr=$ac_header; break],
  90     [AC_MSG_WARN([libintl is missing, frontends will not be localised])])
  91 AS_IF(
  92     [test -n "$ac_ct_gettext_hdr"],
  93     [AC_CHECK_DECL(
  94         [gettext],,
  95         [AC_MSG_WARN([gettext is missing, frontends will not be localised])
  96          GETTEXT=-DKBUILD_NO_NLS],
  97         [#include <$ac_ct_gettext_hdr>])])
  98
  99 #----------------------------------------
 100 # Check for ncurses, for the kconfig frontends
 101 AC_SUBST([CURSES_LOC])
 102 AC_CHECK_HEADERS(
 103     [ncurses/ncurses.h ncurses/curses.h ncursesw/curses.h ncurses.h curses.h],
 104     [CURSES_LOC=$ac_header; break])
 105 AS_IF(
 106     [test -z "$CURSES_LOC"],
 107     [AC_MSG_ERROR([could not find curses headers])])
 108 AC_SEARCH_LIBS(
 109     [initscr],
 110     [ncursesw ncurses curses],
 111     [ac_ct_curses_lib_found=yes; break])
 112 AS_IF(
 113     [test -z "$ac_ct_curses_lib_found"],
 114     [AC_MSG_ERROR([could not find curses library])])
 115
 116 #----------------------------------------
 117 # Check headers and libs for gconf
 118 AS_IF(
 119     [test "$enable_gconf" = yes ],
 120     [PKG_PROG_PKG_CONFIG()
 121      PKG_CHECK_MODULES(
 122         [gtk],
 123         [gtk+-2.0 gmodule-2.0 libglade-2.0])])
 124
 125 #---------------------------------------------------------------------------
 126 # Prepare automake
 127 AM_INIT_AUTOMAKE
 128 AM_PROG_CC_C_O
 129 AM_CONDITIONAL(
 130     [COND_conf],
 131     [test "$enable_conf" = "yes"])
 132 AM_CONDITIONAL(
 133     [COND_mconf],
 134     [test "$enable_mconf" = "yes"])
 135 AM_CONDITIONAL(
 136     [COND_nconf],
 137     [test "$enable_nconf" = "yes"])
 138 AM_CONDITIONAL(
 139     [COND_gconf],
 140     [test "$enable_gconf" = "yes"])
 141
 142 #----------------------------------------
 143 # Finalise
 144 AC_CONFIG_FILES([
 145     Makefile
 146     libs/Makefile
 147     libs/lxdialog/Makefile
 148     libs/parser/Makefile
 149     frontends/Makefile
 150     frontends/conf/Makefile
 151     frontends/mconf/Makefile
 152     frontends/nconf/Makefile
 153     frontends/gconf/Makefile
 154 ])
 155 AC_OUTPUT