git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 1.4.3
   4 DEFINES += APP_VERSION="$$VERSION"
   5 INCLUDEPATH += /usr/include/phonon
   6
   7 # TODO Saner string behaviour
   8 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
   9 TARGET = minitube
  10 QT += network \
  11     xml \
  12     phonon
  13 include(src/qtsingleapplication/qtsingleapplication.pri)
  14 HEADERS += src/MainWindow.h \
  15     src/SearchView.h \
  16     src/MediaView.h \
  17     src/AboutView.h \
  18     src/youtubesearch.h \
  19     src/video.h \
  20     src/youtubestreamreader.h \
  21     src/View.h \
  22     src/searchlineedit.h \
  23     src/urllineedit.h \
  24     src/spacer.h \
  25     src/constants.h \
  26     src/iconloader/qticonloader.h \
  27     src/faderwidget/FaderWidget.h \
  28     src/ListModel.h \
  29     src/playlist/PrettyItemDelegate.h \
  30     src/networkaccess.h \
  31     src/videomimedata.h \
  32     src/global.h \
  33     src/updatechecker.h \
  34     src/playlistwidget.h \
  35     src/searchparams.h \
  36     src/minisplitter.h \
  37     src/loadingwidget.h \
  38     src/videoareawidget.h \
  39     src/autocomplete.h \
  40     src/videowidget.h \
  41     src/videodefinition.h \
  42     src/fontutils.h \
  43     src/thlibrary/thblackbar.h \
  44     src/globalshortcuts.h \
  45     src/globalshortcutbackend.h \
  46     src/downloadmanager.h \
  47     src/downloaditem.h \
  48     src/downloadview.h \
  49     src/downloadmodel.h \
  50     src/downloadlistview.h \
  51     src/downloadsettings.h \
  52     src/youtubesuggest.h \
  53     src/suggester.h \
  54     src/channelsuggest.h
  55 SOURCES += src/main.cpp \
  56     src/MainWindow.cpp \
  57     src/SearchView.cpp \
  58     src/MediaView.cpp \
  59     src/AboutView.cpp \
  60     src/youtubesearch.cpp \
  61     src/youtubestreamreader.cpp \
  62     src/searchlineedit.cpp \
  63     src/urllineedit.cpp \
  64     src/spacer.cpp \
  65     src/video.cpp \
  66     src/iconloader/qticonloader.cpp \
  67     src/faderwidget/FaderWidget.cpp \
  68     src/ListModel.cpp \
  69     src/playlist/PrettyItemDelegate.cpp \
  70     src/videomimedata.cpp \
  71     src/updatechecker.cpp \
  72     src/networkaccess.cpp \
  73     src/playlistwidget.cpp \
  74     src/searchparams.cpp \
  75     src/minisplitter.cpp \
  76     src/loadingwidget.cpp \
  77     src/videoareawidget.cpp \
  78     src/autocomplete.cpp \
  79     src/videowidget.cpp \
  80     src/videodefinition.cpp \
  81     src/constants.cpp \
  82     src/fontutils.cpp \
  83     src/thlibrary/thblackbar.cpp \
  84     src/globalshortcuts.cpp \
  85     src/globalshortcutbackend.cpp \
  86     src/downloadmanager.cpp \
  87     src/downloaditem.cpp \
  88     src/downloadview.cpp \
  89     src/downloadmodel.cpp \
  90     src/downloadlistview.cpp \
  91     src/downloadsettings.cpp \
  92     src/youtubesuggest.cpp \
  93     src/channelsuggest.cpp
  94 RESOURCES += resources.qrc
  95 DESTDIR = build/target/
  96 OBJECTS_DIR = build/obj/
  97 MOC_DIR = build/moc/
  98 RCC_DIR = build/rcc/
  99
 100 # Tell Qt Linguist that we use UTF-8 strings in our sources
 101 CODECFORTR = UTF-8
 102 CODECFORSRC = UTF-8
 103 include(locale/locale.pri)
 104
 105 # deploy
 106 DISTFILES += CHANGES \
 107     COPYING
 108 unix:!mac {
 109     QT += dbus
 110     HEADERS += src/gnomeglobalshortcutbackend.h
 111     SOURCES += src/gnomeglobalshortcutbackend.cpp
 112     isEmpty(PREFIX):PREFIX = /usr
 113     BINDIR = $$PREFIX/bin
 114     INSTALLS += target
 115     target.path = $$BINDIR
 116     DATADIR = $$PREFIX/share
 117     PKGDATADIR = $$DATADIR/minitube
 118     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 119         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 120     INSTALLS += translations \
 121         desktop \
 122         iconsvg \
 123         icon16 \
 124         icon22 \
 125         icon32 \
 126         icon48 \
 127         icon64 \
 128         icon128 \
 129         icon256 \
 130         icon512
 131     translations.path = $$PKGDATADIR
 132     translations.files += $$DESTDIR/locale
 133     desktop.path = $$DATADIR/applications
 134     desktop.files += minitube.desktop
 135     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 136     iconsvg.files += data/minitube.svg
 137     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 138     icon16.files += data/16x16/minitube.png
 139     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 140     icon22.files += data/22x22/minitube.png
 141     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 142     icon32.files += data/32x32/minitube.png
 143     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 144     icon48.files += data/48x48/minitube.png
 145     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 146     icon64.files += data/64x64/minitube.png
 147     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 148     icon128.files += data/128x128/minitube.png
 149     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 150     icon256.files += data/256x256/minitube.png
 151     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 152     icon512.files += data/512x512/minitube.png
 153 }
 154 mac|win32:include(local/local.pri)