git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += c++14 exceptions_off rtti_off optimize_full
   2
   3 TEMPLATE = app
   4 VERSION = 3.1
   5 DEFINES += APP_VERSION="$$VERSION"
   6
   7 APP_NAME = Minitube
   8 DEFINES += APP_NAME="$$APP_NAME"
   9
  10 APP_UNIX_NAME = minitube
  11 DEFINES += APP_UNIX_NAME="$$APP_UNIX_NAME"
  12
  13 DEFINES += APP_SNAPSHOT
  14
  15 message(Building $${APP_NAME} $${VERSION})
  16 message(Qt $$[QT_VERSION] in $$[QT_INSTALL_PREFIX])
  17
  18 DEFINES *= QT_NO_DEBUG_OUTPUT
  19 DEFINES *= QT_USE_QSTRINGBUILDER
  20 DEFINES *= QT_STRICT_ITERATORS
  21
  22 !contains(DEFINES, APP_GOOGLE_API_KEY=.+) {
  23     warning("You need to specify a Google API Key, refer to the README.md file for details")
  24 }
  25
  26 TARGET = $${APP_UNIX_NAME}
  27
  28 QT += widgets network sql qml
  29
  30 include(lib/http/http.pri)
  31 include(lib/idle/idle.pri)
  32
  33 DEFINES += MEDIA_MPV
  34 include(lib/media/media.pri)
  35
  36 include(src/qtsingleapplication/qtsingleapplication.pri)
  37
  38 HEADERS += src/video.h \
  39     src/spacer.h \
  40     src/constants.h \
  41     src/playlistitemdelegate.h \
  42     src/videomimedata.h \
  43     src/updatechecker.h \
  44     src/searchparams.h \
  45     src/minisplitter.h \
  46     src/loadingwidget.h \
  47     src/autocomplete.h \
  48     src/videodefinition.h \
  49     src/fontutils.h \
  50     src/globalshortcuts.h \
  51     src/globalshortcutbackend.h \
  52     src/downloadmanager.h \
  53     src/downloaditem.h \
  54     src/downloadview.h \
  55     src/downloadmodel.h \
  56     src/downloadlistview.h \
  57     src/downloadsettings.h \
  58     src/suggester.h \
  59     src/channelsuggest.h \
  60     src/temporary.h \
  61     src/segmentedcontrol.h \
  62     src/playlistview.h \
  63     src/refinesearchwidget.h \
  64     src/refinesearchbutton.h \
  65     src/sidebarwidget.h \
  66     src/homeview.h \
  67     src/aboutview.h \
  68     src/mainwindow.h \
  69     src/mediaview.h \
  70     src/searchview.h \
  71     src/view.h \
  72     src/playlistmodel.h \
  73     src/videosource.h \
  74     src/ytsearch.h \
  75     src/ytstandardfeed.h \
  76     src/standardfeedsview.h \
  77     src/ytregions.h \
  78     src/ytcategories.h \
  79     src/ytsuggester.h \
  80     src/videosourcewidget.h \
  81     src/regionsview.h \
  82     src/ytsinglevideosource.h \
  83     src/sidebarheader.h \
  84     src/iconutils.h \
  85     src/diskcache.h \
  86     src/gridwidget.h \
  87     src/painterutils.h \
  88     src/database.h \
  89     src/channelaggregator.h \
  90     src/channelmodel.h \
  91     src/aggregatevideosource.h \
  92     src/channelview.h \
  93     src/channelitemdelegate.h \
  94     src/jsfunctions.h \
  95     src/seekslider.h \
  96     src/snapshotsettings.h \
  97     src/snapshotpreview.h \
  98     src/datautils.h \
  99     src/yt3listparser.h \
 100     src/ytchannel.h \
 101     src/yt3.h \
 102     src/paginatedvideosource.h \
 103     src/searchwidget.h \
 104     src/channellistview.h \
 105     src/httputils.h \
 106     src/appwidget.h \
 107     src/clickablelabel.h \
 108     src/ytvideo.h \
 109     src/toolbarmenu.h \
 110     src/sharetoolbar.h \
 111     src/videoarea.h \
 112     src/searchlineedit.h
 113 SOURCES += src/main.cpp \
 114     src/spacer.cpp \
 115     src/video.cpp \
 116     src/videomimedata.cpp \
 117     src/updatechecker.cpp \
 118     src/searchparams.cpp \
 119     src/minisplitter.cpp \
 120     src/loadingwidget.cpp \
 121     src/autocomplete.cpp \
 122     src/videodefinition.cpp \
 123     src/constants.cpp \
 124     src/fontutils.cpp \
 125     src/globalshortcuts.cpp \
 126     src/globalshortcutbackend.cpp \
 127     src/downloadmanager.cpp \
 128     src/downloaditem.cpp \
 129     src/downloadview.cpp \
 130     src/downloadmodel.cpp \
 131     src/downloadlistview.cpp \
 132     src/downloadsettings.cpp \
 133     src/channelsuggest.cpp \
 134     src/temporary.cpp \
 135     src/segmentedcontrol.cpp \
 136     src/playlistview.cpp \
 137     src/refinesearchwidget.cpp \
 138     src/refinesearchbutton.cpp \
 139     src/sidebarwidget.cpp \
 140     src/homeview.cpp \
 141     src/mainwindow.cpp \
 142     src/mediaview.cpp \
 143     src/aboutview.cpp \
 144     src/searchview.cpp \
 145     src/playlistitemdelegate.cpp \
 146     src/playlistmodel.cpp \
 147     src/videosource.cpp \
 148     src/ytsearch.cpp \
 149     src/ytstandardfeed.cpp \
 150     src/standardfeedsview.cpp \
 151     src/ytregions.cpp \
 152     src/ytcategories.cpp \
 153     src/ytsuggester.cpp \
 154     src/videosourcewidget.cpp \
 155     src/regionsview.cpp \
 156     src/ytsinglevideosource.cpp \
 157     src/sidebarheader.cpp \
 158     src/iconutils.cpp \
 159     src/diskcache.cpp \
 160     src/gridwidget.cpp \
 161     src/painterutils.cpp \
 162     src/database.cpp \
 163     src/channelaggregator.cpp \
 164     src/channelmodel.cpp \
 165     src/aggregatevideosource.cpp \
 166     src/channelview.cpp \
 167     src/channelitemdelegate.cpp \
 168     src/jsfunctions.cpp \
 169     src/seekslider.cpp \
 170     src/snapshotsettings.cpp \
 171     src/snapshotpreview.cpp \
 172     src/datautils.cpp \
 173     src/yt3listparser.cpp \
 174     src/ytchannel.cpp \
 175     src/yt3.cpp \
 176     src/paginatedvideosource.cpp \
 177     src/channellistview.cpp \
 178     src/httputils.cpp \
 179     src/appwidget.cpp \
 180     src/clickablelabel.cpp \
 181     src/ytvideo.cpp \
 182     src/toolbarmenu.cpp \
 183     src/sharetoolbar.cpp \
 184     src/videoarea.cpp \
 185     src/searchlineedit.cpp
 186
 187 RESOURCES += resources.qrc
 188 RESOURCES += $$files(icons/*.png, true)
 189
 190 DESTDIR = build/target/
 191 OBJECTS_DIR = build/obj/
 192 MOC_DIR = build/moc/
 193 RCC_DIR = build/rcc/
 194
 195 # Tell Qt Linguist that we use UTF-8 strings in our sources
 196 CODECFORTR = UTF-8
 197 CODECFORSRC = UTF-8
 198
 199 include(locale/locale.pri)
 200
 201 # deploy
 202 DISTFILES += CHANGES COPYING
 203 unix:!mac {
 204     DEFINES += APP_LINUX
 205     QT += dbus
 206     HEADERS += src/gnomeglobalshortcutbackend.h
 207     SOURCES += src/gnomeglobalshortcutbackend.cpp
 208
 209     isEmpty(PREFIX):PREFIX = /usr
 210
 211     BINDIR = $$PREFIX/bin
 212     INSTALLS += target
 213     target.path = $$BINDIR
 214
 215     DATADIR = $$PREFIX/share
 216     PKGDATADIR = $$DATADIR/minitube
 217     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 218         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 219
 220     INSTALLS += translations \
 221         sounds \
 222         desktop \
 223         appdata \
 224         iconsvg \
 225         icon16 \
 226         icon22 \
 227         icon32 \
 228         icon48 \
 229         icon64 \
 230         icon128 \
 231         icon256 \
 232         icon512
 233     translations.path = $$PKGDATADIR
 234     translations.files += $$DESTDIR/locale
 235     sounds.path = $$PKGDATADIR
 236     sounds.files += sounds/
 237     desktop.path = $$DATADIR/applications
 238     desktop.files += minitube.desktop
 239     appdata.path = $$DATADIR/appdata
 240     appdata.files += minitube.appdata.xml
 241     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 242     iconsvg.files += data/minitube.svg
 243     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 244     icon16.files += data/16x16/minitube.png
 245     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 246     icon22.files += data/22x22/minitube.png
 247     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 248     icon32.files += data/32x32/minitube.png
 249     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 250     icon48.files += data/48x48/minitube.png
 251     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 252     icon64.files += data/64x64/minitube.png
 253     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 254     icon128.files += data/128x128/minitube.png
 255     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 256     icon256.files += data/256x256/minitube.png
 257     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 258     icon512.files += data/512x512/minitube.png
 259 }
 260
 261 mac|win32|contains(DEFINES, APP_UBUNTU):include(local/local.pri)