git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 1.6
   4 DEFINES += APP_VERSION="$$VERSION"
   5 INCLUDEPATH += /usr/include/phonon
   6
   7 APP_NAME = Minitube
   8 DEFINES += APP_NAME="$$APP_NAME"
   9
  10 APP_UNIX_NAME = minitube
  11 DEFINES += APP_UNIX_NAME="$$APP_UNIX_NAME"
  12
  13 DEFINES += QT_USE_FAST_CONCATENATION
  14 DEFINES += QT_USE_FAST_OPERATOR_PLUS
  15
  16 # TODO Saner string behaviour
  17 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
  18 TARGET = minitube
  19 QT += network \
  20     xml \
  21     phonon
  22 include(src/qtsingleapplication/qtsingleapplication.pri)
  23 HEADERS += src/MainWindow.h \
  24     src/SearchView.h \
  25     src/MediaView.h \
  26     src/AboutView.h \
  27     src/youtubesearch.h \
  28     src/video.h \
  29     src/youtubestreamreader.h \
  30     src/View.h \
  31     src/searchlineedit.h \
  32     src/urllineedit.h \
  33     src/spacer.h \
  34     src/constants.h \
  35     src/iconloader/qticonloader.h \
  36     src/ListModel.h \
  37     src/playlist/PrettyItemDelegate.h \
  38     src/networkaccess.h \
  39     src/videomimedata.h \
  40     src/global.h \
  41     src/updatechecker.h \
  42     src/playlistwidget.h \
  43     src/searchparams.h \
  44     src/minisplitter.h \
  45     src/loadingwidget.h \
  46     src/videoareawidget.h \
  47     src/autocomplete.h \
  48     src/videowidget.h \
  49     src/videodefinition.h \
  50     src/fontutils.h \
  51     src/thlibrary/thblackbar.h \
  52     src/globalshortcuts.h \
  53     src/globalshortcutbackend.h \
  54     src/downloadmanager.h \
  55     src/downloaditem.h \
  56     src/downloadview.h \
  57     src/downloadmodel.h \
  58     src/downloadlistview.h \
  59     src/downloadsettings.h \
  60     src/youtubesuggest.h \
  61     src/suggester.h \
  62     src/channelsuggest.h \
  63     src/temporary.h
  64 SOURCES += src/main.cpp \
  65     src/MainWindow.cpp \
  66     src/SearchView.cpp \
  67     src/MediaView.cpp \
  68     src/AboutView.cpp \
  69     src/youtubesearch.cpp \
  70     src/youtubestreamreader.cpp \
  71     src/searchlineedit.cpp \
  72     src/urllineedit.cpp \
  73     src/spacer.cpp \
  74     src/video.cpp \
  75     src/iconloader/qticonloader.cpp \
  76     src/ListModel.cpp \
  77     src/playlist/PrettyItemDelegate.cpp \
  78     src/videomimedata.cpp \
  79     src/updatechecker.cpp \
  80     src/networkaccess.cpp \
  81     src/playlistwidget.cpp \
  82     src/searchparams.cpp \
  83     src/minisplitter.cpp \
  84     src/loadingwidget.cpp \
  85     src/videoareawidget.cpp \
  86     src/autocomplete.cpp \
  87     src/videowidget.cpp \
  88     src/videodefinition.cpp \
  89     src/constants.cpp \
  90     src/fontutils.cpp \
  91     src/thlibrary/thblackbar.cpp \
  92     src/globalshortcuts.cpp \
  93     src/globalshortcutbackend.cpp \
  94     src/downloadmanager.cpp \
  95     src/downloaditem.cpp \
  96     src/downloadview.cpp \
  97     src/downloadmodel.cpp \
  98     src/downloadlistview.cpp \
  99     src/downloadsettings.cpp \
 100     src/youtubesuggest.cpp \
 101     src/channelsuggest.cpp \
 102     src/temporary.cpp
 103 RESOURCES += resources.qrc
 104 DESTDIR = build/target/
 105 OBJECTS_DIR = build/obj/
 106 MOC_DIR = build/moc/
 107 RCC_DIR = build/rcc/
 108
 109 # Tell Qt Linguist that we use UTF-8 strings in our sources
 110 CODECFORTR = UTF-8
 111 CODECFORSRC = UTF-8
 112 include(locale/locale.pri)
 113
 114 # deploy
 115 DISTFILES += CHANGES \
 116     COPYING
 117 unix:!mac {
 118     QT += dbus
 119     HEADERS += src/gnomeglobalshortcutbackend.h
 120     SOURCES += src/gnomeglobalshortcutbackend.cpp
 121     isEmpty(PREFIX):PREFIX = /usr
 122     BINDIR = $$PREFIX/bin
 123     INSTALLS += target
 124     target.path = $$BINDIR
 125     DATADIR = $$PREFIX/share
 126     PKGDATADIR = $$DATADIR/minitube
 127     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 128         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 129     INSTALLS += translations \
 130         desktop \
 131         iconsvg \
 132         icon16 \
 133         icon22 \
 134         icon32 \
 135         icon48 \
 136         icon64 \
 137         icon128 \
 138         icon256 \
 139         icon512
 140     translations.path = $$PKGDATADIR
 141     translations.files += $$DESTDIR/locale
 142     desktop.path = $$DATADIR/applications
 143     desktop.files += minitube.desktop
 144     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 145     iconsvg.files += data/minitube.svg
 146     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 147     icon16.files += data/16x16/minitube.png
 148     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 149     icon22.files += data/22x22/minitube.png
 150     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 151     icon32.files += data/32x32/minitube.png
 152     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 153     icon48.files += data/48x48/minitube.png
 154     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 155     icon64.files += data/64x64/minitube.png
 156     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 157     icon128.files += data/128x128/minitube.png
 158     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 159     icon256.files += data/256x256/minitube.png
 160     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 161     icon512.files += data/512x512/minitube.png
 162 }
 163 mac|win32:include(local/local.pri)
 164