git.sur5r.net Git - tio/blob - configure.ac

   1 AC_PREREQ([2.68])
   2 AC_INIT([tio], [1.20], [], [tio], [https://tio.github.io])
   3 AC_CONFIG_HEADERS([src/include/config.h])
   4 AM_INIT_AUTOMAKE([1.11 foreign dist-xz no-dist-gzip -Wall -Werror])
   5 AM_SILENT_RULES([yes])
   6 AC_PROG_CC
   7 AC_LANG([C])
   8 AC_PROG_INSTALL
   9 AC_SYS_LARGEFILE
  10 PKG_PROG_PKG_CONFIG
  11
  12 # Handle bash completion
  13 AC_ARG_WITH([bash-completion-dir],
  14     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
  15                    [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
  16                    [],
  17                    [with_bash_completion_dir=yes])
  18
  19 if test "x$with_bash_completion_dir" = "xyes"; then
  20     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
  21         [BASH_COMPLETION_DIR="`pkg-config --variable=completionsdir bash-completion`"],
  22         [BASH_COMPLETION_DIR="${sysconfdir}/bash_completion.d"])
  23 else
  24     BASH_COMPLETION_DIR="$with_bash_completion_dir"
  25 fi
  26 AC_SUBST([BASH_COMPLETION_DIR])
  27 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
  28
  29 # TIO_CHECK_BAUDRATE(N)
  30 AC_DEFUN(
  31     [TIO_CHECK_BAUDRATE],
  32     [
  33         AC_CHECK_DECL([B$1], [tio_have_decl=1], [tio_have_decl=0], [[#include <termios.h>]])
  34         AS_IF([test $tio_have_decl = 1], [
  35             AC_SUBST([BAUDRATES], ["$BAUDRATES $1"])
  36             AC_SUBST([BAUDRATE_CASES], ["$BAUDRATE_CASES case $1: baudrate = B$1; break;"])]
  37         )
  38     ]
  39 )
  40
  41 # TIO_CHECK_BAUDRATES(N1, N2, ...)
  42 AC_DEFUN(
  43     [TIO_CHECK_BAUDRATES],
  44     [m4_foreach([n], [$@], [TIO_CHECK_BAUDRATE(m4_normalize(n))])]
  45 )
  46
  47 # Check for available terminal I/O speeds
  48 BAUDRATES=
  49 BAUDRATE_CASES=
  50 TIO_CHECK_BAUDRATES(
  51     0,
  52     50,
  53     75,
  54     110,
  55     134,
  56     150,
  57     200,
  58     300,
  59     600,
  60     1200,
  61     1800,
  62     2400,
  63     4800,
  64     7200,
  65     9600,
  66     14400,
  67     19200,
  68     28800,
  69     38400,
  70     57600,
  71     76800,
  72     115200,
  73     230400,
  74     460800,
  75     500000,
  76     576000,
  77     921600,
  78     1000000,
  79     1152000,
  80     1500000,
  81     2000000,
  82     2500000,
  83     3000000,
  84     3500000,
  85     4000000
  86 )
  87
  88 AC_DEFINE_UNQUOTED([AUTOCONF_BAUDRATE_CASES],[$BAUDRATE_CASES],[Switch cases for detected baud rates])
  89
  90 AC_CONFIG_FILES([Makefile])
  91 AC_CONFIG_FILES([src/Makefile])
  92 AC_CONFIG_FILES([src/bash-completion/tio])
  93 AC_CONFIG_FILES([man/Makefile])
  94 AC_OUTPUT