git.sur5r.net Git - minitube/blob - locale/locale.pri

   1 # This voodoo comes from the Arora project
   2
   3 INCLUDEPATH += $$PWD
   4 DEPENDPATH += $$PWD
   5
   6 # ls -1 *.ts | tr '\n' ' '
   7 TRANSLATIONS += ar.ts ast.ts be.ts bg_BG.ts ca.ts ca_ES.ts cs_CZ.ts da.ts de_DE.ts el.ts en.ts es.ts es_AR.ts es_ES.ts es_MX.ts fi.ts fi_FI.ts fr.ts gl.ts he_IL.ts hr.ts hu.ts ia.ts it.ts ja_JP.ts ky.ts ms_MY.ts nb.ts nl.ts nn.ts pl.ts pl_PL.ts pt.ts pt_BR.ts ro.ts ru.ts sk.ts sl.ts sq.ts sv_SE.ts tr.ts uk.ts uk_UA.ts vi.ts zh_CN.ts zh_TW.ts
   8 isEmpty(QMAKE_LRELEASE) {
   9     win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\lrelease.exe
  10     else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
  11 }
  12
  13 updateqm.input = TRANSLATIONS
  14 updateqm.output = build/target/locale/${QMAKE_FILE_BASE}.qm
  15 updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm build/target/locale/${QMAKE_FILE_BASE}.qm
  16 updateqm.CONFIG += no_link target_predeps
  17 QMAKE_EXTRA_COMPILERS += updateqm
  18
  19 #qmfiles.files = TRANSLATIONS
  20 #qmfiles.path = Content/Resources
  21 #QMAKE_BUNDLE_DATA += qmfiles