git.sur5r.net Git - kconfig-frontends/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #---------------------------------------------------------------------------
   5 # Global initialisation
   6
   7 #----------------------------------------
   8 # Prepare autoconf
   9 AC_PREREQ([2.67])
  10 AC_INIT(
  11     [kconfig-frontends],
  12     [m4_esyscmd_s([./scripts/version.sh])],
  13     [yann.morin.1998@free.fr])
  14 AC_CONFIG_SRCDIR([frontends/conf/conf.c])
  15 # Use a config.h to avoid brazilions -DHAVE_FOO on compile lines
  16 AC_CONFIG_HEADERS([scripts/.autostuff/config.h])
  17 AC_CONFIG_AUX_DIR([scripts/.autostuff/scripts])
  18 AC_CONFIG_MACRO_DIR([scripts/.autostuff/m4])
  19
  20 #----------------------------------------
  21 # Prepare automake
  22
  23 # We want to allow the user to override our default program-prefix,
  24 # so we must set-it now, before automake has a chance to interpret
  25 # it, but after the options are parsed, so as not to overwrite the
  26 # value (if any) set by the user
  27 AS_IF(
  28     [test "$program_prefix" = NONE],
  29     [program_prefix=kconfig-])
  30
  31 AM_INIT_AUTOMAKE
  32
  33 AS_IF(
  34     [test "$(${srcdir}/scripts/version.sh --internal)" = "hg"],
  35     [AM_SILENT_RULES],
  36     [AM_SILENT_RULES([yes])])
  37
  38 AS_IF(
  39     [test $AM_DEFAULT_VERBOSITY -eq 0],
  40     [SILENT_MAKEFLAGS="--no-print-directory -s"],
  41     [SILENT_MAKEFLAGS=""])
  42 AC_SUBST([SILENT_MAKEFLAGS])
  43
  44 #----------------------------------------
  45 # Prepare libtool
  46 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl Automake, we have a problem...
  47 LT_PREREQ([2.2.6])
  48 LT_INIT([disable-static])
  49
  50 #---------------------------------------------------------------------------
  51 # Set misc options
  52
  53 # By default, do not build with -Wall, unless the user asks for it
  54 AC_ARG_ENABLE(
  55     [wall],
  56     [AS_HELP_STRING(
  57         [--enable-wall],
  58         [build with -Wall (default=no)])],
  59     [AS_CASE(
  60         ["$enableval"],
  61         [yes], [wall_CFLAGS=-Wall],
  62         [*],   [wall_CFLAGS=""])])
  63 AC_SUBST([wall_CFLAGS],[${wall_CFLAGS}])
  64
  65 # By default, do not build with -Werror, unless the user asks for it
  66 AC_ARG_ENABLE(
  67     [werror],
  68     [AS_HELP_STRING(
  69         [--enable-werror],
  70         [build with -Werror (default=no)])],
  71     [AS_CASE(
  72         ["$enableval"],
  73         [yes], [werror_CFLAGS=-Werror],
  74         [*],   [werror_CFLAGS=""])])
  75 AC_SUBST([werror_CFLAGS],[${werror_CFLAGS}])
  76
  77 # Although there is a default (="linux") in the code, we do provide
  78 # a default here, to get a consistent autostuff behavior
  79 AC_ARG_ENABLE(
  80     [root-menu-prompt],
  81     [AS_HELP_STRING(
  82         [--enable-root-menu-prompt=PROMPT],
  83         [set the root-menu prompt (default=Configuration)])],
  84     [AS_CASE(
  85         ["$enableval"],
  86         [yes], [root_menu=Configuration],
  87         [no],  [root_menu=],
  88                [# Escape the $ signs, otherwise they would get munged by make
  89                 # Also, append a space at the end, to separate the package
  90                 # name from the literal 'Configuration'
  91                 root_menu="$( echo "$enableval" |sed -r -e 's/\$/\\$$/g;' )"])])
  92 AC_SUBST([root_menu], [${root_menu=Configuration}])
  93
  94 AC_ARG_ENABLE(
  95     [config-prefix],
  96     [AS_HELP_STRING(
  97         [--enable-config-prefix=PREFIX],
  98         [the prefix to the config option (default=CONFIG_)])],
  99     [AS_CASE(
 100         ["$enableval"],
 101         [*" "*],[AC_MSG_ERROR([config prefix can not contain spaces: '$enableval'])],
 102         [yes],  [config_prefix=CONFIG_],
 103         [no],   [config_prefix=],
 104                 [config_prefix=$enableval])])
 105 AC_SUBST([config_prefix], [${config_prefix-CONFIG_}])
 106
 107 AC_ARG_ENABLE(
 108     [utils],
 109     [AS_HELP_STRING(
 110         [--disable-utils],
 111         [install utilities to manage .config files (default=no)])])
 112 AC_SUBST([enable_utils], [${enable_utils:-yes}])
 113
 114 AC_ARG_ENABLE(
 115     [L10n],
 116     [AS_HELP_STRING(
 117         [--disable-L10n],
 118         [enable localisation (L10n) (default=auto)])])
 119 AC_SUBST([enable_L10n], [${enable_L10n:-yes}])
 120
 121 #----------------------------------------
 122 # Options to selectively enable/disable frontends
 123 # All are selected by default
 124 AC_ARG_ENABLE(
 125     [conf],
 126     [AS_HELP_STRING(
 127         [--disable-conf],
 128         [conf, the stdin-based frontend (default=auto)])])
 129 AC_SUBST([enable_conf], [${enable_conf:-auto}])
 130 AC_ARG_ENABLE(
 131     [mconf],
 132     [AS_HELP_STRING(
 133         [--disable-mconf],
 134         [mconf, the traditional ncurses-based frontend (default=auto)])])
 135 AC_SUBST([enable_mconf], [${enable_mconf:-auto}])
 136 AC_ARG_ENABLE(
 137     [nconf],
 138     [AS_HELP_STRING(
 139         [--disable-nconf],
 140         [nconf, the modern ncurses-based frontend (default=auto)])])
 141 AC_SUBST([enable_nconf], [${enable_nconf:-auto}])
 142 AC_ARG_ENABLE(
 143     [gconf],
 144     [AS_HELP_STRING(
 145         [--disable-gconf],
 146         [gconf, the GTK-based frontend (default=auto)])])
 147 AC_SUBST([enable_gconf], [${enable_gconf:-auto}])
 148 AC_ARG_ENABLE(
 149     [qconf],
 150     [AS_HELP_STRING(
 151         [--disable-qconf],
 152         [qconf, the QT-based frontend (default=auto)])])
 153 AC_SUBST([enable_qconf], [${enable_qconf:-auto}])
 154
 155 AC_ARG_ENABLE(
 156     [frontends],
 157     [AS_HELP_STRING(
 158         [--enable-frontends=list],
 159         [enables only the set of frontends in comma-separated 'list'
 160          (default: auto selection), takes precedence over all
 161          --enable-*conf, above])],
 162     [for f in conf mconf nconf gconf qconf; do
 163         AS_CASE(
 164             ["$enableval"],
 165             [yes],      [eval enable_$f=yes],
 166             ["$f"],     [eval enable_$f=yes],
 167             ["$f",*],   [eval enable_$f=yes],
 168             [*,"$f"],   [eval enable_$f=yes],
 169             [*,"$f",*], [eval enable_$f=yes],
 170                         [eval enable_$f=no])
 171      done])
 172 AC_SUBST([enable_frontends])
 173
 174 #----------------------------------------
 175 # What extra CFLAGS we will be using
 176 AC_SUBST([kf_CFLAGS], ["$wall_CFLAGS $werror_CFLAGS"])
 177
 178 #----------------------------------------
 179 # Dependencies that will be needed, depending on the frontends
 180 AS_CASE(
 181     ["$enable_mconf":"$enable_nconf"],
 182     [*yes*],  [need_curses=yes],
 183     [*auto*], [need_curses=auto],
 184               [need_curses=no])
 185 [need_panel_menu="$enable_nconf"]
 186 AS_CASE(
 187     ["$enable_gconf":"$enable_qconf"],
 188     [*yes*],  [need_pkgconfig=yes],
 189     [*auto*], [need_pkgconfig=yes],
 190               [need_pkgconfig=no ])
 191 [need_gtk="$enable_gconf"]
 192 [need_qt="$enable_qconf"]
 193
 194 #---------------------------------------------------------------------------
 195 # Now check we have the required stuff
 196
 197 #----------------------------------------
 198 # Some program checks
 199 AC_PROG_CC
 200 AM_PROG_CC_C_O
 201 AC_PROG_CXX
 202 AC_C_INLINE
 203 AC_PROG_MAKE_SET
 204 AC_CHECK_PROGS(
 205     [GPERF],
 206     [gperf])
 207 AS_IF(
 208     [test -z "$GPERF"],
 209     [AC_MSG_ERROR([can not find gperf])])
 210 AS_IF(
 211     [test "$need_pkgconfig" = "yes"],
 212     [PKG_PROG_PKG_CONFIG()])
 213 AC_PROG_LEX
 214 AC_SUBST([AM_LFLAGS], ["-L -P zconf"])
 215 AC_PROG_YACC
 216 AC_SUBST([AM_YFLAGS], ["-t -l -p zconf"])
 217
 218 #----------------------------------------
 219 # Check for standard headers
 220 AC_HEADER_STDC
 221 AC_HEADER_STDBOOL
 222 AC_CHECK_HEADERS([ fcntl.h limits.h locale.h ])
 223 AC_CHECK_HEADERS([ stdlib.h string.h sys/time.h unistd.h ])
 224 AC_TYPE_SIZE_T
 225
 226 #----------------------------------------
 227 # Checks for library functions.
 228 AC_FUNC_MALLOC
 229 AC_FUNC_REALLOC
 230 AC_FUNC_ALLOCA
 231 AC_CHECK_FUNCS([ bzero memmove memset ])
 232 AC_CHECK_FUNCS([ strcasecmp strchr strcspn strdup strncasecmp strpbrk strrchr strspn strtol ])
 233 AC_CHECK_FUNCS([ gettimeofday mkdir regcomp setlocale uname ])
 234
 235 #----------------------------------------
 236 # Check for gettext, for the kconfig frontends
 237 [has_gettext="$enable_L10n"]
 238 AS_IF(
 239     [test "$has_gettext" = "yes"],
 240     [AC_CHECK_HEADERS(
 241         [libintl.h],
 242         [ac_ct_gettext_hdr=$ac_header; break],
 243         [has_gettext=no])])
 244 AS_IF(
 245     [test "$has_gettext" = "yes"],
 246     [AC_CHECK_DECL(
 247         [gettext],,
 248         [has_gettext=no],
 249         [#include <$ac_ct_gettext_hdr>])])
 250 AS_IF(
 251     [test "$has_gettext" = "yes"],
 252     [LIBS_old="$LIBS"
 253      LIBS=
 254      AC_SEARCH_LIBS(
 255         [gettext],
 256         [intl],,
 257         [has_gettext=no])
 258     intl_LIBS="$LIBS"
 259     LIBS="$LIBS_old"])
 260 AS_IF(
 261     [test "$has_gettext" = "no"],
 262     [intl_CPPFLAGS=-DKBUILD_NO_NLS])
 263 AC_SUBST([intl_CPPFLAGS])
 264 AC_SUBST([intl_LIBS])
 265
 266 #----------------------------------------
 267 # Check for ncurses, for the mconf & nconf frontends
 268 AS_IF(
 269     [test "$need_curses" = "yes" -o "$need_curses" = "auto"],
 270     [AC_SUBST([CURSES_LOC])
 271      AC_SUBST([ncurses_LIBS])
 272      LIBS_old="$LIBS"
 273      LIBS=
 274      AC_CHECK_HEADERS(
 275         [ncursesw/curses.h ncurses/ncurses.h ncurses/curses.h ncurses.h curses.h],
 276         [CURSES_LOC=$ac_header; break])
 277      AS_IF(
 278         [test -z "$CURSES_LOC"],
 279         [AS_IF(
 280             [test "$need_curses" = "yes"],
 281             [AC_MSG_ERROR([could not find curses headers (frontends: mconf/nconf)])],
 282             [has_curses=no])])
 283      AC_SEARCH_LIBS(
 284         [initscr],
 285         [ncursesw ncurses curses],
 286         [ac_ct_curses_lib_found=yes; break])
 287      AS_IF(
 288         [test -z "$ac_ct_curses_lib_found"],
 289         [AS_IF(
 290             [test "$need_curses" = "yes"],
 291             [AC_MSG_ERROR([could not find curses library (frontends: mconf/nconf)])],
 292             [has_curses=no])])
 293      ncurses_LIBS="$LIBS"
 294      LIBS=$LIBS_old])
 295
 296 AS_IF(
 297     [test "$has_curses" = "no" ],
 298     [enable_mconf=no; enable_nconf=no])
 299
 300 #----------------------------------------
 301 # Check for libpanel and libmenu, for the nconf frontend
 302 AS_IF(
 303     [test "$need_panel_menu" = "yes" -o "$need_panel_menu" = "auto"],
 304     [AC_SUBST([ncurses_extra_LIBS])
 305      AC_SUBST([ncurses_extra_CPPFLAGS])
 306      AS_CASE(
 307         [$CURSES_LOC],
 308         [ncursesw/*],[ncurses_extra_CPPFLAGS="-I/usr/include/ncursesw"],
 309         [ncurses/*],[ncurses_extra_CPPFLAGS="-I/usr/include/ncurses"])
 310      LIBS_old="$LIBS"
 311      LIBS=
 312      AC_SEARCH_LIBS(
 313         [new_panel],
 314         [panelw panel],
 315         [ac_ct_panel_lib_found=yes; break],,
 316         [$ncurses_LIBS])
 317      AS_IF(
 318         [test -z "$ac_ct_panel_lib_found"],
 319         [AS_IF(
 320             [test "$need_panel_menu" = "yes"],
 321             [AC_MSG_ERROR([could not find libpanel library (frontend: nconf)])],
 322             [has_panel_menu=no])])
 323      AC_SEARCH_LIBS(
 324         [menu_init],
 325         [menuw menu],
 326         [ac_ct_menu_lib_found=yes; break],,
 327         [$ncurses_LIBS])
 328      AS_IF(
 329         [test -z "$ac_ct_panel_lib_found"],
 330         [AS_IF(
 331             [test "$need_panel_menu" = "yes"],
 332             [AC_MSG_ERROR([could not find libmenu library (frontend: nconf)])],
 333             [has_panel_menu=no])])
 334      ncurses_extra_LIBS="$LIBS"
 335      LIBS=$LIBS_old])
 336
 337 AS_IF(
 338     [test "$has_panel_menu" = "no" ],
 339     [enable_nconf=no])
 340
 341 #----------------------------------------
 342 # Check headers and libs for gconf
 343 AS_IF(
 344     [test "$need_gtk" = "yes" -o "$need_gtk" = "auto"],
 345     [PKG_CHECK_MODULES(
 346         [gtk],
 347         [gtk+-2.0 gmodule-2.0 libglade-2.0],
 348         [has_gtk=yes],
 349         [AS_IF(
 350             [test "$need_gtk" = "yes"],
 351             [AC_MSG_ERROR([could not find GTK+ headers and/or libraries (frontend: gconf)])],
 352             [has_gtk=no])])])
 353
 354 AS_IF(
 355     [test "$has_gtk" = "no" ],
 356     [enable_gconf=no])
 357
 358 #----------------------------------------
 359 # Check headers and libs for qconf
 360 AS_IF(
 361     [test "$need_qt" = "yes" -o "$need_qt" = "auto"],
 362     [PKG_CHECK_MODULES(
 363         [qt4],
 364         [QtCore QtGui Qt3Support],
 365         [has_qt=yes; need_moc="$need_qt"],
 366         [AS_IF(
 367             [test "$need_qt" = "yes"],
 368             [AC_MSG_ERROR([could not find QT4 headers and/or libraries (frontend: qconf)])],
 369             [has_qt=no; need_moc=no])])])
 370
 371 AC_ARG_VAR([MOC], [Qt meta object compiler (moc) command])
 372 AS_IF(
 373     [test "$need_moc" = "yes" -o "$need_moc" = "auto"],
 374     [QT4_BINDIR=`$PKG_CONFIG Qt --variable bindir`
 375      AC_PATH_PROGS(
 376         [MOC],
 377         [moc-qt4 moc],,
 378         [$QT4_BINDIR:$PATH])
 379      AS_IF(
 380         [test -n "$MOC"],
 381         [has_moc=yes],
 382         [AS_IF(
 383             [test "$need_moc" = "yes"],
 384             [AC_MSG_ERROR([could not find moc (frontend: qconf)])],
 385             [has_moc=no])])])
 386
 387 AS_IF(
 388     [test "$has_qt" = "no" -o "$has_moc" = "no"],
 389     [enable_qconf=no])
 390
 391 #----------------------------------------
 392 # Per-frontends extra libraries
 393 AC_ARG_VAR([conf_EXTRA_LIBS],  [Extra libraries to build the conf frontend] )
 394 AC_ARG_VAR([gconf_EXTRA_LIBS], [Extra libraries to build the gconf frontend])
 395 AC_ARG_VAR([mconf_EXTRA_LIBS], [Extra libraries to build the mconf frontend])
 396 AC_ARG_VAR([nconf_EXTRA_LIBS], [Extra libraries to build the nconf frontend])
 397 AC_ARG_VAR([qconf_EXTRA_LIBS], [Extra libraries to build the qconf frontend])
 398
 399 #---------------------------------------------------------------------------
 400 # Now, we know what frontends to enable
 401 AS_IF([test "$enable_conf"  = "auto"], [enable_conf=yes ])
 402 AS_IF([test "$enable_gconf" = "auto"], [enable_gconf=yes])
 403 AS_IF([test "$enable_mconf" = "auto"], [enable_mconf=yes])
 404 AS_IF([test "$enable_nconf" = "auto"], [enable_nconf=yes])
 405 AS_IF([test "$enable_qconf" = "auto"], [enable_qconf=yes])
 406
 407 #----------------------------------------
 408 # Check if the lxdialog library should be built
 409 AS_IF(
 410     [test "$enable_mconf" = "yes"],
 411     [need_lxdialog=yes],
 412     [need_lxdialog=no])
 413
 414 #----------------------------------------
 415 # Check if the images library should be built
 416 AS_IF(
 417     [test "$enable_gconf" = "yes" -o "$enable_qconf" = "yes"],
 418     [need_images=yes],
 419     [need_images=no])
 420
 421 #----------------------------------------
 422 # Setup automake conditional build
 423 AM_CONDITIONAL(
 424     [COND_conf],
 425     [test "$enable_conf" = "yes"])
 426 AM_CONDITIONAL(
 427     [COND_mconf],
 428     [test "$enable_mconf" = "yes"])
 429 AM_CONDITIONAL(
 430     [COND_nconf],
 431     [test "$enable_nconf" = "yes"])
 432 AM_CONDITIONAL(
 433     [COND_gconf],
 434     [test "$enable_gconf" = "yes"])
 435 AM_CONDITIONAL(
 436     [COND_qconf],
 437     [test "$enable_qconf" = "yes"])
 438 AM_CONDITIONAL(
 439     [COND_lxdialog],
 440     [test "$need_lxdialog" = "yes"])
 441 AM_CONDITIONAL(
 442     [COND_images],
 443     [test "$need_images" = "yes"])
 444 AM_CONDITIONAL(
 445     [COND_utils],
 446     [test "$enable_utils" = "yes"])
 447 AM_CONDITIONAL(
 448     [COND_utils_gettext],
 449     [test "$has_gettext" = "yes"])
 450
 451 #----------------------------------------
 452 # Get the version to apply to the parser shared library
 453 AC_SUBST(
 454     [KCONFIGPARSER_LIB_VERSION],
 455     [m4_esyscmd_s([./scripts/version.sh --plain])])
 456
 457 #----------------------------------------
 458 # Finalise
 459 AC_CONFIG_FILES([
 460     Makefile
 461     docs/Makefile
 462     libs/Makefile
 463     libs/images/Makefile
 464     libs/lxdialog/Makefile
 465     libs/parser/Makefile
 466     frontends/Makefile
 467     frontends/conf/Makefile
 468     frontends/mconf/Makefile
 469     frontends/nconf/Makefile
 470     frontends/gconf/Makefile
 471     frontends/qconf/Makefile
 472     utils/Makefile
 473     scripts/Makefile
 474 ])
 475 AC_OUTPUT
 476
 477 #----------------------------------------
 478 # Pretty-print the configuration settings
 479 [fe_list=]
 480 AS_IF([test "$enable_conf"  = "yes"], [fe_list="$fe_list conf" ])
 481 AS_IF([test "$enable_gconf" = "yes"], [fe_list="$fe_list gconf"])
 482 AS_IF([test "$enable_mconf" = "yes"], [fe_list="$fe_list mconf"])
 483 AS_IF([test "$enable_nconf" = "yes"], [fe_list="$fe_list nconf"])
 484 AS_IF([test "$enable_qconf" = "yes"], [fe_list="$fe_list qconf"])
 485
 486 [lib_list=]
 487 AS_IF(
 488     [test "$enable_shared" = "yes"],
 489     [lib_list="$lib_list shared (version: $KCONFIGPARSER_LIB_VERSION)"])
 490 AS_IF(
 491     [test "$enable_static" = "yes"],
 492     [lib_list="$lib_list${lib_list:+,} static"])
 493
 494 AC_MSG_NOTICE()
 495 AC_MSG_NOTICE([Configured with:])
 496 AC_MSG_NOTICE([- parser library     :$lib_list])
 497 AC_MSG_NOTICE([  - root-menu prompt : $root_menu])
 498 AC_MSG_NOTICE([  - config prefix    : $config_prefix])
 499 AC_MSG_NOTICE([- frontends          :$fe_list])
 500 AC_MSG_NOTICE([  - transform name   : $program_transform_name])
 501 AC_MSG_NOTICE([  - localised        : $has_gettext])
 502 AC_MSG_NOTICE([- install utilities  : $enable_utils])
 503 AC_MSG_NOTICE([- CFLAGS CXXFLAGS    : $wall_CFLAGS $werror_CFLAGS])