git.sur5r.net Git - minitube/blob - minitube.pro

   1 CONFIG += release
   2 TEMPLATE = app
   3 VERSION = 1.9
   4 DEFINES += APP_VERSION="$$VERSION"
   5
   6 APP_NAME = Minitube
   7 DEFINES += APP_NAME="$$APP_NAME"
   8
   9 APP_UNIX_NAME = minitube
  10 DEFINES += APP_UNIX_NAME="$$APP_UNIX_NAME"
  11
  12 DEFINES += QT_USE_FAST_CONCATENATION
  13 DEFINES += QT_USE_FAST_OPERATOR_PLUS
  14
  15 # TODO Saner string behaviour
  16 # DEFINES += QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII QT_STRICT_ITERATORS
  17 TARGET = minitube
  18 QT += network \
  19     xml \
  20     phonon
  21 include(src/qtsingleapplication/qtsingleapplication.pri)
  22 HEADERS += src/MainWindow.h \
  23     src/SearchView.h \
  24     src/MediaView.h \
  25     src/AboutView.h \
  26     src/youtubesearch.h \
  27     src/video.h \
  28     src/youtubestreamreader.h \
  29     src/View.h \
  30     src/searchlineedit.h \
  31     src/urllineedit.h \
  32     src/spacer.h \
  33     src/constants.h \
  34     src/iconloader/qticonloader.h \
  35     src/ListModel.h \
  36     src/playlist/PrettyItemDelegate.h \
  37     src/networkaccess.h \
  38     src/videomimedata.h \
  39     src/global.h \
  40     src/updatechecker.h \
  41     src/playlistwidget.h \
  42     src/searchparams.h \
  43     src/minisplitter.h \
  44     src/loadingwidget.h \
  45     src/videoareawidget.h \
  46     src/autocomplete.h \
  47     src/videodefinition.h \
  48     src/fontutils.h \
  49     src/globalshortcuts.h \
  50     src/globalshortcutbackend.h \
  51     src/downloadmanager.h \
  52     src/downloaditem.h \
  53     src/downloadview.h \
  54     src/downloadmodel.h \
  55     src/downloadlistview.h \
  56     src/downloadsettings.h \
  57     src/youtubesuggest.h \
  58     src/suggester.h \
  59     src/channelsuggest.h \
  60     src/temporary.h \
  61     src/segmentedcontrol.h \
  62     src/playlistview.h \
  63     src/refinesearchwidget.h \
  64     src/refinesearchbutton.h \
  65     src/sidebarwidget.h
  66 SOURCES += src/main.cpp \
  67     src/MainWindow.cpp \
  68     src/SearchView.cpp \
  69     src/MediaView.cpp \
  70     src/AboutView.cpp \
  71     src/youtubesearch.cpp \
  72     src/youtubestreamreader.cpp \
  73     src/searchlineedit.cpp \
  74     src/urllineedit.cpp \
  75     src/spacer.cpp \
  76     src/video.cpp \
  77     src/iconloader/qticonloader.cpp \
  78     src/ListModel.cpp \
  79     src/playlist/PrettyItemDelegate.cpp \
  80     src/videomimedata.cpp \
  81     src/updatechecker.cpp \
  82     src/networkaccess.cpp \
  83     src/playlistwidget.cpp \
  84     src/searchparams.cpp \
  85     src/minisplitter.cpp \
  86     src/loadingwidget.cpp \
  87     src/videoareawidget.cpp \
  88     src/autocomplete.cpp \
  89     src/videodefinition.cpp \
  90     src/constants.cpp \
  91     src/fontutils.cpp \
  92     src/globalshortcuts.cpp \
  93     src/globalshortcutbackend.cpp \
  94     src/downloadmanager.cpp \
  95     src/downloaditem.cpp \
  96     src/downloadview.cpp \
  97     src/downloadmodel.cpp \
  98     src/downloadlistview.cpp \
  99     src/downloadsettings.cpp \
 100     src/youtubesuggest.cpp \
 101     src/channelsuggest.cpp \
 102     src/temporary.cpp \
 103     src/segmentedcontrol.cpp \
 104     src/playlistview.cpp \
 105     src/refinesearchwidget.cpp \
 106     src/refinesearchbutton.cpp \
 107     src/sidebarwidget.cpp
 108 RESOURCES += resources.qrc
 109 DESTDIR = build/target/
 110 OBJECTS_DIR = build/obj/
 111 MOC_DIR = build/moc/
 112 RCC_DIR = build/rcc/
 113
 114 # Tell Qt Linguist that we use UTF-8 strings in our sources
 115 CODECFORTR = UTF-8
 116 CODECFORSRC = UTF-8
 117 include(locale/locale.pri)
 118
 119 # deploy
 120 DISTFILES += CHANGES \
 121     COPYING
 122 unix:!mac {
 123     INCLUDEPATH += /usr/include/phonon
 124     QT += dbus
 125     HEADERS += src/gnomeglobalshortcutbackend.h
 126     SOURCES += src/gnomeglobalshortcutbackend.cpp
 127     isEmpty(PREFIX):PREFIX = /usr
 128     BINDIR = $$PREFIX/bin
 129     INSTALLS += target
 130     target.path = $$BINDIR
 131     DATADIR = $$PREFIX/share
 132     PKGDATADIR = $$DATADIR/minitube
 133     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 134         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 135     INSTALLS += translations \
 136         desktop \
 137         iconsvg \
 138         icon16 \
 139         icon22 \
 140         icon32 \
 141         icon48 \
 142         icon64 \
 143         icon128 \
 144         icon256 \
 145         icon512
 146     translations.path = $$PKGDATADIR
 147     translations.files += $$DESTDIR/locale
 148     desktop.path = $$DATADIR/applications
 149     desktop.files += minitube.desktop
 150     iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
 151     iconsvg.files += data/minitube.svg
 152     icon16.path = $$DATADIR/icons/hicolor/16x16/apps
 153     icon16.files += data/16x16/minitube.png
 154     icon22.path = $$DATADIR/icons/hicolor/22x22/apps
 155     icon22.files += data/22x22/minitube.png
 156     icon32.path = $$DATADIR/icons/hicolor/32x32/apps
 157     icon32.files += data/32x32/minitube.png
 158     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 159     icon48.files += data/48x48/minitube.png
 160     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 161     icon64.files += data/64x64/minitube.png
 162     icon128.path = $$DATADIR/icons/hicolor/128x128/apps
 163     icon128.files += data/128x128/minitube.png
 164     icon256.path = $$DATADIR/icons/hicolor/256x256/apps
 165     icon256.files += data/256x256/minitube.png
 166     icon512.path = $$DATADIR/icons/hicolor/512x512/apps
 167     icon512.files += data/512x512/minitube.png
 168 }
 169 mac|win32:include(local/local.pri)