git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 2.0
   4 DEFINES += APP_VERSION="$$VERSION"
   5
   6 APP_NAME = Minitube
   7 DEFINES += APP_NAME="$$APP_NAME"
   8
   9 APP_UNIX_NAME = minitube
  10 DEFINES += APP_UNIX_NAME="$$APP_UNIX_NAME"
  11
  12 DEFINES += QT_USE_FAST_CONCATENATION
  13 DEFINES += QT_USE_FAST_OPERATOR_PLUS
  14 DEFINES += QT_STRICT_ITERATORS
  15
  16 TARGET = minitube
  17 QT += network xml phonon
  18 include(src/qtsingleapplication/qtsingleapplication.pri)
  19 HEADERS += \
  20     src/video.h \
  21     src/searchlineedit.h \
  22     src/urllineedit.h \
  23     src/spacer.h \
  24     src/constants.h \
  25     src/playlistitemdelegate.h \
  26     src/networkaccess.h \
  27     src/videomimedata.h \
  28     src/global.h \
  29     src/updatechecker.h \
  30     src/searchparams.h \
  31     src/minisplitter.h \
  32     src/loadingwidget.h \
  33     src/videoareawidget.h \
  34     src/autocomplete.h \
  35     src/videodefinition.h \
  36     src/fontutils.h \
  37     src/globalshortcuts.h \
  38     src/globalshortcutbackend.h \
  39     src/downloadmanager.h \
  40     src/downloaditem.h \
  41     src/downloadview.h \
  42     src/downloadmodel.h \
  43     src/downloadlistview.h \
  44     src/downloadsettings.h \
  45     src/suggester.h \
  46     src/channelsuggest.h \
  47     src/temporary.h \
  48     src/segmentedcontrol.h \
  49     src/playlistview.h \
  50     src/refinesearchwidget.h \
  51     src/refinesearchbutton.h \
  52     src/sidebarwidget.h \
  53     src/homeview.h \
  54     src/aboutview.h \
  55     src/mainwindow.h \
  56     src/mediaview.h \
  57     src/searchview.h \
  58     src/view.h \
  59     src/userview.h \
  60     src/playlistmodel.h \
  61     src/videosource.h \
  62     src/ytsearch.h \
  63     src/ytstandardfeed.h \
  64     src/standardfeedsview.h \
  65     src/ytregions.h \
  66     src/ytcategories.h \
  67     src/ytfeedreader.h \
  68     src/ytsuggester.h \
  69     src/videosourcewidget.h \
  70     src/regionsview.h \
  71     src/ytsinglevideosource.h \
  72     src/sidebarheader.h \
  73     src/utils.h \
  74     src/diskcache.h
  75 SOURCES += src/main.cpp \
  76     src/searchlineedit.cpp \
  77     src/urllineedit.cpp \
  78     src/spacer.cpp \
  79     src/video.cpp \
  80     src/videomimedata.cpp \
  81     src/updatechecker.cpp \
  82     src/networkaccess.cpp \
  83     src/searchparams.cpp \
  84     src/minisplitter.cpp \
  85     src/loadingwidget.cpp \
  86     src/videoareawidget.cpp \
  87     src/autocomplete.cpp \
  88     src/videodefinition.cpp \
  89     src/constants.cpp \
  90     src/fontutils.cpp \
  91     src/globalshortcuts.cpp \
  92     src/globalshortcutbackend.cpp \
  93     src/downloadmanager.cpp \
  94     src/downloaditem.cpp \
  95     src/downloadview.cpp \
  96     src/downloadmodel.cpp \
  97     src/downloadlistview.cpp \
  98     src/downloadsettings.cpp \
  99     src/channelsuggest.cpp \
 100     src/temporary.cpp \
 101     src/segmentedcontrol.cpp \
 102     src/playlistview.cpp \
 103     src/refinesearchwidget.cpp \
 104     src/refinesearchbutton.cpp \
 105     src/sidebarwidget.cpp \
 106     src/homeview.cpp \
 107     src/mainwindow.cpp \
 108     src/mediaview.cpp \
 109     src/aboutview.cpp \
 110     src/searchview.cpp \
 111     src/userview.cpp \
 112     src/playlistitemdelegate.cpp \
 113     src/playlistmodel.cpp \
 114     src/videosource.cpp \
 115     src/ytsearch.cpp \
 116     src/ytstandardfeed.cpp \
 117     src/standardfeedsview.cpp \
 118     src/ytregions.cpp \
 119     src/ytcategories.cpp \
 120     src/ytfeedreader.cpp \
 121     src/ytsuggester.cpp \
 122     src/videosourcewidget.cpp \
 123     src/regionsview.cpp \
 124     src/ytsinglevideosource.cpp \
 125     src/sidebarheader.cpp \
 126     src/utils.cpp \
 127     src/diskcache.cpp
 128 RESOURCES += resources.qrc
 129 DESTDIR = build/target/
 130 OBJECTS_DIR = build/obj/
 131 MOC_DIR = build/moc/
 132 RCC_DIR = build/rcc/
 133
 134 # Tell Qt Linguist that we use UTF-8 strings in our sources
 135 CODECFORTR = UTF-8
 136 CODECFORSRC = UTF-8
 137 include(locale/locale.pri)
 138
 139 # deploy
 140 DISTFILES += CHANGES COPYING
 141 unix:!mac {
 142     INCLUDEPATH += /usr/include/phonon
 143     QT += dbus
 144     HEADERS += src/gnomeglobalshortcutbackend.h
 145     SOURCES += src/gnomeglobalshortcutbackend.cpp
 146     isEmpty(PREFIX):PREFIX = /usr
 147     BINDIR = $$PREFIX/bin
 148     INSTALLS += target
 149     target.path = $$BINDIR
 150     DATADIR = $$PREFIX/share
 151     PKGDATADIR = $$DATADIR/minitube
 152     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 153         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 154     INSTALLS += translations \
 155         desktop \
 156         iconsvg \
 157         icon16 \
 158         icon22 \
 159         icon32 \
 160         icon48 \
 161         icon64 \
 162         icon128 \
 163         icon256 \
 164         icon512
 165     translations.path = $$PKGDATADIR
 166     translations.files += $$DESTDIR/locale
 167     desktop.path = $$DATADIR/applications
 168     desktop.files += minitube.desktop
 169     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 170     iconsvg.files += data/minitube.svg
 171     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 172     icon16.files += data/16x16/minitube.png
 173     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 174     icon22.files += data/22x22/minitube.png
 175     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 176     icon32.files += data/32x32/minitube.png
 177     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 178     icon48.files += data/48x48/minitube.png
 179     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 180     icon64.files += data/64x64/minitube.png
 181     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 182     icon128.files += data/128x128/minitube.png
 183     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 184     icon256.files += data/256x256/minitube.png
 185     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 186     icon512.files += data/512x512/minitube.png
 187 }
 188 mac|win32:include(local/local.pri)