git.sur5r.net Git - tio/blob - configure.ac

   1 AC_PREREQ([2.68])
   2 AC_INIT([tio], [1.24], [], [tio], [https://tio.github.io])
   3 AC_CONFIG_HEADERS([src/include/config.h])
   4 AM_INIT_AUTOMAKE([1.11 foreign dist-xz no-dist-gzip -Wall -Werror])
   5 AM_SILENT_RULES([yes])
   6 AC_PROG_CC
   7 AC_LANG([C])
   8 AC_PROG_INSTALL
   9 AC_SYS_LARGEFILE
  10 PKG_PROG_PKG_CONFIG
  11
  12 # Handle bash completion
  13 AC_ARG_WITH([bash-completion-dir],
  14     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
  15                    [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
  16                    [],
  17                    [with_bash_completion_dir=yes])
  18
  19 if test "x$with_bash_completion_dir" = "xyes"; then
  20     BASH_COMPLETION_DIR="${datadir}/bash-completion/completions"
  21 else
  22     BASH_COMPLETION_DIR="$with_bash_completion_dir"
  23 fi
  24 AC_SUBST([BASH_COMPLETION_DIR])
  25 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
  26
  27 # TIO_CHECK_BAUDRATE(N)
  28 AC_DEFUN(
  29     [TIO_CHECK_BAUDRATE],
  30     [
  31         AC_CHECK_DECL([B$1], [tio_have_decl=1], [tio_have_decl=0], [[#include <termios.h>]])
  32         AS_IF([test $tio_have_decl = 1], [
  33             AC_SUBST([BAUDRATES], ["$BAUDRATES $1"])
  34             AC_SUBST([BAUDRATE_CASES], ["$BAUDRATE_CASES case $1: baudrate = B$1; break;"])]
  35         )
  36     ]
  37 )
  38
  39 # TIO_CHECK_BAUDRATES(N1, N2, ...)
  40 AC_DEFUN(
  41     [TIO_CHECK_BAUDRATES],
  42     [m4_foreach([n], [$@], [TIO_CHECK_BAUDRATE(m4_normalize(n))])]
  43 )
  44
  45 # Check for available terminal I/O speeds
  46 BAUDRATES=
  47 BAUDRATE_CASES=
  48 TIO_CHECK_BAUDRATES(
  49     0,
  50     50,
  51     75,
  52     110,
  53     134,
  54     150,
  55     200,
  56     300,
  57     600,
  58     1200,
  59     1800,
  60     2400,
  61     4800,
  62     7200,
  63     9600,
  64     14400,
  65     19200,
  66     28800,
  67     38400,
  68     57600,
  69     76800,
  70     115200,
  71     230400,
  72     460800,
  73     500000,
  74     576000,
  75     921600,
  76     1000000,
  77     1152000,
  78     1500000,
  79     2000000,
  80     2500000,
  81     3000000,
  82     3500000,
  83     4000000
  84 )
  85
  86 AC_DEFINE_UNQUOTED([AUTOCONF_BAUDRATE_CASES],[$BAUDRATE_CASES],[Switch cases for detected baud rates])
  87
  88 AC_CONFIG_FILES([Makefile])
  89 AC_CONFIG_FILES([src/Makefile])
  90 AC_CONFIG_FILES([src/bash-completion/tio])
  91 AC_CONFIG_FILES([man/Makefile])
  92 AC_OUTPUT