git.sur5r.net Git - u-boot/blob - arch/arm/cpu/arm926ejs/mxs/u-boot-spl.lds

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  * Copyright (C) 2011 Marek Vasut <marek.vasut@gmail.com>
   4  * on behalf of DENX Software Engineering GmbH
   5  *
   6  * January 2004 - Changed to support H4 device
   7  * Copyright (c) 2004-2008 Texas Instruments
   8  *
   9  * (C) Copyright 2002
  10  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  11  */
  12
  13 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  14 OUTPUT_ARCH(arm)
  15 ENTRY(_start)
  16 SECTIONS
  17 {
  18         . = CONFIG_SPL_TEXT_BASE;
  19
  20         . = ALIGN(4);
  21         .text   :
  22         {
  23                 *(.vectors)
  24                 arch/arm/cpu/arm926ejs/mxs/start.o      (.text*)
  25                 *(.text*)
  26         }
  27
  28         . = ALIGN(4);
  29         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  30
  31         . = ALIGN(4);
  32         .data : {
  33                 *(.data*)
  34         }
  35
  36         . = ALIGN(4);
  37
  38         .rel.dyn : {
  39                 __rel_dyn_start = .;
  40                 *(.rel*)
  41                 __rel_dyn_end = .;
  42         }
  43
  44         .bss : {
  45                 . = ALIGN(4);
  46                 __bss_start = .;
  47                 *(.bss*)
  48                 . = ALIGN(4);
  49                 __bss_end = .;
  50         }
  51
  52         .end :
  53         {
  54                 *(.__end)
  55         }
  56
  57         _image_binary_end = .;
  58
  59         .dynsym _image_binary_end : { *(.dynsym) }
  60         .dynbss : { *(.dynbss) }
  61         .dynstr : { *(.dynstr*) }
  62         .dynamic : { *(.dynamic*) }
  63         .hash : { *(.hash*) }
  64         .plt : { *(.plt*) }
  65         .interp : { *(.interp*) }
  66         .gnu : { *(.gnu*) }
  67         .ARM.exidx : { *(.ARM.exidx*) }
  68 }