git.sur5r.net Git - bacula/bacula/blob - bacula/src/qt-console/tray-monitor/tray-monitor.pro.in

   1 ######################################################################
   2 #
   3 #  !!!!!!! IMPORTANT !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
   4 #
   5 #  Edit only tray-monitor.pro.in  -- tray-monitor.pro is built by the ./configure program
   6 #
   7 #  !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
   8 #
   9 # CONFIG options for Windows are pulled from win32/qmake.conf
  10 CONFIG += qt
  11 #CONFIG += qt debug
  12
  13 cross-win32 {
  14   LIBS       +=  -mwindows -L../../win32/release32 -lbacula
  15   INCLUDEPATH += ../../win32/compat
  16 }
  17 !cross-win32 {
  18   LIBS        += -L../../lib -lbaccfg -lbac -L../../findlib -lbacfind @OPENSSL_LIBS@
  19 }
  20
  21
  22 bins.path = /$(DESTDIR)@sbindir@
  23 bins.files = bacula-tray-monitor
  24 confs.path = /$(DESTDIR)@sysconfdir@
  25 confs.commands = ./install_conf_file
  26
  27 TEMPLATE     = app
  28 TARGET       = bacula-tray-monitor
  29 QMAKE_EXTRA_TARGETS += depend
  30 DEPENDPATH  += .
  31 INCLUDEPATH += ../.. .
  32 LIBTOOL_LINK = @QMAKE_LIBTOOL@ --silent --tag=CXX --mode=link
  33 LIBTOOL_INSTALL = @QMAKE_LIBTOOL@ --silent --mode=install
  34 QMAKE_LINK   = $${LIBTOOL_LINK} $(CXX)
  35 QMAKE_INSTALL_PROGRAM = $${LIBTOOL_INSTALL} install -m @SBINPERM@ -p
  36 QMAKE_CLEAN += obj/* .libs/* bacula-tray-monitor release/bacula-tray-monitor
  37 QMAKE_CXXFLAGS += -DTRAY_MONITOR
  38 QMAKE_CFLAGS += -DTRAY_MONITOR
  39
  40 INSTALLS = bins confs
  41
  42 RESOURCES    = ../main.qrc
  43 MOC_DIR      = moc
  44 OBJECTS_DIR  = obj
  45 UI_DIR       = ui
  46
  47 # Main directory
  48 HEADERS += tray-monitor.h tray_conf.h tray-ui.h fdstatus.h task.h ../util/fmtwidgetitem.h dirstatus.h conf.h sdstatus.h runjob.h status.h
  49 SOURCES +=  tray-monitor.cpp tray_conf.cpp fdstatus.cpp task.cpp authenticate.cpp ../util/fmtwidgetitem.cpp dirstatus.cpp sdstatus.cpp conf.cpp runjob.cpp status.cpp common.h
  50
  51 FORMS += fd-monitor.ui dir-monitor.ui sd-monitor.ui main-conf.ui res-conf.ui run.ui
  52
  53 TRANSLATIONS += ts/tm_fr.ts ts/tm_de.ts ts/tm_ja.ts