git.sur5r.net Git - u-boot/blob - cpu/at91rm9200/start.S

   1 /*
   2  *  armboot - Startup Code for ARM720 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26
  27 #include "config.h"
  28 #include "version.h"
  29
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 _TEXT_BASE:
  75         .word   TEXT_BASE
  76
  77 .globl _armboot_start
  78 _armboot_start:
  79         .word _start
  80
  81 /*
  82  * These are defined in the board-specific linker script.
  83  */
  84 .globl _bss_start
  85 _bss_start:
  86         .word __bss_start
  87
  88 .globl _bss_end
  89 _bss_end:
  90         .word _end
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104
 105 /*
 106  * the actual reset code
 107  */
 108
 109 reset:
 110         /*
 111          * set the cpu to SVC32 mode
 112          */
 113         mrs     r0,cpsr
 114         bic     r0,r0,#0x1f
 115         orr     r0,r0,#0xd3 /* was 13 */
 116         msr     cpsr,r0
 117
 118 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 119         /* scratch stack */
 120 /****   ldr     r1, =0x00204000         ****/
 121         /* Insure word alignment */
 122 /****   bic     r1, r1, #3              ****/
 123         /* Init stack SYS        */
 124 /****   mov     sp, r1                  ****/
 125         /*
 126          * This does a lot more than just set up the memory, which
 127          * is why it's called lowlevel_init
 128          */
 129         bl      lowlevel_init /* in lowlevel.S */
 130
 131         /*
 132          * Read/modify/write CP15 control register
 133          * disable MMU, enable I-Cache, select Asychronous Clocking Mode
 134          */
 135
 136         mrc     p15, 0, r0, c1, c0, 0   @ read cp15 control register (cp15 r1) in r0
 137         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 138         bic     r0, r0, #0x0000008f     @ clear bits 7, 3:0 (B--- WCAM)
 139         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 140         orr     r0, r0, #0x00000004     @ set bit 3 (C) D-Cache
 141         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 142         orr     r0, r0, #0xC0000000     @ set bits 31:30 (iA, nF)
 143         mcr     p15, 0, r0, c1, c0, 0   @ write r0 in cp15 control register (cp15 r1)
 144 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 145         /*
 146          * relocate exeception table
 147          */
 148         ldr     r0, =_start
 149         ldr     r1, =0x0
 150         mov     r2, #16
 151 copyex:
 152         subs    r2, r2, #1
 153         ldr     r3, [r0], #4
 154         str     r3, [r1], #4
 155         bne     copyex
 156
 157         /*
 158          * we do sys-critical inits only at reboot,
 159          * not when booting from ram!
 160          */
 161 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 162         bl      cpu_init_crit
 163 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 164
 165 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 166 relocate:                               /* relocate U-Boot to RAM           */
 167         adr     r0, _start              /* r0 <- current position of code   */
 168         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 169         cmp     r0, r1                  /* don't reloc during debug         */
 170         beq     stack_setup
 171
 172         ldr     r2, _armboot_start
 173         ldr     r3, _bss_start
 174         sub     r2, r3, r2              /* r2 <- size of armboot            */
 175         add     r2, r0, r2              /* r2 <- source end address         */
 176
 177 copy_loop:
 178         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 179         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 180         cmp     r0, r2                  /* until source end addreee [r2]    */
 181         ble     copy_loop
 182 #endif  /* CONFIG_SKIP_RELOCATE_UBOOT */
 183
 184         /* Set up the stack                                                 */
 185 stack_setup:
 186         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 187         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 188         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 189 #ifdef CONFIG_USE_IRQ
 190         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 191 #endif
 192         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 193
 194 clear_bss:
 195         ldr     r0, _bss_start          /* find start of bss segment        */
 196         ldr     r1, _bss_end            /* stop here                        */
 197         mov     r2, #0x00000000         /* clear                            */
 198
 199 clbss_l:str     r2, [r0]                /* clear loop...                    */
 200         add     r0, r0, #4
 201         cmp     r0, r1
 202         ble     clbss_l
 203
 204         ldr pc,_start_armboot
 205
 206 _start_armboot: .word start_armboot
 207
 208 /*
 209  *************************************************************************
 210  *
 211  * CPU_init_critical registers
 212  *
 213  *************************************************************************
 214  */
 215
 216 cpu_init_crit:
 217         /* do nothing for now */
 218         mov     pc, lr
 219
 220
 221 /*
 222  *************************************************************************
 223  *
 224  * Interrupt handling
 225  *
 226  *************************************************************************
 227  */
 228
 229 @
 230 @ IRQ stack frame.
 231 @
 232 #define S_FRAME_SIZE    72
 233
 234 #define S_OLD_R0        68
 235 #define S_PSR           64
 236 #define S_PC            60
 237 #define S_LR            56
 238 #define S_SP            52
 239
 240 #define S_IP            48
 241 #define S_FP            44
 242 #define S_R10           40
 243 #define S_R9            36
 244 #define S_R8            32
 245 #define S_R7            28
 246 #define S_R6            24
 247 #define S_R5            20
 248 #define S_R4            16
 249 #define S_R3            12
 250 #define S_R2            8
 251 #define S_R1            4
 252 #define S_R0            0
 253
 254 #define MODE_SVC 0x13
 255 #define I_BIT    0x80
 256
 257 /*
 258  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 259  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 260  */
 261
 262         .macro  bad_save_user_regs
 263         sub     sp, sp, #S_FRAME_SIZE
 264         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 265         add     r8, sp, #S_PC
 266
 267         ldr     r2, _armboot_start
 268         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 269         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 270         ldmia   r2, {r2 - r4}                   @ get pc, cpsr, old_r0
 271         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 272
 273         add     r5, sp, #S_SP
 274         mov     r1, lr
 275         stmia   r5, {r0 - r4}                   @ save sp_SVC, lr_SVC, pc, cpsr, old_r
 276         mov     r0, sp
 277         .endm
 278
 279         .macro  irq_save_user_regs
 280         sub     sp, sp, #S_FRAME_SIZE
 281         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 282         add     r8, sp, #S_PC
 283         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 284         str     lr, [r8, #0]                    @ Save calling PC
 285         mrs     r6, spsr
 286         str     r6, [r8, #4]                    @ Save CPSR
 287         str     r0, [r8, #8]                    @ Save OLD_R0
 288         mov     r0, sp
 289         .endm
 290
 291         .macro  irq_restore_user_regs
 292         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 293         mov     r0, r0
 294         ldr     lr, [sp, #S_PC]                 @ Get PC
 295         add     sp, sp, #S_FRAME_SIZE
 296         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 297         .endm
 298
 299         .macro get_bad_stack
 300         ldr     r13, _armboot_start             @ setup our mode stack
 301         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 302         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 303
 304         str     lr, [r13]                       @ save caller lr / spsr
 305         mrs     lr, spsr
 306         str     lr, [r13, #4]
 307
 308         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 309         msr     spsr_c, r13
 310         mov     lr, pc
 311         movs    pc, lr
 312         .endm
 313
 314         .macro get_irq_stack                    @ setup IRQ stack
 315         ldr     sp, IRQ_STACK_START
 316         .endm
 317
 318         .macro get_fiq_stack                    @ setup FIQ stack
 319         ldr     sp, FIQ_STACK_START
 320         .endm
 321
 322 /*
 323  * exception handlers
 324  */
 325         .align  5
 326 undefined_instruction:
 327         get_bad_stack
 328         bad_save_user_regs
 329         bl      do_undefined_instruction
 330
 331         .align  5
 332 software_interrupt:
 333         get_bad_stack
 334         bad_save_user_regs
 335         bl      do_software_interrupt
 336
 337         .align  5
 338 prefetch_abort:
 339         get_bad_stack
 340         bad_save_user_regs
 341         bl      do_prefetch_abort
 342
 343         .align  5
 344 data_abort:
 345         get_bad_stack
 346         bad_save_user_regs
 347         bl      do_data_abort
 348
 349         .align  5
 350 not_used:
 351         get_bad_stack
 352         bad_save_user_regs
 353         bl      do_not_used
 354
 355 #ifdef CONFIG_USE_IRQ
 356
 357         .align  5
 358 irq:
 359         get_irq_stack
 360         irq_save_user_regs
 361         bl      do_irq
 362         irq_restore_user_regs
 363
 364         .align  5
 365 fiq:
 366         get_fiq_stack
 367         /* someone ought to write a more effiction fiq_save_user_regs */
 368         irq_save_user_regs
 369         bl      do_fiq
 370         irq_restore_user_regs
 371
 372 #else
 373
 374         .align  5
 375 irq:
 376         get_bad_stack
 377         bad_save_user_regs
 378         bl      do_irq
 379
 380         .align  5
 381 fiq:
 382         get_bad_stack
 383         bad_save_user_regs
 384         bl      do_fiq
 385
 386 #endif
 387
 388         .align  5
 389 .globl reset_cpu
 390 reset_cpu:
 391         mov     pc, r0