git.sur5r.net Git - u-boot/blob - cpu/arm920t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27
  28 #include <config.h>
  29 #include <version.h>
  30
  31
  32 /*
  33  *************************************************************************
  34  *
  35  * Jump vector table as in table 3.1 in [1]
  36  *
  37  *************************************************************************
  38  */
  39
  40
  41 .globl _start
  42 _start: b       reset
  43         ldr     pc, _undefined_instruction
  44         ldr     pc, _software_interrupt
  45         ldr     pc, _prefetch_abort
  46         ldr     pc, _data_abort
  47         ldr     pc, _not_used
  48         ldr     pc, _irq
  49         ldr     pc, _fiq
  50
  51 _undefined_instruction: .word undefined_instruction
  52 _software_interrupt:    .word software_interrupt
  53 _prefetch_abort:        .word prefetch_abort
  54 _data_abort:            .word data_abort
  55 _not_used:              .word not_used
  56 _irq:                   .word irq
  57 _fiq:                   .word fiq
  58
  59         .balignl 16,0xdeadbeef
  60
  61
  62 /*
  63  *************************************************************************
  64  *
  65  * Startup Code (reset vector)
  66  *
  67  * do important init only if we don't start from memory!
  68  * relocate armboot to ram
  69  * setup stack
  70  * jump to second stage
  71  *
  72  *************************************************************************
  73  */
  74
  75 _TEXT_BASE:
  76         .word   TEXT_BASE
  77
  78 .globl _armboot_start
  79 _armboot_start:
  80         .word _start
  81
  82 /*
  83  * These are defined in the board-specific linker script.
  84  */
  85 .globl _bss_start
  86 _bss_start:
  87         .word __bss_start
  88
  89 .globl _bss_end
  90 _bss_end:
  91         .word _end
  92
  93 #ifdef CONFIG_USE_IRQ
  94 /* IRQ stack memory (calculated at run-time) */
  95 .globl IRQ_STACK_START
  96 IRQ_STACK_START:
  97         .word   0x0badc0de
  98
  99 /* IRQ stack memory (calculated at run-time) */
 100 .globl FIQ_STACK_START
 101 FIQ_STACK_START:
 102         .word 0x0badc0de
 103 #endif
 104
 105
 106 /*
 107  * the actual reset code
 108  */
 109
 110 reset:
 111         /*
 112          * set the cpu to SVC32 mode
 113          */
 114         mrs     r0,cpsr
 115         bic     r0,r0,#0x1f
 116         orr     r0,r0,#0xd3
 117         msr     cpsr,r0
 118
 119 /* turn off the watchdog */
 120 #if defined(CONFIG_S3C2400)
 121 # define pWTCON         0x15300000
 122 # define INTMSK         0x14400008      /* Interupt-Controller base addresses */
 123 # define CLKDIVN        0x14800014      /* clock divisor register */
 124 #elif defined(CONFIG_S3C2410)
 125 # define pWTCON         0x53000000
 126 # define INTMSK         0x4A000008      /* Interupt-Controller base addresses */
 127 # define INTSUBMSK      0x4A00001C
 128 # define CLKDIVN        0x4C000014      /* clock divisor register */
 129 #endif
 130
 131 #if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
 132         ldr     r0, =pWTCON
 133         mov     r1, #0x0
 134         str     r1, [r0]
 135
 136         /*
 137          * mask all IRQs by setting all bits in the INTMR - default
 138          */
 139         mov     r1, #0xffffffff
 140         ldr     r0, =INTMSK
 141         str     r1, [r0]
 142 # if defined(CONFIG_S3C2410)
 143         ldr     r1, =0x3ff
 144         ldr     r0, =INTSUBMSK
 145         str     r1, [r0]
 146 # endif
 147
 148         /* FCLK:HCLK:PCLK = 1:2:4 */
 149         /* default FCLK is 120 MHz ! */
 150         ldr     r0, =CLKDIVN
 151         mov     r1, #3
 152         str     r1, [r0]
 153 #endif  /* CONFIG_S3C2400 || CONFIG_S3C2410 */
 154
 155         /*
 156          * we do sys-critical inits only at reboot,
 157          * not when booting from ram!
 158          */
 159 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 160         bl      cpu_init_crit
 161 #endif
 162
 163 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 164 relocate:                               /* relocate U-Boot to RAM           */
 165         adr     r0, _start              /* r0 <- current position of code   */
 166         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 167         cmp     r0, r1                  /* don't reloc during debug         */
 168         beq     stack_setup
 169
 170         ldr     r2, _armboot_start
 171         ldr     r3, _bss_start
 172         sub     r2, r3, r2              /* r2 <- size of armboot            */
 173         add     r2, r0, r2              /* r2 <- source end address         */
 174
 175 copy_loop:
 176         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 177         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 178         cmp     r0, r2                  /* until source end addreee [r2]    */
 179         ble     copy_loop
 180 #endif  /* CONFIG_SKIP_RELOCATE_UBOOT */
 181
 182         /* Set up the stack                                                 */
 183 stack_setup:
 184         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 185         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 186         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 187 #ifdef CONFIG_USE_IRQ
 188         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 189 #endif
 190         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 191
 192 clear_bss:
 193         ldr     r0, _bss_start          /* find start of bss segment        */
 194         ldr     r1, _bss_end            /* stop here                        */
 195         mov     r2, #0x00000000         /* clear                            */
 196
 197 clbss_l:str     r2, [r0]                /* clear loop...                    */
 198         add     r0, r0, #4
 199         cmp     r0, r1
 200         ble     clbss_l
 201
 202 #if 0
 203         /* try doing this stuff after the relocation */
 204         ldr     r0, =pWTCON
 205         mov     r1, #0x0
 206         str     r1, [r0]
 207
 208         /*
 209          * mask all IRQs by setting all bits in the INTMR - default
 210          */
 211         mov     r1, #0xffffffff
 212         ldr     r0, =INTMR
 213         str     r1, [r0]
 214
 215         /* FCLK:HCLK:PCLK = 1:2:4 */
 216         /* default FCLK is 120 MHz ! */
 217         ldr     r0, =CLKDIVN
 218         mov     r1, #3
 219         str     r1, [r0]
 220         /* END stuff after relocation */
 221 #endif
 222
 223         ldr     pc, _start_armboot
 224
 225 _start_armboot: .word start_armboot
 226
 227
 228 /*
 229  *************************************************************************
 230  *
 231  * CPU_init_critical registers
 232  *
 233  * setup important registers
 234  * setup memory timing
 235  *
 236  *************************************************************************
 237  */
 238
 239
 240 cpu_init_crit:
 241         /*
 242          * flush v4 I/D caches
 243          */
 244         mov     r0, #0
 245         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 246         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 247
 248         /*
 249          * disable MMU stuff and caches
 250          */
 251         mrc     p15, 0, r0, c1, c0, 0
 252         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 253         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 254         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 255         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 256         mcr     p15, 0, r0, c1, c0, 0
 257
 258
 259         /*
 260          * before relocating, we have to setup RAM timing
 261          * because memory timing is board-dependend, you will
 262          * find a lowlevel_init.S in your board directory.
 263          */
 264         mov     ip, lr
 265         bl      lowlevel_init
 266         mov     lr, ip
 267
 268         mov     pc, lr
 269
 270
 271 /*
 272  *************************************************************************
 273  *
 274  * Interrupt handling
 275  *
 276  *************************************************************************
 277  */
 278
 279 @
 280 @ IRQ stack frame.
 281 @
 282 #define S_FRAME_SIZE    72
 283
 284 #define S_OLD_R0        68
 285 #define S_PSR           64
 286 #define S_PC            60
 287 #define S_LR            56
 288 #define S_SP            52
 289
 290 #define S_IP            48
 291 #define S_FP            44
 292 #define S_R10           40
 293 #define S_R9            36
 294 #define S_R8            32
 295 #define S_R7            28
 296 #define S_R6            24
 297 #define S_R5            20
 298 #define S_R4            16
 299 #define S_R3            12
 300 #define S_R2            8
 301 #define S_R1            4
 302 #define S_R0            0
 303
 304 #define MODE_SVC 0x13
 305 #define I_BIT    0x80
 306
 307 /*
 308  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 309  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 310  */
 311
 312         .macro  bad_save_user_regs
 313         sub     sp, sp, #S_FRAME_SIZE
 314         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 315         ldr     r2, _armboot_start
 316         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 317         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 318         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 319         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 320
 321         add     r5, sp, #S_SP
 322         mov     r1, lr
 323         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 324         mov     r0, sp
 325         .endm
 326
 327         .macro  irq_save_user_regs
 328         sub     sp, sp, #S_FRAME_SIZE
 329         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 330         add     r8, sp, #S_PC
 331         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 332         str     lr, [r8, #0]                    @ Save calling PC
 333         mrs     r6, spsr
 334         str     r6, [r8, #4]                    @ Save CPSR
 335         str     r0, [r8, #8]                    @ Save OLD_R0
 336         mov     r0, sp
 337         .endm
 338
 339         .macro  irq_restore_user_regs
 340         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 341         mov     r0, r0
 342         ldr     lr, [sp, #S_PC]                 @ Get PC
 343         add     sp, sp, #S_FRAME_SIZE
 344         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 345         .endm
 346
 347         .macro get_bad_stack
 348         ldr     r13, _armboot_start             @ setup our mode stack
 349         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 350         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 351
 352         str     lr, [r13]                       @ save caller lr / spsr
 353         mrs     lr, spsr
 354         str     lr, [r13, #4]
 355
 356         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 357         @ msr   spsr_c, r13
 358         msr     spsr, r13
 359         mov     lr, pc
 360         movs    pc, lr
 361         .endm
 362
 363         .macro get_irq_stack                    @ setup IRQ stack
 364         ldr     sp, IRQ_STACK_START
 365         .endm
 366
 367         .macro get_fiq_stack                    @ setup FIQ stack
 368         ldr     sp, FIQ_STACK_START
 369         .endm
 370
 371 /*
 372  * exception handlers
 373  */
 374         .align  5
 375 undefined_instruction:
 376         get_bad_stack
 377         bad_save_user_regs
 378         bl      do_undefined_instruction
 379
 380         .align  5
 381 software_interrupt:
 382         get_bad_stack
 383         bad_save_user_regs
 384         bl      do_software_interrupt
 385
 386         .align  5
 387 prefetch_abort:
 388         get_bad_stack
 389         bad_save_user_regs
 390         bl      do_prefetch_abort
 391
 392         .align  5
 393 data_abort:
 394         get_bad_stack
 395         bad_save_user_regs
 396         bl      do_data_abort
 397
 398         .align  5
 399 not_used:
 400         get_bad_stack
 401         bad_save_user_regs
 402         bl      do_not_used
 403
 404 #ifdef CONFIG_USE_IRQ
 405
 406         .align  5
 407 irq:
 408         get_irq_stack
 409         irq_save_user_regs
 410         bl      do_irq
 411         irq_restore_user_regs
 412
 413         .align  5
 414 fiq:
 415         get_fiq_stack
 416         /* someone ought to write a more effiction fiq_save_user_regs */
 417         irq_save_user_regs
 418         bl      do_fiq
 419         irq_restore_user_regs
 420
 421 #else
 422
 423         .align  5
 424 irq:
 425         get_bad_stack
 426         bad_save_user_regs
 427         bl      do_irq
 428
 429         .align  5
 430 fiq:
 431         get_bad_stack
 432         bad_save_user_regs
 433         bl      do_fiq
 434
 435 #endif
 436
 437         .align  5
 438 .globl reset_cpu
 439 reset_cpu:
 440 #ifdef CONFIG_S3C2400
 441         bl      disable_interrupts
 442 # ifdef CONFIG_TRAB
 443         bl      disable_vfd
 444 # endif
 445         ldr     r1, _rWTCON
 446         ldr     r2, _rWTCNT
 447         /* Disable watchdog */
 448         mov     r3, #0x0000
 449         str     r3, [r1]
 450         /* Initialize watchdog timer count register */
 451         mov     r3, #0x0001
 452         str     r3, [r2]
 453         /* Enable watchdog timer; assert reset at timer timeout */
 454         mov     r3, #0x0021
 455         str     r3, [r1]
 456 _loop_forever:
 457         b       _loop_forever
 458 _rWTCON:
 459         .word   0x15300000
 460 _rWTCNT:
 461         .word   0x15300008
 462 #else /* ! CONFIG_S3C2400 */
 463         mov     ip, #0
 464         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 465         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 466         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 467         bic     ip, ip, #0x000f                 @ ............wcam
 468         bic     ip, ip, #0x2100                 @ ..v....s........
 469         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 470         mov     pc, r0
 471 #endif /* CONFIG_S3C2400 */