git.sur5r.net Git - tio/blob - meson.build

   1 project('tio', 'c',
   2     version : '1.42',
   3     license : [ 'GPL-2'],
   4     meson_version : '>= 0.53.2',
   5     default_options : [ 'warning_level=2', 'buildtype=release', 'c_std=gnu99' ]
   6 )
   7
   8 # The tag date of the project_version(), update when the version bumps.
   9 version_date = '2022-07-04'
  10
  11 # Test for dynamic baudrate configuration interface
  12 compiler = meson.get_compiler('c')
  13 enable_setspeed2 = false
  14 enable_iossiospeed = false
  15 if host_machine.system() != 'darwin'
  16   if compiler.check_header('asm-generic/ioctls.h')
  17     enable_setspeed2 = compiler.has_header_symbol('asm-generic/ioctls.h', 'TCGETS2')
  18   endif
  19 else
  20   if compiler.check_header('IOKit/serial/ioss.h')
  21     enable_iossiospeed = compiler.has_header_symbol('IOKit/serial/ioss.h', 'IOSSIOSPEED')
  22   endif
  23 endif
  24
  25 # Test for supported baudrates
  26 test_baudrates = [
  27     0,
  28     50,
  29     75,
  30     110,
  31     134,
  32     150,
  33     200,
  34     300,
  35     600,
  36     1200,
  37     1800,
  38     2400,
  39     4800,
  40     7200,
  41     9600,
  42     14400,
  43     19200,
  44     28800,
  45     38400,
  46     57600,
  47     76800,
  48     115200,
  49     230400,
  50     460800,
  51     500000,
  52     576000,
  53     921600,
  54     1000000,
  55     1152000,
  56     1500000,
  57     2000000,
  58     2500000,
  59     3000000,
  60     3500000,
  61     4000000 ]
  62
  63 baudrates = ''
  64 baudrate_cases = ''
  65 foreach rate : test_baudrates
  66   baudrate = rate.to_string()
  67   value = compiler.get_define('B' + baudrate, prefix: '#include <termios.h>')
  68   if value != ''
  69     baudrates = baudrates + baudrate + ' '
  70     baudrate_cases = baudrate_cases + ' case ' + baudrate + ': baudrate = B' + baudrate + '; break;'
  71   endif
  72 endforeach
  73
  74 subdir('src')
  75 subdir('man')