git.sur5r.net Git - openocd/blob - testing/examples/STR710Test/prj/hitex_str7_ram.ld

   1 /***********************************************************************************\r
   2 *       Copyright 2005 Anglia Design\r
   3 *       This demo code and associated components are provided as is and has no warranty,\r
   4 *       implied or otherwise.  You are free to use/modify any of the provided\r
   5 *       code at your own risk in your applications with the expressed limitation\r
   6 *       of liability (see below)\r
   7 * \r
   8 *       LIMITATION OF LIABILITY:   ANGLIA OR ANGLIA DESIGNS SHALL NOT BE LIABLE FOR ANY\r
   9 *       LOSS OF PROFITS, LOSS OF USE, LOSS OF DATA, INTERRUPTION OF BUSINESS, NOR FOR\r
  10 *       INDIRECT, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES OF ANY KIND WHETHER UNDER\r
  11 *       THIS AGREEMENT OR OTHERWISE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.\r
  12 *\r
  13 *       Author                  : Spencer Oliver\r
  14 *       Web                     : www.anglia-designs.com\r
  15 *\r
  16 ***********************************************************************************/\r
  17 \r
  18 /* Stack Sizes */\r
  19 \r
  20         _STACKSIZE     = 1024;\r
  21         _STACKSIZE_IRQ = 256;\r
  22         _STACKSIZE_FIQ = 0;\r
  23         _STACKSIZE_SVC = 1024;\r
  24         _STACKSIZE_ABT = 0;\r
  25         _STACKSIZE_UND = 0;\r
  26         _HEAPSIZE      = 1024;\r
  27   \r
  28 /* Memory Definitions */\r
  29 \r
  30 MEMORY\r
  31 {\r
  32         DATA (rw) : ORIGIN = 0x20000000, LENGTH = 0x00010000\r
  33 }\r
  34 \r
  35 /* Section Definitions */\r
  36 \r
  37 SECTIONS\r
  38 {       \r
  39         /* first section is .text which is used for code */\r
  40 \r
  41         .text :\r
  42         {\r
  43                 CREATE_OBJECT_SYMBOLS\r
  44                 KEEP(*(.vectrom))\r
  45                 KEEP(*(.init))\r
  46                 *(.text .text.*)\r
  47                 *(.gnu.linkonce.t.*)\r
  48                 *(.glue_7t) *(.glue_7) *(.vfp11_veneer)\r
  49                 KEEP(*(.fini))\r
  50                 *(.gcc_except_table)\r
  51         } >DATA =0\r
  52         . = ALIGN(4);\r
  53 \r
  54         /* .ctors .dtors are used for c++ constructors/destructors */\r
  55         \r
  56         .ctors :\r
  57         {\r
  58                 PROVIDE(__ctors_start__ = .);\r
  59                 KEEP(*(SORT(.ctors.*)))\r
  60                 KEEP(*(.ctors))\r
  61                 PROVIDE(__ctors_end__ = .);\r
  62         } >DATA\r
  63 \r
  64         .dtors :\r
  65         {\r
  66                 PROVIDE(__dtors_start__ = .); \r
  67                 KEEP(*(SORT(.dtors.*)))\r
  68                 KEEP(*(.dtors))\r
  69                 PROVIDE(__dtors_end__ = .);\r
  70         } >DATA\r
  71         \r
  72         /* .rodata section which is used for read-only data (constants) */\r
  73 \r
  74         .rodata :\r
  75         {\r
  76                 *(.rodata .rodata.*)\r
  77                 *(.gnu.linkonce.r.*)\r
  78         } >DATA\r
  79         . = ALIGN(4);\r
  80 \r
  81         .init_array :\r
  82         {\r
  83                 *(.init)\r
  84         *(.fini)\r
  85                 PROVIDE_HIDDEN (__preinit_array_start = .);\r
  86                 KEEP (*(.preinit_array))\r
  87                 PROVIDE_HIDDEN (__preinit_array_end = .);\r
  88                 PROVIDE_HIDDEN (__init_array_start = .);\r
  89                 KEEP (*(SORT(.init_array.*)))\r
  90                 KEEP (*(.init_array))\r
  91                 PROVIDE_HIDDEN (__init_array_end = .);\r
  92                 PROVIDE_HIDDEN (__fini_array_start = .);\r
  93                 KEEP (*(.fini_array))\r
  94                 KEEP (*(SORT(.fini_array.*)))\r
  95                 PROVIDE_HIDDEN (__fini_array_end = .);\r
  96         } >DATA\r
  97 \r
  98         . = ALIGN(4);\r
  99         \r
 100         /* .ARM.exidx is sorted, so has to go in its own output section.  */\r
 101         __exidx_start = .;\r
 102         .ARM.exidx :\r
 103         {\r
 104                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)\r
 105         } >DATA\r
 106         __exidx_end = .;\r
 107 \r
 108         _vectext = .;\r
 109         PROVIDE (vectext = .);\r
 110 \r
 111         .vect : AT (_vectext)\r
 112         {\r
 113                 _vecstart = .;\r
 114                 KEEP(*(.vectram))\r
 115                 _vecend = .;\r
 116         } >DATA\r
 117 \r
 118         _etext = _vectext + SIZEOF(.vect);\r
 119         PROVIDE (etext = .);\r
 120 \r
 121         /* .data section which is used for initialized data */\r
 122 \r
 123         .data : AT (_etext)\r
 124         {\r
 125                 *(.data .data.*)\r
 126                 *(.gnu.linkonce.d.*)\r
 127                 SORT(CONSTRUCTORS)\r
 128         } >DATA\r
 129         . = ALIGN(4);\r
 130         \r
 131         __data_start = .;\r
 132         _edata = .;\r
 133         PROVIDE (edata = .);\r
 134 \r
 135         /* .bss section which is used for uninitialized data */\r
 136 \r
 137         .bss :\r
 138         {\r
 139                 __bss_start = .;\r
 140                 __bss_start__ = .;\r
 141                 *(.bss .bss.*)\r
 142                 *(.gnu.linkonce.b.*)\r
 143                 *(COMMON)\r
 144                 . = ALIGN(4);\r
 145         } >DATA\r
 146         . = ALIGN(4);\r
 147         __bss_end__ = .;\r
 148         \r
 149         _end = .;\r
 150         PROVIDE(end = .);\r
 151 \r
 152         /* .heap section which is used for memory allocation */\r
 153         \r
 154         .heap (NOLOAD) :\r
 155         {\r
 156                 __heap_start__ = .;\r
 157                 *(.heap)\r
 158                 . = MAX(__heap_start__ + _HEAPSIZE , .);\r
 159         } >DATA\r
 160         __heap_end__ = __heap_start__ + SIZEOF(.heap);\r
 161         \r
 162         /* .stack section - user mode stack */\r
 163         \r
 164         .stack (__heap_end__ + 3) / 4 * 4 (NOLOAD) :\r
 165         {\r
 166                 __stack_start__ = .;\r
 167                 *(.stack)\r
 168                 . = MAX(__stack_start__ + _STACKSIZE , .);\r
 169         } >DATA\r
 170         __stack_end__ = __stack_start__ + SIZEOF(.stack);\r
 171 \r
 172         /* .stack_irq section */\r
 173         \r
 174         .stack_irq (__stack_end__ + 3) / 4 * 4 (NOLOAD) :\r
 175         {\r
 176                 __stack_irq_start__ = .;\r
 177                 *(.stack_irq)\r
 178                 . = MAX(__stack_irq_start__ + _STACKSIZE_IRQ , .);\r
 179         } >DATA\r
 180         __stack_irq_end__ = __stack_irq_start__ + SIZEOF(.stack_irq);\r
 181 \r
 182         /* .stack_fiq section */\r
 183         \r
 184         .stack_fiq (__stack_irq_end__ + 3) / 4 * 4 (NOLOAD) :\r
 185         {\r
 186                 __stack_fiq_start__ = .;\r
 187                 *(.stack_fiq)\r
 188             . = MAX(__stack_fiq_start__ + _STACKSIZE_FIQ , .);\r
 189         } >DATA\r
 190         __stack_fiq_end__ = __stack_fiq_start__ + SIZEOF(.stack_fiq);\r
 191 \r
 192         /* .stack_svc section */\r
 193         \r
 194         .stack_svc (__stack_fiq_end__ + 3) / 4 * 4 (NOLOAD) :\r
 195         {\r
 196                 __stack_svc_start__ = .;\r
 197                 *(.stack_svc)\r
 198                 . = MAX(__stack_svc_start__ + _STACKSIZE_SVC , .);\r
 199         } >DATA\r
 200         __stack_svc_end__ = __stack_svc_start__ + SIZEOF(.stack_svc);\r
 201 \r
 202         /* .stack_abt section */\r
 203         \r
 204         .stack_abt (__stack_svc_end__ + 3) / 4 * 4 (NOLOAD) :\r
 205         {\r
 206                 __stack_abt_start__ = .;\r
 207                 *(.stack_abt)\r
 208                 . = MAX(__stack_abt_start__ + _STACKSIZE_ABT , .);\r
 209         } >DATA\r
 210         __stack_abt_end__ = __stack_abt_start__ + SIZEOF(.stack_abt);\r
 211 \r
 212         /* .stack_und section */\r
 213         \r
 214         .stack_und (__stack_abt_end__ + 3) / 4 * 4 (NOLOAD) :\r
 215         {\r
 216                 __stack_und_start__ = .;\r
 217                 *(.stack_und)\r
 218         . = MAX(__stack_und_start__ + _STACKSIZE_UND , .);\r
 219         } >DATA\r
 220         __stack_und_end__ = __stack_und_start__ + SIZEOF(.stack_und);\r
 221         \r
 222         /* Stabs debugging sections.  */\r
 223         .stab          0 : { *(.stab) }\r
 224         .stabstr       0 : { *(.stabstr) }\r
 225         .stab.excl     0 : { *(.stab.excl) }\r
 226         .stab.exclstr  0 : { *(.stab.exclstr) }\r
 227         .stab.index    0 : { *(.stab.index) }\r
 228         .stab.indexstr 0 : { *(.stab.indexstr) }\r
 229         .comment       0 : { *(.comment) }\r
 230         /* DWARF debug sections.\r
 231                 Symbols in the DWARF debugging sections are relative to the beginning\r
 232                 of the section so we begin them at 0.  */\r
 233         /* DWARF 1 */\r
 234         .debug          0 : { *(.debug) }\r
 235         .line           0 : { *(.line) }\r
 236         /* GNU DWARF 1 extensions */\r
 237         .debug_srcinfo  0 : { *(.debug_srcinfo) }\r
 238         .debug_sfnames  0 : { *(.debug_sfnames) }\r
 239         /* DWARF 1.1 and DWARF 2 */\r
 240         .debug_aranges  0 : { *(.debug_aranges) }\r
 241         .debug_pubnames 0 : { *(.debug_pubnames) }\r
 242         /* DWARF 2 */\r
 243         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }\r
 244         .debug_abbrev   0 : { *(.debug_abbrev) }\r
 245         .debug_line     0 : { *(.debug_line) }\r
 246         .debug_frame    0 : { *(.debug_frame) }\r
 247         .debug_str      0 : { *(.debug_str) }\r
 248         .debug_loc      0 : { *(.debug_loc) }\r
 249         .debug_macinfo  0 : { *(.debug_macinfo) }\r
 250         /* SGI/MIPS DWARF 2 extensions */\r
 251         .debug_weaknames 0 : { *(.debug_weaknames) }\r
 252         .debug_funcnames 0 : { *(.debug_funcnames) }\r
 253         .debug_typenames 0 : { *(.debug_typenames) }\r
 254         .debug_varnames  0 : { *(.debug_varnames) }     \r
 255 }\r